*DECK,QU0500
          IDENT  QU0500 
          COMMENT  INITIALIZATION OF OVERLAY 5-0
QU0500    TITLE    QU0500 - INITIALIZATION OF OVERLAY 5-0 
          LIST   F
          LIST   -L          *CALL ENVIRON
*CALL ENVIRON 
          LIST   L
          LIST   -L          *CALL BASIC
*CALL BASIC 
          LIST   L
          LIST   -L          *CALL MACRO
*CALL MACRO 
          LIST    L 
          LIST   -L                * CALL TO NUMOPT FOLLOWS * 
*CALL NUMOPT
          LIST   L
          SPACE  4,10 
**        CAPSULE LIST FOR (5,0).                                       002000
                                                                        002100
                                                                        002200
 CAPLIST  BSS    0                                                      002300
          CAPSULE CDCSREQ    PERFORM CDCS OBJECT ROUTINES 
          CAPSULE OPNCAT     OPEN CATALOG FILE                          002400
          CAPSULE RTNSSCM    RETURN CM AFTER FATAL CDCS ERROR 
          CON    0           END OF LIST                                002500
          SPACE  4,8                                                    002600
**        CAPSULE ENTRY POINTS.                                         002700
                                                                        002800
                                                                        002900
 CDCSREQ  INCAP  CDCSREQ,QU0500 
 DB.CLS   INCAP  CDCSREQ,QU0500 
 DB.DBST  INCAP  CDCSREQ,QU0500 
 DB.END   INCAP  CDCSREQ,QU0500 
 DB.INQV  INCAP  CDCSREQ,QU0500 
 DB.INVV  INCAP  CDCSREQ,QU0500 
 OPNCAT   INCAP  OPNCAT,QU0500                                          003000
 REQPF    INCAP  OPNCAT,QU0500                                          003100
 RTNSSCM  INCAP  RTNSSCM,QU0500 
          SPACE  4,8                                                    003200
**        ENTRY POINT PASSLOC LIST FOR (5,0).                           003300
                                                                        003400
                                                                        003500
 ENTLIST  PASSLOC            BUILD (5,0) ENTRY POINT PASSLOC TABLE      003600
          SPACE  4,8                                                    003700
**        EXTERNAL PASSLOC LIST FOR (5,0).
  
  
          PASS   CATCHK,X    REQUIRED BY CAPSULE *OPNCAT*               003900
          PASS   CDCSCAT,X   REQUIRED BY CAPSULE *OPNCAT*               004000
          PASS   CLOSEM,X    REQUIRED BY CAPSULE *OPNCAT* AND *RTNSSCM* 
          PASS   CMM$FGR,X   REQUIRED BY CAPSULE *RTNSSCM*
          PASS   ER$SRM,X    REQD BY *CDCSREQ* - KLUGE FOR LOADER PSR 
          PASS   OPENM,X     REQUIRED BY CAPSULE *OPNCAT*               004300
          PASS   PUT,X       REQUIRED BY CAPSULE *OPNCAT*               004400
          PASS   RETURNM,X   REQUIRED BY CAPSULE *OPNCAT* AND *RTNSSCM* 
          PASS   RTNSSCM,X   REQUIRED BY CAPSULE *CDCSREQ*
 EXTLIST  PASSLOC            BUILD (5,0) EXTERNAL PASSLOC TABLE 
 QU0500   SPACE  4,10 
          ENTRY  QU0500 
QU0500    JP     *+400000B
          MX6    0           NO *AUTOPSY* ADDRESS WHILE IN (5,0)         QU0500 
          SA6    =XAUTLOC                                               000340
          SA1    P1          PARAMETER LIST 
          RJ     =XQU.LNK    LINK UP ALTERNATE CAPSULE LISTS
          SA1    LOADPM      ENTER (5,1) OVERLAY                         QU0500 
          RJ     =XLOADOVL                                               QU0500 
*         --                 EXIT FROM (5,0) VIA OVERLAY LOAD            QU0500 
                                                                         QU0500 
                                                                         QU0500 
 LOADPM   BSS    0           PARAMETER FOR (5,1) LOAD                    QU0500 
