*COMDECK CLOSE
          IDENT  CLOSE
          ENTRY  CLOSE
          SYSCOM B1 
          TITLE  CLOSE - CLOSE FILE.
          COMMENT CLOSE FILE. 
          COMMENT COPYRIGHT CONTROL DATA CORP. 1978.
 CLOSE    SPACE  4,10 
***       CLOSE - CLOSE FILE. 
* 
*         CALL CLOSE (FILE,OPTION,R)
* 
*         ENTRY  (FILE) = FIRST WORD OF THE FET.
*                (OPTION) = 0, CLOSE WITH REWIND. 
*                         = 2HNR, CLOSE WITHOUT REWIND. 
*                         = 6HRETURN, CLOSE WITH REWIND, RETURN.
*                         = 6HREWIND, CLOSE WITH REWIND.
*                         = 6HUNLOAD, CLOSE WITH REWIND, UNLOAD.
*                (R) = RECALL, IF .NE. 0, RECALL IS REQUESTED.
* 
*         CLOSE(FILE,OPTION,R); (*SYMPL* CALL)
* 
*         ENTRY   FILE, AN ARRAY THAT CONTAINS THE FET. 
*                 OPTION, AN ITEM CONTAINING ONE OF THE FOLLOWING 
*                         CHARACTER STRINGS, LEFT JUSTIFIED, BLANK
*                         FILL, OR A BINARY 0.
*                            NR  (NO REWIND). 
*                            RETURN.
*                            REWIND (SAME AS 0).
*                            UNLOAD.
*                (R) = RECALL, IF .NE. 0, RECALL IS REQUESTED.
* 
*         EXIT   TO ARGUMENT-ERROR PROCESSOR IF OPTION IS UNRECOGNIZED. 
* 
*         USES   X - 2, 3, 4. 
*                A - 2, 3, 4. 
*                B - 1. 
* 
*         CALLS MACREL. 
* 
*         MACROS CLOSE. 
  
  
 CLOSE    SUBR               ENTRY/EXIT 
          SB1    1
          SA2    A1+B1       ADDRESS OF OPTION
          SA3    A2+B1       GET ADDRESS OF RECALL PARAMETER
          SA2    X2          OPTION 
          SA3    X3          RECALL OPTION
          ZR     X2,CLO1     IF REWIND
          NO
          SA4    =0HNR
          BX4    X2-X4
          ZR     X4,CLO2     IF NR
          SA4    =0HRETURN
          BX4    X2-X4
          ZR     X4,CLO6     IF RETURN
          SA4    =0HREWIND
          BX4    X2-X4
          ZR     X4,CLO1     IF REWIND
          SA4    =0HUNLOAD
          BX4    X2-X4
          ZR     X4,CLO8     IF UNLOAD
          SA1    =0LCLOSE 
          RJ     =XMACREL=   DIAGNOSE ILLEGAL ARGUMENT
          EQ     CLOSEX 
  
 CLO1     NZ     X3,CLO5     IF RECALL
          CLOSE  X1 
          EQ     CLOSEX 
  
 CLO2     NZ     X3,CLO6     IF RECALL
          CLOSE  X1,NR
          EQ     CLOSEX 
  
 CLO3     NZ     X3,CLO7     IF RECALL
          CLOSE  X1,RETURN
          EQ     CLOSEX 
  
 CLO4     NZ     X3,CLO8     IF RECALL
          CLOSE  X1,UNLOAD
          EQ     CLOSEX 
  
 CLO5     CLOSE  X1,,R
          EQ     CLOSEX 
  
 CLO6     CLOSE  X1,NR,R
          EQ     CLOSEX 
  
 CLO7     CLOSE  X1,RETURN,R
          EQ     CLOSEX 
  
 CLO8     CLOSE  X1,UNLOAD,R
          EQ     CLOSEX 
  
          END 
