*COMDECK DEFMAC 
*#
*1DC  DEFINE MACRO
* 
*     PURPOSE 
*         PROVIDE COMPASS EQU STATEMENTS FOR NAM PREDEFINED 
*         SYMBOLS AND TWO WORD ENTRY CONTAINING NAME FOLLOWED 
*         BY VALUE IN A TABLE FOR THE NFETCH AND NSTORE 
*         SUBROUTINES.
*     CALLING SEQUENCE
*         DEF# NAME, TYPE, VALUE #
*     PARAMETERS
*         <NAME>-    NAM PREDEFINED SYMBOL. 
*         <TYPE>-    NUMERIC BASE FOR THE VALUE,
*                    H - HEXADECIMAL, 
*                    D - DECIMAL, 
*                    O - OCTAL. 
*         <VALUE>-   VALUE OF THE PREDEFINED SYMBOL.
*     ACTION
*         GENERATES A COMPASS EQU STATEMENT FOR THE NAM 
*         PREDEFINED SYMBOL. IF NP$SYMP IS DEFINED, IT
*         GENERATES TWO WORD ENTRY FOR THAT SYMBOL IN A 
*         TABLE USED BY NFETCH AND NSTORE SUBROUTINES.
*      REGISTERS USED.
*         NONE. 
*#
* 
          PURGMAC DEF#
* 
DEF#      MACRO  NAME,T,VALUE 
DEF#1     IF     DEF,NP$SYMP
SYM       ECHO   ,X=(H,O,D,,C),Y=(0#,O,D,,10L)
SYM1      IFC    EQ,*X*T* 
          IFC    -EQ,*T*H*,3
          IFC    -EQ,*T*C*,2
NAME      EQU    VALUE_Y
          SKIP   1
NAME      EQU    Y_VALUE
SYMTAB    RMT 
          VFD    42D/0L_NAME,12D/0,6/4
          VFD    60D/NAME 
SYMTAB    RMT 
          STOPDUP 
SYM1      ENDIF 
SYM       ENDD
DEF#1     ELSE
SYM2      ECHO   ,X=(H,O,D,,C),Y=(0#,O,D,,10L)
SYM2A     IFC    EQ,*X*T* 
          IFC    -EQ,*T*H*,3
          IFC    -EQ,*T*C*,2
'_NAME    EQU    VALUE_Y
          SKIP   1
'_NAME    EQU    Y_VALUE
 NAME     EQU    '_NAME 
          STOPDUP 
SYM2A     ENDIF 
SYM2      ENDD
DEF#1     ENDIF 
DEF#      ENDM
  
