*DECK,QU0100
          IDENT  QU0100 
          COMMENT  INITIALIZATION OF OVERLAY 1-0
QU0100    TITLE    QU0100 - INITIALIZATION OF OVERLAY 1-0 
          TITLE     INITIALIZATION OF OVERLAY 1-0.         (OVERLAY 1,0)
          ENTRY  QU0100 
          LIST   F
          EXT    SYNTAX      ENTRY POINT TO SYNTAX ANALYSIS.
          EXT    QUIWSA      FWA OF WSA FOR SAVING SOURCE AND PTRS. 
*CALL ENVIRON 
          LIST   -L                * CALL TO MACRO FOLLOWS *
*CALL MACRO 
          LIST   L
          LIST   -L                * CALL TO NUMOPT FOLLOWS * 
*CALL NUMOPT
          LIST   L
QU0100    JP     *+400000B
          RJ     INIT10 
          RJ     SYNTAX      BEGIN SYNTAX ANALYSIS. 
                             THE RETURN FROM (1,0) IS DONE BY A CALL
                             FROM SYNTAX TO LOADX0 IN (0,0).
          ABORT              ABORT IF RETURN IS DONE HERE.
          SPACE  3                                                      000130
          SPACE  5
          SPACE  3                                                      001970
          ENTRY  RETURNM
 RETURNM  DATA   0
          SX2    174B              RETURN/UNLOAD CIO CODE 
          RJ     CALLCIO           GO PROCESS THE REQUEST(S)
+         EQ     RETURNM           EXIT 
* 
* 
          ENTRY REWINDM 
REWINDM   DATA   0                 ENTRY TO REWIND A LIST OF FILES
          SX2    50B               REWIND CIO CODE
          RJ     CALLCIO
+         EQ     REWINDM           EXIT 
* 
* 
CALLCIO   DATA   0
          BX6    X2 
          SA6    SAVCODE           SAVE THE CIO CODE FOR ALL REQUESTS 
          SX6    A1                GO GET PARAMETER LIST
          SA6    PARAMLT           LIMIT
          SX6    1                 AND
          SA6    PARAMCT           COUNT
CHKLOOP ZR X1,CALLCIO 
          SA1    X1 
          MX0    42                MASK FOR LFN 
          BX4    X0*X1             MASK JUST 7 CHARACTERS                QU3A351
          SA2    =XTPROCES
          ZR     X2,CHKLOOP1       IF NO TRACE FILE 
          SA2    =XTFILE           (X2) = WORD 0 OF TRACE FILE FET
          BX3    X0*X2             (X3) = LFN OF TRACE FILE 
          BX3    X4-X3                                                   QU3A351
          NZ     X3,CHKLOOP1       IF NOT CALLED TO REW/RET TRACE FILE
          RECALL A2                WAIT FOR FILE NOT BUSY                QU3A351
          SA2    A2+2              (X2) = IN POINTER FOR TRACE FILE 
          SX7    X2 
          SA7    A2+1              STORE AS IN=OUT, OR, BUFFER EMPTY
 CHKLOOP1 SA2    SAVCODE           GET CIO CODE FOR THIS LFN
          BX6    X4+X2             MERGE IN CIO CODE                     QU3A351
          SA6    DUMYFET
          SX6    DUMYFET
          SA5    CIOP 
          BX6    X6+X5
          EXT    CIOWD
          SA6    CIOWD
          RJ     =XCIOREQ       GO DO AN RA+1 REQUEST 
          SA2    PARAMCT           GET LIST POINTERS
          SA3    PARAMLT
          IX1    X2+X3             UPDATE 
          SA1    X1 
          SX6    X2+1 
          SA6    A2                AND
          EQ     CHKLOOP           LOOP FOR MORE LFN-S
CIOP      VFD    18/3LCIO,3/2,39/0
 DUMYFET  BSS     1                                                     006300
          DATA    100B    FIRST                                         006310
          DATA    100B    IN                                            006320
          DATA    101B    OUT                                           006330
          DATA    200B    LIMIT                                         006340
INIT10    JP     *+400000B        ONE TIME INITIALIZATION FOR (1,0) 
          SX6    =XAUTOPSY
          SA6    =XAUTLOC 
          SA1    P1 
          RJ     =XQU.LNK    LINK UP ALTERNATE CAPSULE LISTS
          EQ     INIT10 
          ENTRY  UPNFIT 
 UPNFIT   FILE   FO=SQ,BT=C,RT=F,BFS=601B,EFC=3 
  
          SPACE  4
