*DECK AUTLOAD 
USETEXT COMCBEG 
USETEXT COMRRTN 
USETEXT COMRNET 
USETEXT COMRRHH 
PROC AUTLOAD; 
# TITLE   AUTLOAD - AUTO-LOAD CONTROLWARE IN LOCAL NADS # 
  
      BEGIN  # AUTLOAD #
  
# 
**    AUTLOAD - AUTO-LOAD CONTROLWARE IN LOCAL NADS.
* 
*     SEARCHES LOCAL NAD TABLE TO FIND NADS THAT SHOULD BE
*     LOADED AND INITIALIZES THE NAD TABLE ENTRIES WITH A 
*     REQUEST FOR MHF TO LOAD THOSE NADS AFTER IT NETS ON.
* 
*     PROC AUTLOAD. 
* 
*     ENTRY   - NONE. 
* 
*     EXIT    - LOCAL NAD TABLE ENTRIES HAVE BEEN INITIALIZED --
*                 NAD$STATE = LOAD-REQUIRED.
* 
*     PROCESS - CALL RHH TO INITIALIZE LNT. 
*               FOR EACH LOCAL NAD ENTRY DO 
*                 IF NO CONFIGURATION ERROR 
*                 THEN
*                   CALL RHH TO CLEAR RHF ACTIVE FLAG IN EST
*                 IF NAD AVAILABLE AND NOT LOADED 
*                 THEN
*                   SET NAD STATE = LOAD-REQUIRED.
*                 ELSE
*                   SET NAD STATE = DISABLED. 
# 
  
# 
****  PROC AUTLOAD - XREF LIST BEGIN
# 
  
      XREF
        BEGIN 
        PROC CALLSYS;                # MAKE RA + 1 REQUEST #
        ITEM NUMNADS;                # NUMBER OF LOCAL NADS # 
        ITEM NADTBL;                 # FWA OF LOCAL NAD TABLE # 
        END 
  
# 
****  PROC AUTLOAD - XREF LIST END
# 
  
  
      ITEM I          I;             # LOOP COUNTER # 
  
CONTROL EJECT;
  
      RHHRCL = TRUE;
      RHHFUNCTN = RH$INIT;
      RHHPARMAD = LOC(RHH$PARAM); 
      RHH$PARAM = 0;
      RHH$NUMNAD = NUMNADS; 
      RHH$NADADR = NADTBL;
      RHH$COMPLT = FALSE; 
      CALLSYS(RHHCALL); 
      RHHRCL = FALSE; 
  
      P<NAD$ENTRY> = NADTBL;
      FOR I = 1 STEP 1 WHILE I LE NUMNADS DO
        BEGIN 
        IF NOT NAD$CONFER 
        THEN
          BEGIN 
          RHHRCL=TRUE;
          RHHFUNCTN=RH$CLEAR; 
          RHHPARMAD=LOC(RHH$PARAM); 
          RHH$PARAM=0;
          RHH$ESTORD=NAD$ESTORD;
          CALLSYS(RHHCALL); 
          RHHRCL=FALSE; 
          END 
  
        P<NST$ENTRY> = LOC(NAD$NSTWD0);  # NAD STATUS ENTRY # 
        NST$DMPCTR = 0; 
        IF NAD$CWSBL
        THEN
          BEGIN 
          NST$STATE = NS$LDREQ; 
          END 
  
        ELSE
          BEGIN 
          NST$STATE = NS$DISAB; 
          END 
  
        P<NAD$ENTRY> = P<NAD$ENTRY> + NAD$LENGTH; 
        END 
  
      END  # AUTLOAD #
  
      TERM
