*COMDECK RUA
 RUA      SPACE  4,14 
***       RUA    RESERVE USABLE AREA
* 
*              REQUESTS THE LARGEST POSSIBLE BLOCK OF MEMORY BETWEEN
*         DABA AND HHA. ROUTINE ASSUMES IT IS FIRST TO CALL CMM THIS OVL
* 
*         ENTRY  NONE 
* 
*         EXIT   (X6) =   30/FWA,30/LWA+1 OF USEABLE AREA 
*                (B1) = 1 
* 
*         CALLS  CMM.AGR, CMM.ALF 
 RUA      SPACE  4
          ENTRY  RUA
 RUA      SUBR                     **ENTRY/EXIT** 
          SX1    1                 (X1) = GROUP-TYPE FOR *BELOW HHA*
          RJ     =XCMM.AGR         ACTIVATE A GROUP-ID OF THIS TYPE 
          BX6    X2                (X6) = GROUP-ID ACTIVATED
          SA6    GROUPID
          BX3    X2 
          LX3    12D               (X3) = GROUP-ID POSITIONED FOR  .ALF 
          SA1    104B              (X1) = 42/STUFF,18/HHA 
          SA2    65B               (X2) = 42/STUFF,18/-DABA 
          SX1    X1                (X1) = 60/HHA
          SX2    X2                (X2) = 60/-DABA
          IX2    X1+X2             (X2) = NO. WORDS BETWEEN DABA, HHA 
          SX2    X2-20B            (X2) = NO. WORDS LESS CMM OVERHEAD 
          BX6    X2 
          SA6    UALENG            (X6) = NO. WORDS REQUESTED 
          RJ     =XCMM.ALF         ALLOCATE A FIXED BLOCK 
          BX6    X1                (X1) = FWA OF BLOCK ALLOCATED
          SA6    UAFWA
          SA2    UALENG            (X2) = NO. WORDS REQUESTED 
          IX2    X2+X6             (X2) = LWA+1 OF WORDS IN BLOCK 
          LX6    30D
          IX6    X2+X6             (X6) = 30/FWA,30/LWA+1 OF USEBLE AREA
          EQ     EXIT.
          SPACE  4
 GROUPID  DATA   0                 WILL HOLD GROUP-ID OF THE USEBLE AREA
          ENTRY  UALENG 
 UALENG   DATA   0                 WILL HOLD NO. WORDS IN USEABLE AREA
          ENTRY  UAFWA
 UAFWA    DATA   0                 WILL HOLD FWA OF USEABLE AREA
 FUA      SPACE  4,14 
***       FUA    FREE USEABLE AREA
* 
*              COMPANION TO -RUA-, THIS ROUTINE FREES THE BLOCK ALLOCATD
*         BY RUA. 
* 
*         ENTRY  NONE 
* 
*         EXIT   (B1) = 1 
* 
*         CALLS  CMM.FGR
 FUA      SPACE  4
          ENTRY  FUA
 FUA      SUBR                     **ENTRY/EXIT** 
          SA1    GROUPID           (X1) = GROUP-ID TO FREE
          ZR     X1,EXIT.          IF NO GROUP-ID TO FREE 
          RJ     =XCMM.FGR         FREE A GROUP 
          MX6    0
          SA6    GROUPID           (X6) = 0 FOR NO GROUP-ID LEFT TO FREE
          EQ     EXIT.
          SPACE  4