**        XSETFIT 
* 
*         USE SETFIT MACRO TO READ FILE CARD INFORMATION
* 
          ENTRY  XSETFIT
 XSETFIT  JP     *+400000B
          SETFIT X1 
          EQ     XSETFIT
  
  
  
PARAMLT   BSS    1
PARAMCT   BSS    1
          SPACE  3
TEMP      BSS    0
SAVEADD   BSS    0
SAVCODE   BSS    0
 P1       CON    CAPLIST     ALTERNATE CAPSULE LIST 
          CON    ENTLIST     ALTERNATE ENTRY POINT PASSLOC LIST 
          CON    EXTLIST     ALTERNATE EXTERNAL PASSLOC LIST
          SPACE  4,10 
**        CAPSULE LIST FOR (1,0). 
  
  
 CAPLIST  BSS    0
          CAPSULE CDCSNAM    FIND CDCS DB ITEM AND BUILD INDEX TABLE
          CAPSULE CDCSREQ    PERFORMS CDCS ROUTINES 
          CAPSULE CRMNAME    SEARCH CRM SUBSCHEMA FOR DATA NAME 
          CAPSULE CUMFUNC    CUMULATIVE FUNCTIONS SYNTAX PROCESSOR
          CAPSULE EXPANAL    EXPRESSION ANALYSIS
          CAPSULE EXPEVAL    EXPRESSION EVALUATION
          CAPSULE IMFDICT    IMF DICTIONARY (METADB TABLE LOOKUP) 
          CAPSULE IMFRUN     IMF RUN-TIME ROUTINES
          CAPSULE OPNCAT     OPEN CATALOG FILE
          CAPSULE PEREXEC    *PERFORM* EXECUTIVE
          CAPSULE RPTEXIT    REPORT INITIALIZATION AND COMPLETION 
          CAPSULE RTNSSCM    RETURN CM AFTER FATAL CDCS ERROR          #
          CON    0           END OF LIST
          SPACE  4,10 
