*COMDECK XREL 
          IDENT  XREL 
          ENTRY  XREL=
          ENTRY  XREL.
          SYSCOM B1 
          TITLE  XREL - COMMON DECK INTERFACE ROUTINES. 
          COMMENT COMMON DECK INTERFACE ROUTINES. 
          COMMENT COPYRIGHT CONTROL DATA CORP. 1978.
 XREL     SPACE  4,10 
***       XREL - COMMON DECK INTERFACE ROUTINES.
* 
*                XREL IS A COLLECTION OF RELOCATABLE MODULES THAT 
*         PROVIDE THE INTERFACE BETWEEN HIGHER LEVEL LANGUAGE MODULES 
*         AND THE STANDARD COMMON DECK ROUTINES THAT ARE NOT CALLED 
*         BY SYSTEM MACROS. 
 XREL     SPACE  4,10 
 LOCAL    EQU    3
 XREL.    SPACE  4,10 
**        XREL. - UNDEFINED COMMON DECK PROCESSOR.
* 
*         ENTRY  (X1) = LAST 3 CHARACTERS OF COMMON DECK NAME,
*                       LEFT JUSTIFIED. 
* 
*         USES   X - 6. 
*                A - 6. 
*                B - 1. 
* 
*         MACROS ABORT, MESSAGE.
  
  
 XREL.    SUBR               ENTRY/EXIT 
          SB1    1
          BX6    X1 
          SA6    XREA+3 
          MESSAGE  XREA,LOCAL,R 
          ABORT 
  
 XREA     DATA   C* XREL - UNDEFINED ROUTINE -   FILL-IN.*
 XREL=    SPACE  4,10 
**        XREL= - ILLEGAL ARGUMENT PROCESSOR. 
* 
*         ENTRY  (X1) = LAST 3 CHARACTERS OF COMMON DECK NAME,
*                       LEFT JUSTIFIED. 
*                (X2) = ILLEGAL ARGUMENT. 
* 
*         USES   X - 0, 1, 2, 6.
*                A - 6. 
*                B - 1. 
* 
*         CALLS  ZTB=.
* 
*         MACROS ABORT, MESSAGE.
  
  
 XREL=    SUBR               ENTRY/EXIT 
          SB1    1
          BX0    X2          SAVE SECOND ARGUMENT 
          LX1    -6 
          SX2    1R-
          BX1    X1+X2
          RJ     =XZTB= 
          BX1    X0 
          SA6    XREB 
          RJ     =XZTB= 
          SA6    XREB+3 
          MESSAGE  XREB,LOCAL,R 
          ABORT 
  
 XREB     DATA   C* FILL-IN - ILLEGAL ARGUMENT  .GT.FILL-IT-IN.LT..*
  
          END 
