*COMDECK CLOSER 
          IDENT  CLOSER 
          ENTRY  CLOSER 
          SYSCOM B1 
          TITLE  CLOSER - CLOSE REEL. 
          COMMENT CLOSE REEL. 
          COMMENT COPYRIGHT CONTROL DATA CORP. 1978.
 CLOSER   SPACE  4,10 
***       CLOSER - CLOSER REEL. 
* 
*         CALL CLOSER (FILE,OPTION,R) 
* 
*         ENTRY  (FILE) = FIRST WORD OF THE FET.
*                (OPTION) = 0, CLOSE WITH REWIND. 
*                         = 2HNR, CLOSE WITHOUT REWIND. 
*                         = 6HREWIND, CLOSE WITH REWIND.
*                         = 6HUNLOAD, CLOSE WITH REWIND, UNLOAD.
*                (R) = RECALL, IF .NE. 0, RECALL IS REQUESTED.
* 
*         CLOSER(FILE,OPTION,R); (*SYMPL* CALL) 
* 
*         ENTRY   FILE, AN ARRAY THAT CONTAINS THE FET. 
*                 OPTION, AN ITEM THE CONTAINS ONE OF THE FOLLOWING 
*                         CHARACTER STRINGS, LEFT JUSTIFIED, BLANK
*                         FILL, OR A BINARY 0.
*                            NR  (NO REWIND). 
*                            REWIND (SAME AS 0).
*                            UNLOAD.
*                (R) = RECALL, IF .NE. 0, RECALL IS REQUESTED.
* 
*         EXIT   TO ARGUMENT ERROR PROCESSOR IF OPTION IS UNRECOGNIZED. 
* 
*         USES   X - 1, 2, 3, 4.
*                A - 1, 2, 3, 4.
*                B - 1. 
* 
*         CALLS MACREL. 
* 
*         MACROS CLOSER.
  
  
  
 CLOSER   SUBR               ENTRY/EXIT 
          SB1    1
          SA2    A1+B1       ADDRESS OF OPTION
          SA3    A2+B1       GET RECALL PARAMETER ADDRESS 
          SA2    X2          OPTION 
          SA3    X3          GET RECALL VALUE 
          ZR     X2,CLO1     IF REWIND
          NO
          SA4    =0HNR
          BX4    X2-X4
          ZR     X4,CLO2     IF NR
          SA4    =0HREWIND
          BX4    X2-X4
          ZR     X4,CLO1     IF REWIND
          SA4    =0HUNLOAD
          BX4    X2-X4
          ZR     X4,CLO3     IF UNLOAD
          SA1    =0LCLOSER
          RJ     =XMACREL=   DIAGNOSE ILLEGAL ARGUMENT
          EQ     CLOSERX
  
 CLO1     NZ     X3,CLO4     IF RECALL
          CLOSER X1 
          EQ     CLOSERX
  
 CLO2     NZ     X3,CLO5     IF RECALL
          CLOSER X1,NR
          EQ     CLOSERX
  
 CLO3     NZ     X3,CLO6     IF RECALL
          CLOSER X1,UNLOAD
          EQ     CLOSERX
  
 CLO4     CLOSER X1,,R
          EQ     CLOSERX
  
 CLO5     CLOSER X1,NR,R
          EQ     CLOSERX
  
 CLO6     CLOSER X1,UNLOAD,R
          EQ     CLOSERX
  
          END 