+         VFD    60/*        UNUSED *LOADOVL* PARAMETER                  QU0500 
+         VFD    60/FIVE                                                 QU0500 
+         VFD    60/ONE                                                  QU0500 
 FIVE     CON    5                                                       QU0500 
 ONE      CON    1                                                       QU0500 
                                                                         QU0500 
                                                                         QU0500 
 P1       VFD    60/CAPLIST  ALTERNATE CAPSULE LIST                     004700
          VFD    60/ENTLIST  ALTERNATE ENTRY POINT PASSLOC LIST         004800
          VFD    60/EXTLIST  ALTERNATE EXTERNAL PASSLOC LIST
         SPACE  3 
          SPACE  3
*  THIS IS THE FIT FOR THE SUB-SCHEMA FILE
*  IT IS COPIED BY THE SYMPL PROCEDURE -USE-
*  FOR ACCESSING THE SUB-SCHEMA FILE
          ENTRY    SCFIT
          ENTRY    SCSIZE 
          SPACE    1
 SCFIT    FILE   FO=WA,RT=U,MRL=510,BFS=102,EFC=3 
SCSIZE    VFD      60/*-SCFIT 
          SPACE  5
          ENTRY  WENDFIL
*  WRITE AN END OF PARTITIONON THE PERM LOG FILE
 WENDFIL  BSS    1
          ENDFILE    X1 
          EQ     WENDFIL
          IFEQ   OS$NAME,KRONOS 
          SPACE  2
          ENTRY  LJUST
*  LEFT JUSTIFIES AN FDB PARAMETER VALUE...RETURNS VALUE AS FUNCTION
 LJUST    JP     *+400000B
          SA1    X1          (X1) = FDB PF PARAMETER TO LEFT JUSTIFY
          MX0    -6 
          BX6    -X0*X1      (X6) = SAVED KEYWORD VALUE 
          BX1    X0*X1       CLEAR THE KEYWORD FIELD
          ZR     X1,LJUST2   IF BINARY ZERO VALUE 
          MX0    6
 LJUST1   BX2    X0*X1       TOP CHARACTER
          NZ     X2,LJUST2   IF LEFT JUSTIFIED
          LX1    6
          EQ     LJUST1 
  
 LJUST2   MX0    42 
          BX1    X0*X1       TRUNCATE TO SEVEN CHARS
          BX6    X6+X1       MERGE WITH KEYWORD VALUE TO FORM RESULT
          EQ     LJUST
          ENDIF 
          SPACE  5
          IFEQ   OS$NAME,SCOPE
          ENTRY   CATALOG                                               005250
 CATALOG  DATA    0                                                     005260
          SX3     20B                                                   005270
          SA2     CATAL                                                 005280
          RJ      PFIO                                                  005290
          EQ      CATALOG                                               005300
          SPACE  3
          ENTRY   EXTEND                                                005310
 EXTEND   DATA    0                                                     005320
          SA2     EXT                                                   005330
          SX3     30B                                                   005340
          RJ      PFIO                                                  005350
          EQ      EXTEND                                                005360
 PFIO     DATA    0                                                     005370
          SX1    X1+4        LOCATE LFN ADDRESS IN FDB
          BX7     X2+X1                                                 005380
          SA4     A1+1                                                  005390
          BX6     X4                                                    005400
          SA6     RTNADDR                                               005410
          SA1     X1                                                    005420
          SA5     TERMINAL                                              005430
          ZR      X5,BATCHMO                                            005440
          SX3     X3+200B                                               005450
 BATCHMO  BSS     0                                                     005460
          MX0     42                                                    005470
          BX0     X0*X1                                                 005480
          BX6     X0+X3                                                 005490
          SA6     A1                                                    005500
          SB1     1                                                     005510
+         SA5     B1                                                    005520
          NZ      X5,*                                                  005530
          SA7     B1                                                    005540
          SA5    66B
          PL     X5,NOXJ
          XJ
* 
NOXJ      BSS    0
+         SA5     B1                                                    005550
          NZ      X5,*                                                  005560
          SA2     A1                                                    005570
          BX7     X2                                                    005580
          AX2     9                                                     005590
          MX0     51                                                    005600
          BX6     -X0*X2                                                005610
          SA2     RTNADDR                                               005620
          SA6     X2                                                    005630
          EQ      PFIO                                                  005640
 CATAL    VFD     18/3LPFC,2/1,40/0                                     005650
 EXT      VFD     18/3LPFE,2/1,40/0                                     005660
 RTNADDR  BSSZ    1                                                     005670
          SPACE  3
          ENTRY   WAIT                                                  005680
* ROUTINE TO W IT A GIVEN NO. OF SECONDS                                005690
 WAIT     BSS     1                                                     005700
          SA1     A1                                                    005710
          SA1     X1                                                    005720
          BX6     X1      PICK UP NUMBER OF SECONDS                     005730
          LX6     12                                                    005740
          SA6    WAITIME     (X6) IS NUMBER OF SECONDS TO WAIT
          RTIME   BEGTIME                                               005760
 WT10     RTIME   NEXTIME    READ TIME                                  005770
          SA1     BEGTIME                                               005780
          SA2     NEXTIME                                               005790
          IX2      X2-X1                                                005800
          SA3    WAITIME     (X3) IS NUMBER OF SECONDS TO WAIT
          IX3     X3-X2                                                 005820
          PL      X3,WT10                                               005830
          EQ      WAIT   RETURN                                         005840
          SPACE   1                                                     005850
 BEGTIME  BSS     1                                                     005870
 NEXTIME  BSS     1                                                     005880
WAITIME   BSS    1           HOLDS NUMBER OF SECONDS TO WAIT
          ENDIF 
          SPACE  3
          LIST   -L     *CALL COSPACE FOLLOWS. SEE LISTING IN QU10
          LIST   L
          ENTRY  RETURNM
 RETURNM  DATA   0
          SX2    174B              RETURN/UNLOAD CIO CODE 
          RJ     CALLCIO           GO PROCESS THE REQUEST(S)
+         EQ     RETURNM           EXIT 
* 
* 
          ENTRY REWINDM 
REWINDM   DATA   0                 ENTRY TO REWIND A LIST OF FILES
          SX2    50B               REWIND CIO CODE
          RJ     CALLCIO
+         EQ     REWINDM           EXIT 
* 
* 
CALLCIO   DATA   0
          BX6    X2 
          SA6    SAVCODE           SAVE THE CIO CODE FOR ALL REQUESTS 
          SX6    A1                GO GET PARAMETER LIST
          SA6    PARAMLT           LIMIT
          SX6    1                 AND
          SA6    PARAMCT           COUNT
CHKLOOP ZR X1,CALLCIO 
          SA1    X1 
          MX0    42                MASK FOR LFN 
          BX6    X0*X1             NASK JUST 7 CHAR 
          SA2    SAVCODE           GET THE CIO CODE TO BE DONE ON THIS L
          BX6    X6+X2             MERGE IN CIO CODE
          SA6    DUMYFET
          SX6    DUMYFET
          SA5    CIOP 
          BX6    X6+X5
          EXT    CIOWD
          SA6    CIOWD
          RJ     =XCIOREQ      GO DO AN RA+1 REQUEST
          SA2    PARAMCT           GET LIST POINTERS
          SA3    PARAMLT
          IX1    X2+X3             UPDATE 
          SA1    X1 
          SX6    X2+1 
          SA6    A2                AND
          EQ     CHKLOOP           LOOP FOR MORE LFN-S
CIOP      VFD    18/3LCIO,3/2,39/0
SAVCODE   BSSZ   1
 PARAMLT  BSS     1                                                     006280
 PARAMCT  BSS     1                                                     006290
 DUMYFET  BSS     1                                                     006300
          DATA    100B    FIRST                                         006310
          DATA    100B    IN                                            006320
          DATA    101B    OUT                                           006330
          DATA    200B    LIMIT                                         006340
          SPACE  3,5                                                    005000
***       AVOID PULLING IN THE FTN INTERFACE TO CRM FOR THIS FUNCTION.  005100
                                                                        005200
          ENTRY  SKIPB1                                                 005300
 SKIPB1   EQ     *+1S17                                                 005400
          SKIPBL  X1,1       SKIP BACK 1 LOGICAL RECORD                 005500
          EQ     SKIPB1                                                 005600
*CALL ATTACH
  
  
  
          END    QU0500 
