*DECK QU1200
          IDENT  QU1200 
          COMMENT  INITIALIZATION OF OVERLAY 12-0 
QU1200    TITLE    QU1200 - INITIALIZATION OF OVERLAY 12-0
          ENTRY  QU1200 
          SST 
QU1200    DATA   0
          SA1    AUTOPSY
          SX6    A1                                                     000290
          SA6    =XAUTLOC                                               000300
          RJ     =XCOMPILE         COMPRESS REPORT TABLES 
*         ---    ---------- 
AUTOPSY   DATA   0           DO NOTHING OPERATION FOR THIS OVERLAY
          RJ     FUA         FREE USEABLE AREA BELOW HHA
          EQ     AUTOPSY
          LIST   -L    *CALL COSPACE FOLLOWS
          LIST   L
          LIST   -L          *CALL ENVIRON FOLLOWS
*CALL ENVIRON 
          LIST   L
          SPACE  3
* WRITEBR IS CALLED BY BINTAB WHEN THE COMPRESSED REPORT TABLES ARE 
*  READY TO BE WRITTEN OUT AS ONE RECORD.  THREE PARAMETERS ARE GIVEN.
*       LOGICAL FILE NAME 
*       RECORD LENGTH IN WORDS. 
*       ADDRESS OF THE RECORD TO WRITE. 
* 
*         *WRITEBR* BUILDS A FET WITH THE GIVEN PARAMETERS, SKIPS TO
*         EOI AND THEN WRITES THE DATA AS ONE RECORD. 
* 
*  THE COMPILE FILE IS DEFINED WITH S-TYPE RECORDS, SO THAT THE 
*  REPORT MODULE CAN ISSUE PARTIAL GET-S TO OBTAIN THE RECORDS. 
  
  
 WRITEBR  SUBR   =           ENTRY/EXIT 
          SB1    1
          SA2    A1+B1
          SA3    A2+B1       FWA OF DATA
          SA1    X1          FILE NAME
          SA2    X2          LENGTH 
          IX7    X2+X3       LWA+1 OF DATA
          SA4    FET
          SA5    A4+B1
          MX2    42 
          BX1    X2*X1
          BX4    -X2*X4 
          BX6    X1+X4
          SA6    A4          SET NAME INTO FET+0
          BX5    X2*X5
          BX6    X3+X5
          SA6    A4+B1       SET FWA IN FET+1 
          SX6    X3 
          SA6    A6+B1       SET IN = FWA 
          SA6    A6+B1       SET OUT = FWA
          SX7    X7+B1
          SA7    A6+B1       SET LIMIT = LWA+2
          SKIPEI A4,RCL      SKIP TO EOI
          SA4    FET+4
          SX6    X4-1 
          SA6    FET+2       SET IN = LWA+1 OF DATA 
          WRITER X2,RCL      WRITE THE RECORD 
          EQ     EXIT.
  
 FET      RFILEB FET,1       BUILD FET WITH DUMMY NAME, FWA AND LENGTH
*CALL RUA 
          SPACE  4
***       GETFL  GET CURRENT FL 
* 
*         ISSUES MEM REQUEST TO OBTAIN CURRENT FL 
*         PASSES FL TO CALLING ROUTINE THROUGH QUFL 
* 
  
          ENTRY QUFL
          ENTRY  GETFL
 QUFL     DATA   0           MEM WILL STORE FL HERE 
  
 GETFL    DATA   0           ENTRY/EXIT 
          MX6    0
          SA6    QUFL        REQUEST FOR CURRENT FL 
          MEMORY CM,QUFL,R   ISSUE REQUEST
          SA1    QUFL 
          AX1    30          RIGHT JUSTIFY FL 
          BX6    X1 
          SA6    A1 
          EQ     GETFL       EXIT 
          END    QU1200 
