*DECK RBF 
JOBRBF
*IF -DEF,SVL,1
TITLE(JOB) JOBRBF - RBF RELEASE DEFAULT JOB SKELETON. 
*IF DEF,SVLC,1
TITLE(JOB) JOBRBF - RBF SUNNYVALE CLOSED SHOP DEFAULT JOB SKELETON. 
*IF DEF,SVLD,1
TITLE(JOB) JOBRBF - RBF SUNNYVALE DEVELOPMENT DEFAULT JOB SKELETON. 
.*
.*
.*  THIS IS THE STARTUP JOB FOR RBF.
.*
.*    THIS RECORD MUST BE ADDED TO THE NAMSTRT FILE FOR RBF 
.*    TO BE STARTED WITH THE REST OF THE NETWORK. 
.*
.*    STATEMENTS OF THE FORM
.*               JOB(JOBRBF,RB,RBF) 
.*    MUST BE ADDED TO ALL PARAMETER RECORDS TO SELECT THIS RECORD
.*    TO BE PROCESSED BY NAMI AND SUBMITTED TO START RBF. 
.*
.*    THE PERMANENT FILES THAT RBF DUMPS AND TRACES ARE WRITTEN TO
.*    WILL BE COLLECTED BY THE COLLECTOR JOB ALONG WITH THE 
.*    REST OF THE THE NETWORK TRACES AND DUMPS. 
.*
.*
.*  THE FOLLOWING PARAMETERS MUST BE SET IN THE PARAMETER RECORD. 
.*
.*    ZZMC = MESSAGE COUNT BEFORE RELEASE OF TRACE FILE.
.*
.*    ZZRUNCT = MAXIMUM NUMBER OF EXECUTION RUNS OF RBF 
.*              WITHOUT OPERATOR INTERVENTION.
.*
.*
.*  PERMANENT FILES FOR RUN DATA ARE DEFINED AT JOB TERMINATION.
.*
.*       TFN       LFN       PFN       CONTENTS 
.*
.*       OUTPUT    RBFOUT    RBD0FIL   OUTPUT FROM JOB (DMP,DMD,ETC). 
.*       ZZZZDMB   RBFDMB    RBD2FIL   BINARY FIELD LENGTH DUMPS. 
.*                 RBFLST    RBL0FIL   FILE *SPITOUT* AND JOB DAYFILE.
.*       ZZZZZSN   RBFSTAT   RBS0FIL   AIP STATISTICS FILE. 
.*       ZZZZZDN   TRCLEV1             AIP TRACE FILE WRITTEN BY RBF. 
.*                 TRCLEV2   ZZRBFIL   INTERMEDIATE AIP TRACE FILE. 
.*                 TRCLEV3   RBT0FIL   PERMANENT AIP TRACE FILE.
.*
.*
.*
*IF -DEF,SVL,1
RBF_CIN,T77777.    RBF RELEASE DEFAULT JOB. 
*IF DEF,SVLC,1
RBF_CIN,T77777.    RBF SUNNYVALE CLOSED SHOP DEFAULT JOB. 
*IF DEF,SVLD,1
RBF_CIN,T77777.    RBF SUNNYVALE DEVELOPMENT DEFAULT JOB. 
USER(UNM,PWM) 
NORERUN.
*IF DEF,SVL,1 
DTSET.*  TODAY IS WWW MMDDYY, SN = SSS. 
*IF -DEF,SVL,2
DISPLAY(DATE) 
DISPLAY(HID)
DISPLAY(OT) 
DISPLAY(SC) 
RETURN(OUTPUT)
.*
.*  SET UP NRF FILES. 
.*
COPYBR(INPUT,NRF1)
COPYBR(INPUT,NRF2)
.*
.*  INITIALIZE RBF FL ROLLOUT FILE. 
.*
WRITER(RBFROLL) 
.*
.*  PURGE OLD LEVEL-2 TRACE FILES.
.*
PURGE(ZZRB_OIN,ZZRB_CIN/NA) 
.*
.*  LOOP RESTARTING RBF UNTIL NORMAL TERMINATION OR NAM ABORTS. 
.*  ALSO STOP FOR CERTAIN SYSTEM ERRORS.
.*
SET(R1=ZZRUNCT) 
WHILE(1,LOOP1)
SET(EF=0) 
RFL(50000)
RBF2P0(MC=ZZMC) NIN=CIN 
.*
.*  RBF NORMAL TERMINATION - CHECK FOR PREVIOUS FAILURE.
.*
RFL(0)
SKIP(BAILOUT) 
.*
EXIT.  RBF
.*
.*
.*  RBF FAILED - CHECK IF LOOP OR QUIT. 
.*
.*
DISPLAY(EF) 
RFL(0)
IF(EF.NE.ODE,SAVFILS) 
IF(EF.NE.DRE,SAVFILS) 
IF(EF.NE.SSE,SAVFILS) 
IF(EF.NE.SYE,BAILOUT) 
IF(EF.NE.RAE,SAVFILS) 
IF(EF.NE.ORE,SAVFILS) 
IF(R1.GT.1,SAVFILS) 
SET(R1=R1-1)
.*
.*  WILL LOOP - SAVE TRACE DATA IF AVAILABLE. 
.*
ATTACH(TRCLEV2=ZZRB_CIN/NA) 
IF(FILE(TRCLEV2,AS),NTRCLV2)
SKIPR(TRCLEV2)
IF(.NOT.FILE(TRCLEV2,EOF))  REWIND(TRCLEV2) 
ELSE(NTRCLV2) 
IF(FILE(ZZZZZDN,AS),NOTRACE)
ENDIF(NTRCLV2)
ATTACH(TRCLEV3=RBT0FIL/NA,M=W)
*IF DEF,SVL,1 
IF(.NOT.FILE(TRCLEV3,AS))  DEFINE(TRCLEV3=RBT0FIL/CT=PU)
*IF -DEF,SVL,1
IF(.NOT.FILE(TRCLEV3,AS))  DEFINE(TRCLEV3=RBT0FIL)
SKIPEI(TRCLEV3) 
COPYEI(TRCLEV2,TRCLEV3) 
PURGE(ZZRB_CIN/NA)
IF(FILE(ZZZZZDN,AS),NTRCLV1)
RENAME(TRCLEV1=ZZZZZDN) 
REWIND(TRCLEV1) 
IF(ZZMC.NE.0)  SKIPR(TRCLEV1) 
COPYBF(TRCLEV1,TRCLEV3) 
BKSP(TRCLEV3) 
SKIPR(TRCLEV3)
IF(.NOT.FILE(TRCLEV3,EOF))  WRITEF(TRCLEV3) 
ENDIF(NTRCLV1)
RETURN(TRCLEV1,TRCLEV2,TRCLEV3) 
ENDIF(NOTRACE)
.*
ENDW(LOOP1) 
.*
.*  END OF AUTO RESTART SECTION.
.*
ENDIF(BAILOUT)
IF(R1.EQ.ZZRUNCT,SAVFILS) 
ATTACH(RBFLST=RBL0FIL/NA) 
IF(.NOT.FILE(RBFLST,AS),SAVFILS)
.*
.*  NO PREVIOUS FAILURE, DO NOT SAVE RUN DATA ON PERMANENT FILES. 
.*
PURGE(RBT0FIL,ZZRB_CIN/NA)
SETJOB(DC=NO) 
EXIT.  RBF
.*
.*  SAVE RUN DATA IF AVAILABLE. 
.*
ENDIF(SAVFILS)
.*
IF(FILE(OUTPUT,AS),NOUTPUT) 
ATTACH(RBFOUT=RBD0FIL/NA,M=W) 
*IF DEF,SVL,1 
IF(.NOT.FILE(RBFOUT,AS))  DEFINE(RBFOUT=RBD0FIL/CT=PU)
*IF -DEF,SVL,1
IF(.NOT.FILE(RBFOUT,AS))  DEFINE(RBFOUT=RBD0FIL)
REWIND(OUTPUT)
SKIPEI(RBFOUT)
COPYEI(OUTPUT,RBFOUT) 
RETURN(OUTPUT,RBFOUT) 
ENDIF(NOUTPUT)
.*
IF(FILE(ZZZZDMB,AS),NOZZDMB)
ATTACH(RBFDMB=RBD2FIL/NA,M=W) 
*IF DEF,SVL,1 
IF(.NOT.FILE(RBFDMB,AS))  DEFINE(RBFDMB=RBD2FIL/CT=PU)
*IF -DEF,SVL,1
IF(.NOT.FILE(RBFDMB,AS))  DEFINE(RBFDMB=RBD2FIL)
REWIND(ZZZZDMB) 
SKIPEI(RBFDMB)
COPYEI(ZZZZDMB,RBFDMB)
RETURN(ZZZZDMB,RBFDMB)
ENDIF(NOZZDMB)
.*
IF(FILE(ZZZZZSN,AS),NOSTATS)
ATTACH(RBFSTAT=RBS0FIL/NA,M=W)
*IF DEF,SVL,1 
IF(.NOT.FILE(RBFSTAT,AS))  DEFINE(RBFSTAT=RBS0FIL/CT=PU)
*IF -DEF,SVL,1
IF(.NOT.FILE(RBFSTAT,AS))  DEFINE(RBFSTAT=RBS0FIL)
REWIND(ZZZZZSN) 
SKIPEI(RBFSTAT) 
COPYEI(ZZZZZSN,RBFSTAT) 
RETURN(ZZZZZSN,RBFSTAT) 
ENDIF(NOSTATS)
.*
ATTACH(TRCLEV2=ZZRB_CIN/NA) 
IF(FILE(TRCLEV2,AS),NTRCLV2)
SKIPR(TRCLEV2)
IF(.NOT.FILE(TRCLEV2,EOF))  REWIND(TRCLEV2) 
ELSE(NTRCLV2) 
IF(FILE(ZZZZZDN,AS),NOTRACE)
ENDIF(NTRCLV2)
ATTACH(TRCLEV3=RBT0FIL/NA,M=W)
*IF DEF,SVL,1 
IF(.NOT.FILE(TRCLEV3,AS))  DEFINE(TRCLEV3=RBT0FIL/CT=PU)
*IF -DEF,SVL,1
IF(.NOT.FILE(TRCLEV3,AS))  DEFINE(TRCLEV3=RBT0FIL)
SKIPEI(TRCLEV3) 
COPYEI(TRCLEV2,TRCLEV3) 
PURGE(ZZRB_CIN/NA)
IF(FILE(ZZZZZDN,AS),NTRCLV1)
RENAME(TRCLEV1=ZZZZZDN) 
REWIND(TRCLEV1) 
IF(ZZMC.NE.0)  SKIPR(TRCLEV1) 
COPYBF(TRCLEV1,TRCLEV3) 
BKSP(TRCLEV3) 
SKIPR(TRCLEV3)
IF(.NOT.FILE(TRCLEV3,EOF))  WRITEF(TRCLEV3) 
ENDIF(NTRCLV1)
RETURN(TRCLEV1,TRCLEV2,TRCLEV3) 
ENDIF(NOTRACE)
.*
ATTACH(RBFLST=RBL0FIL/NA,M=W) 
*IF DEF,SVL,1 
IF(.NOT.FILE(RBFLST,AS))  DEFINE(RBFLST=RBL0FIL/CT=PU)
*IF -DEF,SVL,1
IF(.NOT.FILE(RBFLST,AS))  DEFINE(RBFLST=RBL0FIL)
REWIND(SPITOUT) 
SKIPEI(RBFLST)
COPYEI(SPITOUT,RBFLST)
NOTE(DFL,NR)/RBDA_CIN 
DAYFILE(DFL)
PACK(DFL) 
COPYEI(DFL,RBFLST)
.*
*IF DEF,SVL 
IF(EF.NE.0,DONE)
IF(EF.NE.ODE,DONE)
IF(EF.NE.DRE,DONE)
IF(EF.NE.SSE,DONE)
IF(EF.NE.SYE,DONE)
IF(EF.NE.RAE,DONE)
IF(EF.NE.ORE,DONE)
PAUSE.**RBF FAILED-NOTE/X.NAMI(RS=RBF)
ENDIF(DONE) 
*ENDIF
SETJOB(DC=NO) 
EXIT.  RBF
.EOR
.*
.*
.*  THIS JOB IS SUBMITTED EVERY ZZMC MESSAGES TO PLACE
.*    THE TRACE INFORMATION FROM THE PROGRAM (LEVEL 1) ONTO 
.*    THE INTERMEDIATE PERMANENT FILE ZZRB_CIN (LEVEL 2). 
.*
.*    IF ALL THAT HAPPENS IS THAT THIS JOB IS REPEATEDLY
.*    SUBMITTED THEN THE TRACE INFORMATION IS KEPT FOR
.*    ONLY THE LAST 2 TIMES ZZMC MESSAGES.
.*
.*    THIS CONSTRAINS THE SIZE OF THE TRACE FILE KEPT 
.*    WHEN THE NETWORK IS RUNNING WITHOUT ANY PROBLEMS. 
.*
.*
RBFA_CIN,T77777.     DUMP AIP TRACE TO ZZRB_CIN.
USER(UNM,PWM) 
ATTACH(TRCLEV2=ZZRB_CIN/M=W,NA) 
IF(FILE(TRCLEV2,AS),NTRCLV2)
SKIPF(TRCLEV2)
COPYBF(TRCLEV2,TEMP)
REWIND(TRCLEV2,TEMP)
COPYBF(TEMP,TRCLEV2)
ELSE(NTRCLV2) 
*IF DEF,SVL,1 
DEFINE(TRCLEV2=ZZRB_CIN/CT=PU)
*IF -DEF,SVL,1
DEFINE(TRCLEV2=ZZRB_CIN)
WRITEF(TRCLEV2) 
ENDIF(NTRCLV2)
COPYBF(INPUT,TRCLEV2) 
BKSP(TRCLEV2) 
SKIPR(TRCLEV2)
IF(.NOT.FILE(TRCLEV2,EOF))  WRITEF(TRCLEV2) 
SETJOB(DC=NO) 
EXIT.  RBFA 
.EOR
.*
.*
.*  THIS JOB IS SUBMITTED IN RESPONSE TO A
.*    *HOP RELEASE DEBUG LOGFILE* COMMAND.
.*
.*    THE PURPOSE OF THIS JOB IS TO SAVE ON THE LEVEL 3 PERMANENT 
.*    FILE *RBT0FIL* THE PREVIOUS 2 TIMES ZZMC MESSAGES 
.*    CURRENTLY IN THE INTERMEDIATE (LEVEL 2) FILE *ZZRB_CIN* 
.*    BEFORE WRITING THE NEW TRACE DATA (FROM LEVEL 1 FILE) 
.*    ON THE INTERMEDIATE (LEVEL 2) FILE. THIS WILL ALLOW THESE 
.*    TRACE MESSAGES TO BE COLLECTED AND WRITTEN TO TAPE. 
.*
.*
RBFB_CIN,T77777.     DUMP TO PERMANENT TRACE FILE.
USER(UNM,PWM) 
ATTACH(TRCLEV2=ZZRB_CIN/M=W,NA) 
IF(FILE(TRCLEV2,AS),NTRCLV2)
SKIPR(TRCLEV2)
IF(.NOT.FILE(TRCLEV2,EOF))  REWIND(TRCLEV2) 
ATTACH(TRCLEV3=RBT0FIL/NA,M=W)
*IF DEF,SVL,1 
IF(.NOT.FILE(TRCLEV3,AS))  DEFINE(TRCLEV3=RBT0FIL/CT=PU)
*IF -DEF,SVL,1
IF(.NOT.FILE(TRCLEV3,AS))  DEFINE(TRCLEV3=RBT0FIL)
SKIPEI(TRCLEV3) 
COPYEI(TRCLEV2,TRCLEV3) 
EVICT(TRCLEV2)
ELSE(NTRCLV2) 
*IF DEF,SVL,1 
DEFINE(TRCLEV2=ZZRB_CIN/CT=PU)
*IF -DEF,SVL,1
DEFINE(TRCLEV2=ZZRB_CIN)
ENDIF(NTRCLV2)
WRITEF(TRCLEV2) 
COPYBF(INPUT,TRCLEV2) 
BKSP(TRCLEV2) 
SKIPR(TRCLEV2)
IF(.NOT.FILE(TRCLEV2,EOF))  WRITEF(TRCLEV2) 
SETJOB(DC=NO) 
EXIT.  RBFB 