**        CAPSULE ENTRY POINTS. 
* 
*              THESE ENTRY POINTS MUST BE IN ALPHANUMERIC ORDER FOR FDL.
  
  
 CDCSNAM  INCAP  CDCSNAM,QU0100 
 CDCSREQ  INCAP  CDCSREQ,QU0100 
 CHKLOGO  INCAP  EXPANAL,QU0100 
 CKININF  INCAP  EXPEVAL,QU0100 
 CLOSE$   INCAP  IMFRUN,QU0100
 CONDINI  INCAP  EXPANAL,QU0100 
 CRMNAME  INCAP  CRMNAME,QU0100 
 CUMFUN   INCAP  CUMFUNC,QU0100 
 CUMFUNC  INCAP  CUMFUNC,QU0100 
 CUMFUPM  INCAP  CUMFUNC,QU0100 
 CURTT    INCAP  EXPANAL,QU0100                                          QU3A334
 DB.CLS   INCAP  CDCSREQ,QU0100 
 DB.DBST  INCAP  CDCSREQ,QU0100 
 DB.DEL   INCAP  CDCSREQ,QU0100 
 DB.END   INCAP  CDCSREQ,QU0100 
 DB.INQV  INCAP  CDCSREQ,QU0100 
 DB.INVV  INCAP  CDCSREQ,QU0100 
 DB.OPN   INCAP  CDCSREQ,QU0100 
 DB.PVC   INCAP  CDCSREQ,QU0100 
 DB.RD1   INCAP  CDCSREQ,QU0100 
 DB.RD2   INCAP  CDCSREQ,QU0100 
 DB.RPT   INCAP  CDCSREQ,QU0100 
 DB.RWF   INCAP  CDCSREQ,QU0100 
 DB.SKF   INCAP  CDCSREQ,QU0100 
 DB.STR   INCAP  CDCSREQ,QU0100 
 DB.WR2   INCAP  CDCSREQ,QU0100 
 DES$APT  INCAP  IMFDICT,QU0100 
 DES$CST  INCAP  IMFDICT,QU0100 
 DES$DIT  INCAP  IMFDICT,QU0100 
 DES$REC  INCAP  IMFDICT,QU0100 
 ENDABEX  INCAP  EXPANAL,QU0100 
 ENDCOND  INCAP  EXPANAL,QU0100 
 ENDEXPR  INCAP  EXPANAL,QU0100 
 EXEC$    INCAP  IMFRUN,QU0100
 EXPEVAL  INCAP  EXPEVAL,QU0100 
 EXPRESS  INCAP  EXPANAL,QU0100 
 EXPRINI  INCAP  EXPANAL,QU0100 
 FOL$END  INCAP  IMFDICT,QU0100 
 FOL$INI  INCAP  IMFDICT,QU0100 
 FOL$OFF  INCAP  IMFDICT,QU0100 
 FUNCPAR  INCAP  EXPANAL,QU0100 
 FUNCTIO  INCAP  EXPANAL,QU0100 
 GET$AP   INCAP  IMFDICT,QU0100 
 IFSAME   INCAP  EXPANAL,QU0100 
 IMFNAM   INCAP  IMFDICT,QU0100 
 INITID   INCAP  IMFDICT,QU0100 
 INVOKE$  INCAP  IMFRUN,QU0100
 INV$ABS  INCAP  IMFRUN,QU0100
 LOGOP    INCAP  EXPANAL,QU0100 
 NOTOP    INCAP  EXPANAL,QU0100 
 OPENPAR  INCAP  EXPANAL,QU0100 
 OPERAND  INCAP  EXPANAL,QU0100 
 OPERATO  INCAP  EXPANAL,QU0100 
 OPNCAT   INCAP  OPNCAT,QU0100
 PATHKEY  INCAP  IMFDICT,QU0100 
 PERBEGI  INCAP  PEREXEC,QU0100 
 PERCKDM  INCAP  PEREXEC,QU0100 
 PEREND   INCAP  PEREXEC,QU0100 
 PEREXEC  INCAP  PEREXEC,QU0100 
 PERINIT  INCAP  PEREXEC,QU0100 
 PERNEXT  INCAP  PEREXEC,QU0100 
 PEROVER  INCAP  PEREXEC,QU0100 
 RECSAME  INCAP  EXPANAL,QU0100 
 RELOP    INCAP  EXPANAL,QU0100 
 REQPF    INCAP  OPNCAT,QU0100
 RPTCLR   INCAP  RPTEXIT,QU0100 
 RPTEXIT  INCAP  RPTEXIT,QU0100 
 RPTSET   INCAP  RPTEXIT,QU0100 
 RTNSSCM  INCAP  RTNSSCM,QU0100 
 SETBIT   INCAP  RPTEXIT,QU0100 
 STKOPND  INCAP  EXPANAL,QU0100 
 STO$AP   INCAP  IMFDICT,QU0100 
 STO$KEY  INCAP  IMFDICT,QU0100 
 STO$MEM  INCAP  IMFDICT,QU0100 
 STO$OWN  INCAP  IMFDICT,QU0100 
 STO$REC  INCAP  IMFDICT,QU0100 
 TRNSDBI  INCAP  CDCSNAM,QU0100 
 TSVETO   INCAP  PEREXEC,QU0100 
 UNARYOP  INCAP  EXPANAL,QU0100 
          SPACE  4,10 
**        ENTRY POINT PASSLOC LIST FOR (1,0). 
  
  
 ENTLIST  PASSLOC            BUILD (1,0) ENTRY POINT PASSLOC TABLE
          SPACE  4,10 
