*DECK AUTSTRT 
USETEXT COMCBEG 
USETEXT COMRAPL 
PROC AUTSTRT; 
# TITLE   AUTSTRT - AUTO START APPLICATIONS  #
  
      BEGIN  # AUTSTRT #
  
# 
**    AUTSTRT - AUTO START APPLICATIONS 
* 
*     SEARCHS THRU APPLICATION TABLE HEADERS FOR APPLICATIONS WITH BOTH 
*     THE AUTOSTART BIT AND ENABLED BIT SET AND BATCHES JOBS TO THE 
*     INPUT QUEUE TO INITIATE THEM. 
* 
*     PROC AUTSTRT. 
* 
*     ENTRY   - NONE
* 
*     EXIT    - JOBS SENT TO INPUT QUEUE TO INITIATE APPLICATIONS.
* 
*     PROCESS - FOR EACH APPLICATION TABLE
*                 IF AUTOSTART
*                   AND ENABLED 
*                   AND THIS APPLICATION NOT YET STARTED
*                 THEN
*                   INITIATE APPLICATION PROGRAM. 
*               RETURN. 
* 
* 
****  PROC AUTSTRT - XREF LIST BEGIN. 
# 
  
      XREF
        BEGIN 
        ITEM FAPLADR  I;             # FIRST APPLICATION TABLE ADDRESS #
        ITEM LAPLADR  I;             # LAST APPLICATION TABLE ADDRESS # 
        PROC STRTJOB;                # INITIATE APPLICATION PROGRAM # 
        END 
  
# 
****  PROC AUTSTRT - XREF LIST END. 
# 
  
  
      ITEM LASTAPLNAM C(7) = " ";    # LAST APPLICATION NAME #
  
CONTROL EJECT;
      P<APL$HEADER> = FAPLADR;
      ASLONGAS P<APL$HEADER> LE LAPLADR 
      DO
        BEGIN 
        IF LASTAPLNAM NE APL$NAME 
          AND APL$ASTART
          AND APL$ENABLE
        THEN
          BEGIN 
          LASTAPLNAM = APL$NAME;
          STRTJOB;
          END 
  
        P<APL$HEADER> = P<APL$HEADER> + APL$LENGTH +
                         (APL$NUMCON * CON$LENGTH); 
        END 
  
      END 
  
      TERM
