*DECK CALLNG
USETEXT COMCBEG 
USETEXT COMADEF 
USETEXT COMACBF 
USETEXT COMACBX 
PROC CALLNG (HDRAREA,TEXTAREA); 
# TITLE CALLNG - CALL NETGET.  #
  
      BEGIN  # CALLNG # 
  
# 
*     CALLNG - CALL NETGET. 
* 
*     CALLNG MAKES A CALL TO THE RHF SUBSYSTEM IN ORDER TO PERFORM
*     A NETGET FUNCTION OF AN ASYNCHRONOUS SUPERVISORY MESSAGE OR FOR 
*     A LEVEL 7 COMMAND.
* 
*     PROC CALLNG (HDRAREA,TEXTAREA)
* 
*     ENTRY      HDRAREA - HEADER WORD ADDRESS. 
*                TEXTAREA   - TEXT AREA ADDRESS.
*                ACN        - THE ACN MUST BE PUT IN THE RHF REPLY
*                             BLOCK USED DURING FILE TRANSFERS. 
*                SSCXRECALL - SET TO TRUE IF RECALL IS DESIRED. 
* 
*     EXIT       NONE.
* 
*     PROCESS    ZERO THE HEADER WORD.
*                CALL SYSTEM TO MAKE AN RA + 1 CALL FOR SSC 
*                  SO THAT RHF CAN PERFORM A NETGET FUNCTION. 
* 
# 
  
*CALL HDRAREA 
*CALL TEXTAREA
  
# 
****  PROC CALLNG - XREF LIST BEGIN.
# 
  
      XREF
        BEGIN 
        PROC DBGMSG;                 # WRITE DEBUG DAYFILE MESSAGE #
        PROC CALLSYS;                # MAKES RA+1 CALLS # 
        END 
  
# 
****  PROC CALLNG - XREF LIST END.
# 
                                               CONTROL WEAK DBGMSG; 
                                               CONTROL EJECT; 
      IF NOT RRB$DONE[0]
      THEN
        BEGIN  # WAIT UNTIL LAST REQUEST COMPLETES #
        RCLPARAMAD[0] = LOC (RRBDFT); 
        RCLRECALL[0] = TRUE;
        CALLSYS (RCLCALL);           # ENTER AUTO-RECALL #
        END 
  
      HDR$WORD[0] = 0;
      RRB$HDRADR[0]  = LOC (HDRAREA); 
      RRB$TEXTAD[0]  =  LOC (TEXTAREA); 
      RRB$MAXBL[0] = LENTEXAREA;
      RRB$FNCNUM[0]  = NETGETFUNC;
      RRB$DONE[0] = FALSE;
      SSCXPARAMA[0]  =  LOC (RRBDFT); 
      CALLSYS (SSCXCALL);            # ISSUE RHF REQUEST #
      DBGXNG = DBGXNG + 1;
  
      IF DBUGDAT OR DBUGSUP 
      THEN
        BEGIN 
        DBGMSG (LOC (HDRAREA), LOC (TEXTAREA), FALSE);
        END 
  
      END    # CALLNG # 
  
      TERM