**        EXTERNAL PASSLOC LIST FOR (1,0).
* 
*              THESE ENTRIES MUST BE IN ALPHANUMERIC ORDER FOR FDL. 
  
  
          PASS   ALTERKE,X   REQUIRED BY CAPSULE *EXPANAL*
          PASS   CATCHK,X    REQUIRED BY CAPSULE *OPNCAT* 
          PASS   CDCSCAT,X   REQUIRED BY CAPSULE *OPNCAT* 
          PASS   CLOSEM,X    REQUIRED BY CAPSULE *OPNCAT* AND *RTNSSCM* 
          PASS   CMM$AGR,X   REQUIRED BY CAPSULE *EXPANAL*
          PASS   CMM$FGR,X   REQUIRED BY CAPSULE *RPTEXIT* AND *RTNSSCM*
          PASS   CURFUNC,X   REQUIRED BY CAPSULE *CUMFUNC* AND *EXPANAL*
          PASS   CURLENG,X   REQUIRED BY CAPSULE *DIAGS* AND *EXPANAL*
          PASS   CURLXID,X   REQUIRED BY CAPSULE *EXPANAL* AND *CUMFUNC*
          PASS   CURP1,X     REQUIRED BY CAPSULE *EXPANAL*
          PASS   CURP2,X     REQUIRED BY CAPSULE *PEREXEC*
          PASS   CURREG,X    REQUIRED BY CAPSULE *CURTT* AND *CUMFUNC*   QU3A334
          PASS   CURTYPE,X   REQUIRED BY CAPSULE *EXPANAL*
          PASS   CURWORD,X   REQUIRED BY CAPSULE *DIAGS* AND *EXPANAL*
          PASS   DDIAG,X     REQUIRED BY CAPSULE *EXPANAL* AND *CUMFUNC*
          PASS   DHASH,X     REQUIRED BY CAPSULE *CRMNAME* AND *CDCSNAM*
          PASS   DIAG,X      REQUIRED BY CAPSULE *EXPEVAL*
          PASS   ENDPTR,X    REQUIRED BY CAPSULE *CUMFUNC*
          PASS   EOTTERM,X   REQUIRED BY CAPSULE *EXPANAL*
          PASS   ER$SRM,X    REQD BY *CDCSREQ* - KLUGE FOR LOADER PSR 
          PASS   ESTDBEG,X   REQUIRED BY CAPSULE *EXPANAL*
          PASS   ESTDEND,X   REQUIRED BY CAPSULE *EXPANAL*
          PASS   ESTDLEN,X   REQUIRED BY CAPSULE *EXPANAL*
          PASS   EVALDAT,X   REQUIRED BY CAPSULE *CUMFUNC*
          PASS   EVALFWA,X   REQUIRED BY CAPSULE *CUMFUNC*
          PASS   EXIT10,X    REQUIRED BY CAPSULE *RPTEXIT*
          PASS   EXPEVAL,X   REQUIRED BY CAPSULE *PEREXEC*
          PASS   FIELDN,X    REQUIRED BY CAPSULE *CRMNAME* AND *CDCSNAM*
          PASS   FIELDNA,X   REQUIRED BY CAPSULE *CRMNAME* AND *CDCSNAM*
          PASS   GET,X       REQUIRED BY CAPSULE *CRMNAME* AND *CDCSNAM*
          PASS   LEXINIT,X   REQUIRED BY CAPSULE *EXPANAL*
          PASS   NEXLENG,X   REQUIRED BY CAPSULE *DIAGS*
          PASS   NEXLXID,X   REQUIRED BY CAPSULE *EXPANAL*
          PASS   NEXTYPE,X   REQUIRED BY CAPSULE *EXPANAL*
          PASS   NEXWORD,X   REQUIRED BY CAPSULE *DIAGS*
          PASS   OLDSEAR,X   REQUIRED BY CAPSULE *CUMFUNC*
          PASS   OPENM,X     REQUIRED BY CAPSULE *OPNCAT* 
          PASS   PRIMKEY,X   REQUIRED BY CAPSULE *EXPANAL*
          PASS   PUT,X       REQUIRED BY CAPSULE *OPNCAT* 
          PASS   RECNO,X     REQUIRED BY CAPSULES *EXPANAL*,*PEREXEC* 
          PASS   RECYES,X    REQUIRED BY CAPSULES *EXPANAL*,*PEREXEC* 
          PASS   RETURNM,X   REQUIRED BY CAPSULE *OPNCAT* AND *RTNSSCM* 
          PASS   RPTFLAG,X   REQUIRED BY CAPSULE *RPTEXIT*
          PASS   RPTOVL,X    REQUIRED BY CAPSULE *RPTEXIT*
          PASS   RTNSSCM,X   REQUIRED BY CAPSULE *CDCSREQ*
          PASS   SAMINPU,X   REQUIRED BY CAPSULE *EXPANAL*
          PASS   SAMPTR,X    REQUIRED BY CAPSULE *EXPANAL*
          PASS   SAVATTR,X   REQUIRED BY CAPSULE *EXPANAL* AND *CUMFUNC*
          PASS   SAVEDES,X   REQUIRED BY CAPSULE *CUMFUNC*
          PASS   SESSPTR,X   REQUIRED BY CAPSULE *PEREXEC*
          PASS   STATE,X     REQUIRED BY CAPSULE *EXPANAL*
          PASS   STATETR,X   REQUIRED BY CAPSULE *EXPANAL*
          PASS   STDNO,X     REQUIRED BY MANY CAPSULES
          PASS   STDYES,X    REQUIRED BY MANY CAPSULES
          PASS   SUB100,X    REQUIRED BY CAPSULE *EXPANAL*
          PASS   SVCT100,X   REQUIRED BY CAPSULE *EXPANAL*
          PASS   SVEOTTE,X   REQUIRED BY CAPSULE *EXPANAL*
          PASS   SVESTD,X    REQUIRED BY CAPSULE *EXPANAL*
          PASS   SVOLDLE,X   REQUIRED BY CAPSULE *EXPANAL*
          PASS   SVQUIRL,X   REQUIRED BY CAPSULE *EXPANAL*
          PASS   SVQUIWS,X   REQUIRED BY CAPSULE *EXPANAL*
          PASS   SVSTATE,X   REQUIRED BY CAPSULE *EXPANAL*
          PASS   SVSTATR,X   REQUIRED BY CAPSULE *EXPANAL*
          PASS   SYMHBR.,X   REQUIRED BY CAPSULE *EXPANAL*
          PASS   SYNIO,X     REQUIRED BY CAPSULE *PEREXEC*
          PASS   SYNTAX,X    REQUIRED BY CAPSULE *PEREXEC*
 EXTLIST  PASSLOC            BUILD (1,0) EXTERNAL PASSLOC TABLE 
          EJECT 
