*DECK ACANSUP 
USETEXT COMCBEG 
USETEXT COMRQUE 
PROC ACANSUP((ACRQREPLY));
# TITLE ACANSUP - GIVE CON/ACRQ/R ABORT RESPONSE. # 
  
      BEGIN  # ACANSUP #
  
# 
**    ACANSUP - GIVE CON/ACRQ/R ABORT RESPONSE. 
* 
*     ACANSUP GIVES THE CON/ACRQ/R ABORT RESPONSE. THIS INCLUDES
*     GENERATION OF THE CON/ACRQ/A SUPERVISORY MESSAGE AND INITIATION 
*     OF AN NSUP REPLY. 
* 
*     PROC ACANSUP(ACRQREPLY).
* 
*     ENTRY   -  QU$ADDRESS IS BASED ARRAY CONTAINING CON/ACRQ/R. 
*                ACRQREPLY IS THE REPLY CODE FOR THE CON/ACRQ/R REQUEST 
*                APL$HEADER IS BASED ARRAY CONTAINING APPL HEADER.
* 
*     EXIT    -  CON/ACRQ/A SUPERVISORY MSG QUEUED. 
*                NSUP UPDATED.
* 
*     PROCESS -  SAVE JOB ID AND UCPA FROM QUEUE ENTRY
*                INITIATE CON/ACRQ/A SUPERVISORY MSG REPLY
*                GET FREE QUEUE ENTRY 
*                SET UP UCPA, JOBID AND CHARGE
*                INITIATE NSUP REPLY
*                RETURN 
* 
* 
# 
  
      ITEM ACRQREPLY I;              # CON/ACRQ/R REPLY CODE #
  
# 
****  PROC ACANSUP - XREF LIST BEGIN. 
# 
  
      XREF
        BEGIN 
        PROC ACRQA;                  # INITIATE CON/ACRQ/A SUP MSG RPLY#
        PROC GETFREE;                # GET FREE QUEUE ENTRY # 
        PROC RTNNSUP;                # INITIATE NSUP UPDATE # 
        END 
  
# 
****  PROC ACANSUP - XREF LIST END. 
# 
  
  
      ITEM QUJOBID  I;               # TEMP CELL FOR REQUESTORS JOBID # 
      ITEM QUUCPA   I;               # TEMP CELL FOR REQUESTORS UCPAD # 
  
CONTROL EJECT;
  
      QUUCPA = QU$UCPA; 
      QUJOBID= QU$JOBID;
      ACRQA(ACRQREPLY); 
      GETFREE;
      QU$UCPA = QUUCPA; 
      QU$JOBID= QUJOBID;
      QU$CHARGE = 1;                 # HIGH OVERHEAD FUNCTION # 
      RTNNSUP;
      RETURN; 
      END  # ACANSUP #
  
      TERM
