*COMDECK BKSPRU 
          IDENT  BKSPRU 
          ENTRY  BKSPRU 
          SYSCOM B1 
          TITLE  BKSPRU - BACKSPACE PHYSICAL RECORDS. 
          COMMENT BACKSPACE PHYSICAL RECORDS. 
          COMMENT COPYRIGHT CONTROL DATA CORP. 1978.
 BKSPRU   SPACE  4,10 
***       BKSPRU - BACKSPACE PHYSICAL RECORDS.
* 
*         CALL BKSPRU (FILE,N,R)
* 
*         ENTRY  (FILE) = FIRST WORD OF THE FET.
*                (N) = NUMBER OF RECORDS. 
*                (R) = RECALL, IF .NE. 0, RECALL IS REQUESTED.
* 
*         BKSPRU(FILE,N,R);  (*SYMPL* CALL) 
* 
*         ENTRY  FILE, AN ARRAY THAT CONTAINS THE FET.
*                (N) = AN ITEM CONTAINING THE NUMBER OF PRU*S TO
*                      BACKSPACE
*                (R) = RECALL,IF .NE. 0, RECALL IS REQUESTED. 
* 
*         USES   X - 2, 3.
*                A - 2, 3.
*                B - 1. 
* 
*         MACROS BKSPRU.
* 
  
  
 BKSPRU   SUBR               ENTRY/EXIT 
          SB1    1
          SA3    A1+B1       ADDRESS OF N 
          SA2    A3+B1       GET RECALL PARAMETER 
          SA3    X3          N
          SA2    X2 
          NZ     X2,BKP1     IF RECALL REQUESTED
          BKSPRU X1,X3
          EQ     BKSPRUX
  
 BKP1     BKSPRU X1,X3,R
          EQ     BKSPRUX
  
          END 