*  IN ORDER TO MINIMIZE THE CORE REQUIREMENTS, THE SUBROUTINES
*   OPENM, CLOSEM, GET, GETN, PUT AND DLTE
*  ARE NOT LOADED FROM THE STANDARD FTN/6RM INTERFACE THAT RESIDES IN 
*  THE LIBRARY SYSIO.  INSTEAD, THEY HAVE BEEN RECODED TO PERFORM 
*  ONLY THOSE FUNCTIONS REQUIRED BY OVERLAY 1-0.
*  THESE FUNCTIONS ARE
*    -OPENM, GET, GETN, PUT, DLTE, CLOSEM ON THE CATALOG OF SESSIONS
*         (IS FILE, 10 CHARACTERS KEY IN POSITION 0, NO DUPLICATE)
*    -OPENM, GET, CLOSEM ON THE SUBSCHEMA (WA FILE) 
*  THE OTHER PRIMARY OVERLAYS, AS WELL AS THE OWNCODE ROUTINES, MAKE
*  USE OF THE FTN/6RM INTERFACE ROUTINES AS FOUND IN SYSIO. 
          SST 
          SPACE  3
*               (     5LINPUT)
*         OPENM (FIT, 3LNEW  )
*               (     3LI-O  )
* 
* 
*         CLOSEM (FIT)
* 
          ENTRY  CLOSEM,OPENM 
 OPENM    BSSZ   1
          SB1    1
          STORE  X1,OF=R      SET OPEN FLAG = REWIND
          SA2    A1+B1             LOAD PD PARAMETER ADDRESS
          ZR     X2,CALL           CHECK FOR END OF PARAMETER LIST
          SA2    X2                LOAD PD PARAMETER MNEMONIC 
          SX3    3LNEW
          LX3    42 
          IX5    X3-X2
          NZ     X5,OLD 
          STORE  X1,ON=NEW
          STORE X1,PD=OUTPUT
          EQ     CALL 
OLD       STORE  X1,ON=OLD
          SX3    3LI-O
          LX3    42 
          IX5    X3-X2
          NZ     X5,INPUT 
          STORE  X1,PD=IO 
          EQ     CALL 
INPUT     STORE  X1,PD=INPUT
 CALL     OPENM  X1 
          EQ     OPENM
          SPACE  3
 CLOSEM   BSSZ   1
          STORE  X1,CF=DET   CLOSE OPTION IS *DETACH* 
          CLOSEM X1,,FILE 
          EQ     CLOSEM 
          SPACE  3
