*COMDECK XDXB 
          IDENT  XDXB 
          ENTRY  XDXB 
          SYSCOM B1 
          COMMENT CONVERT WORD OF DISPLAY CODE DIGITS TO BINARY.
          COMMENT COPYRIGHT CONTROL DATA CORP. 1978.
          SPACE  4,10 
***       XDXB - CONVERT WORD OF DISPLAY CODE DIGITS TO BINARY. 
* 
*         *SYMPL* CALLABLE ROUTINE TO CONVERT ONE 60 BIT WORD 
*         OF DISPLAY CODE DIGITS INTO BINARY. 
* 
*         STAT = XDXB(OWORD,TYPE,NWORD);    (*SYMPL* CALL)
* 
*                OWORD - AN ITEM THAT CONTAINS THE WORD 
*                        BE CONVERTED.
*                TYPE  - CONVERSION TYPE. 
*                      - .GT. 0, CONVERSION IN DECIMAL. 
*                      - = 0, CONVERSION IN OCTAL.
*                NWORD - AN ITEM TO CONTAIN THE CONVERTED DIGITS. 
*                STAT  - = 0, NO ERROR. 
*                      - NON ZERO, ERROR IN ASSEMBLY. 
* 
*         USES   X - 2, 3, 5, 6.
*                A - 2, 3, 5, 6.
*                B - 1, 2, 7. 
* 
*         CALLS  DXB. 
  
  
 XDXB     SUBR               ENTRY/EXIT 
          SB1    1
          SA5    X1          (X5) = WORD
          SA2    A1+B1       ADDRESS OF TYPE IN X2
          SA3    X2 
          SB7    X3          (B7) = TYPE
          SB2    10D         DO TEN CHARACTERS
          MX6    -6 
          MX3    54 
 DXB1     LX5    6
          BX2    -X6*X5 
          SX2    X2-1R
          SB2    B2-B1
          NZ     X2,DXB2     IF NOT A SPACE CHARACTER 
          BX5    X3*X5
 DXB2     NZ     B2,DXB1     IF MORE CHARACTERS 
          RJ     =XDXB= 
          SA3    A2+B1
          SA6    X3          STORE CONVERTED DIGITS 
          BX6    X4          PUT STATUS IN (X6) 
          EQ     XDXBX
  
          END 
