*DECK BUILDFT 
USETEXT COMCBEG 
USETEXT COMADEF 
USETEXT COMACBF 
USETEXT COMACBX 
USETEXT COMAFET 
    PROC BUILDFT (FILENAME);
# TITLE BUILDFT - BUILD FET.  # 
  
      BEGIN  # BUILDFT #
  
# 
**    BUILDFT  - BUILD FETS.
* 
*     BUILDFT CREATES THE LOCAL FILE FET AND THE
*     RHF NETXFR REQUEST/REPLY PARAMETER BLOCK ASSOCIATED WITH THIS ACN.
* 
*     PROC BUILDFT(FILENAME)
* 
*     ENTRY      FILENAME - FILE NAME OF LOCAL FILE.
*                P<LFET> = FWA LOCAL FET. 
*                P<RFET> = FWA RHF FET. 
*                LFETLIM = LOCAL FET BUFFER SIZE. 
*                RFETLIM = RHF FET BUFFER SIZE. 
* 
*     EXIT       LOCAL FILE FET SET UP. 
*                RHF FILE FET SET UP (FIRST + LIMIT). 
*                RHF PARAMETER BLOCK SET UP.
* 
*     PROCESS    BUILD LOCAL FILE FET.
*                SET ERROR-PROCESSING FLAG IN LOCAL FET.
*                SET FIRST AND LIMIT POINTERS IN RHF FET. 
*                BUILD RHF-S NETXFR REQUEST/REPLY PARAMETER BLOCK 
*                  FOR THIS ACN.
* 
# 
  
      ITEM FILENAME   C(7);          # FILE NAME #
  
# 
****  PROC BUILDFT - XREF LIST BEGIN. 
# 
  
      XREF
        BEGIN 
        FUNC REPBLNK U;              # REPLACE TRAILING " " WITH ZEROS #
        END 
  
# 
****  PROC BUILDFT - XREF LIST END. 
# 
  
                                               CONTROL EJECT; 
  
# 
*     BUILD THE LOCAL FILE FET, ASSUMING 2-BUFFER I/O,
*     AND SET RHF FET FIRST AND LIMIT POINTERS. 
# 
  
      LFETLFNC[0]  =  FILENAME; 
      LFETCOMP = TRUE;
      LFETLFN[0]   =   REPBLNK (LFETLFN[0]);
      LFETEP = TRUE;
      LFETFETL[0]  =  LEN$LFET  -  5; 
      LFETFIR = LOC (RFET) + LEN$RFET + LEN$XTRA; 
      LFETIN[0]    =  LFETFIR[0]; 
      LFETOUT[0]   =  LFETFIR[0]; 
      LFETLIM[0] = LFETLIM[0] + LFETFIR[0]; 
  
      RFETCOMP = TRUE;
      RFETFIR[0] = LFETLIM[0];
      RFETLIM[0] = RFETLIM[0] + RFETFIR[0]; 
  
# 
*     BUILD RHF-S  NETXFR REQUEST/REPLY PARAMETER BLOCK.
# 
  
      P<RHFREQREPB>  =  FTTPBLKADR; 
      RHF$WC[0]      =  MAXWCRHFPL; 
      RHF$FNCNUM[0]  =  NETXFRFUNC; 
      RHF$ACN[0]     =  FTTACN; 
      RHF$ATA[0]     =  BKF$ATA[0]; 
      RHF$RFETAD[0]  =  LOC (RFET); 
      RHF$CMTYPE[0]  =  BINARYST; 
  
      END    # BUILDFT #
  
      TERM