* 
*         GET (FIT, WSA, KA, KP, MKL, RL) 
*             (          WA             ) 
* 
          ENTRY  GET
 GET      BSSZ   1
          SB1    1
          SA1    A1                LOAD FIT ADDRESS 
          SA2    A1+B1             LOAD WSA ADDRESS 
          ZR     X2,CALLG          CHECK IF END OF PARAMETER LIST 
          STORE  X1,WSA=X2
          SA2    A2+B1             LOAD KA OR WA ADDRESS
          ZR     X2,CALLG          CHECK IF END OF PARAMETER LIST 
          FETCH  X1,FO,X4 
          SX5    X4-#IS#           CHECK FOR IS FILE
          ZR     X5,XKA 
          SA3    X2                LOAD WA VALUE
          SA4    =XSBSCADD   FWA OF SUBSCHEMA WITHIN LIBRARY
          IX3    X3+X4
          STORE  X1,WA=X3 
          EQ     AA 
 XKA      STORE  X1,KA=X2 
 AA       SA2    A2+B1             LOAD KP ADDRESS
          ZR     X2,CALLG          CHECK IF END OF PARAMETER LIST 
          SA3    X2                LOAD KP VALUE
          STORE  X1,KP=X3 
          SA2    A2+B1             LOAD MKL ADDRESS 
          ZR     X2,CALLG          CHECK IF END OF PARAMETER LIST 
          SA3    X2                LOAD MKL VALUE 
          STORE  X1,MKL=X3
          SA2    A2+B1
          ZR     X2,CALLG          CHECK IF END OF PARAMETER LIST 
          SA3    X2                LOAD RL
          STORE  X1,RL=X3 
 CALLG    GET    X1 
          EQ     GET
          SPACE  3
* 
*         PUT (FIT, WSA, RL, KA)
* 
          ENTRY  PUT
 PUT      BSSZ   1
          SB1    1
          SA2    A1+B1             LOAD WSA ADDRESS 
          ZR     X2,CALLP          CHECK FOR END OF PARAMETER LIST
          STORE  X1,WSA=X2
          SA2    A2+B1             LOAD RL ADDRESS
          ZR     X2,CALLP          CHECK FOR END OF PARAMETER LIST
          SA3    X2                LOAD RL VALUE
          STORE  X1,RL=X3 
          SA2    A2+B1            LOAD KA ADDRESS 
          ZR     X2,CALLP          CHECK FOR END OF PARAMETER LIST
          STORE  X1,KA=X2 
 CALLP    PUT    X1 
          EQ     PUT
          SPACE  3
* 
*         DLTE (FIT, KA)
* 
          ENTRY  DLTE 
 DLTE     BSSZ   1
          SB1    1
          SA2    A1+B1             LOAD KA ADDRESS
          ZR     X2,CALLD          CHECK FOR END OF PARAMETER LIST
          STORE  X1,KA=X2 
 CALLD    DELETEM X1
          EQ     DLTE 
          SPACE  3
* 
*         GETN (FIT, WSA, KA) 
* 
          ENTRY  GETN 
 GETN     BSSZ   1
          SB1    1
          SA2    A1+B1             LOAD WSA ADDRESS 
          ZR     X2,CALLN          CHECK FOR END OF PARAMETER LIST
          STORE  X1,WSA=X2
          SA2    A2+B1             LOAD KA ADDRESS
          ZR     X2,CALLN          CHECK FOR END OF PARAMETER LIST
          STORE  X1,KA=X2 
 CALLN    GETN   X1 
          EQ     GETN 
          SPACE  3
***       AVOID PULLING IN THE FTN INTERFACE TO CRM FOR THIS FUNCTION 
          ENTRY  SKIPB1 
SKIPB1    JP     *+400000B
          SKIPBL  X1,1             SKIP BACK 1 LOGICAL RECORD 
          EQ     SKIPB1 
  
  
  
***       STARTM   POSITION FILE RELATIVE TO A KEY
* 
*                THIS INTERFACE ROUTINE EXISTS TO AVOID LOADING THE 
*         GENERALIZED FTN INTERFACE TO CRM FOR OUR SPECIAL AND LIMITED
*         NEEDS. THIS INTERFACE PROVIDES A SUBSET OF THE *STARTM* 
*         PARAMETERS/OPTIONS. 
* 
*         CALLING SEQUENCE -
* 
*                STARTM (FIT, KA) 
  
          ENTRY  STARTM 
 STARTM   SUBR               ENTRY/EXIT 
          SA2    A1+1        (X2) = ADDR OF KEY AREA (PERHAPS ZERO) 
          NZ     X2,STARTM2  IF KA WAS SPECIFIED
          START  X1          POSITION RELATIVE TO A KEY (EXISTING KA) 
          EQ     EXIT.
  
 STARTM2  START  X1,,X2      POSITION RELATIVE TO A KEY (NEW KA)
          EQ     EXIT.
  
  
  
          END    QU0100 
