*DECK LOADOVL 
          IDENT LOADOVL                                                 000120
          COMMENT OVERLAY AND OVCAP LOADING ROUTINES. 
LOADOVL   TITLE    LOADOVL - DIAGNOSTIC AND EXECUTION OVERLAY LOADER
          ENTRY  LOADOVL                                                000130
          ENTRY  LDOVL1 
          ENTRY  LDOVL2 
          ENTRY  DIAG 
          ENTRY  DIAGBUF
          ENTRY  DIAGFLU
          ENTRY  DIAGLEV
          ENTRY  DIAGN
          ENTRY  DIAGPRM
          ENTRY  HELPFLG
          ENTRY  HELPLEX
          ENTRY  HELPOVL
          ENTRY  INIOVL 
          ENTRY  OVLNAME
          LIST   F
          SPACE  4,10 
*****     LOADOVL - LOAD OVERLAYS AND OVCAPS. 
* 
*         G. E. LOGG         77/05/13 
          SPACE  4,10 
***              THIS PROGRAM LOADS QU OVERLAYS AND OVCAPS.  DIAGNOSTIC 
*         PROCESSING IS ALSO PERFORMED IN THIS OVERLAY.  OVERLAY
*         INITIALIZATION IS INCLUDED IN THIS OVERLAY BECAUSE THE
*         DIAGNOSTIC INDEX OVERLAY WILL OVERWRITE THIS CODE.
          SPACE  4,10 
**        OVERLAY/OVCAP LOADING ERROR MESSAGES. 
  
  
 MSG1     DATA   C*  FOL ERROR LOADING-.......* 
 OVLNAME  EQU    MSG1+2      CURRENT OVERLAY NAME 
 MSG2     DATA   C* FDL ERR .  LOADING-.......* 
          SPACE  4,10 
**        GLOBAL DEFINITIONS. 
  
  
*CALL MACRO 
  
  
          LIST   -L          *CALL ENVIRON
*CALL     ENVIRON 
          LIST   L
          LIST   -L                * CALL TO NUMOPT FOLLOWS * 
*CALL NUMOPT
          LIST   L
  
  
HHA       EQU    104B        HIGHEST HIGH ADDRESS OF OVERLAY STRUCTURE
MINFL00   EQU    101B        LWA + 1 OF OVERLAY 0-0 
          TITLE  OVERLAY LOADING ROUTINES.
 LOADOVL  SPACE  4,10 
***       LOADOVL - LOAD AN OVERLAY.
* 
*         LOADOVL(FWA,L1,L2)
* 
*         FWA = IGNORED.
*         L1 = PRIMARY OVERLAY LEVEL NUMBER.
*         L2 = SECONDARY OVERLAY LEVEL NUMBER.
* 
*                THE OVERLAY IS LOADED AND A RJ IS MADE TO THE FIRST
*         ENTRY POINT IN THE OVERLAY.  ALL CAPSULES ARE UNLOADED WHEN 
*         A NEW PRIMARY OVERLAY IS LOADED.  THE ENTRY POINTS *LDOVL1* 
*         AND *LDOVL2* ARE PROVIDED FOR IDP (AN INTERACTIVE DEBUG 
*         PACKAGE). *LDOVL1* IS USED TO CLEAR THE BREAK TABLE FOR ANY 
*         BREAKS IN THE LAST OVERLAY.  *LDOVL2* IS PROVIDED SO THAT 
*         IDP WILL GAIN CONTROL BEFORE THE OVERLAY DOES.  IN THIS WAY 
*         BREAKPOINTS CAN BE INSERTED IN THE OVERLAY OR CHANGES CAN 
*         BE MADE WITHIN THE OVERLAY. 
* 
*         CALLS  QU.UOC, CMM.LOV, FOL.GDE 
*         USES   ALL REGISTERS. 
  
  
 LOADOVL  SUBR               ENTRY/EXIT 
          SA2    A1+1 
          SA3    A2+1 
          SA2    X2          L1 
          SA3    X3          L2 
          LX2    6
          BX1    X2+X3       LEVEL NUMBERS
          SB2    X1          SAVE LEVEL NUMBERS 
          NZ     X3,LOADOVL1 IF WE ARE NOT LOADING A PRIMARY
          RJ     QU.UOC      UNLOAD ALL QU CAPSULES 
 LOADOVL1 SX1    B2 
          RJ     =XFOL.GDE   GET DIRECTORY ENTRY
          SX4    X6          FWA FOR IDP
          SX5    X7          LWA+1 FOR IDP
          MX7    42 
          BX6    X7*X6       OVERLAY NAME 
          SA6    OVLNAME     SAVE OVERLAY NAME
 LDOVL1   NO                 MODIFIED BY IDP TO A RJ
 +        SA1    OVLNAME
          RJ     =XCMM.LOV   LOAD OVERLAY 
          SX2    MSG1 
          SA1    LOADOVL     SIMULATE RJ TO OVERLAY 
          MI     B6,ERR      IF ERROR LOADING OVERLAY 
          BX6    X1 
          SA6    B7          SAVE RETURN ADDRESS
          RJ     CLR.IS1     CLEAR INSTRUCTION STACK
 CLR.IS1  DATA   0
 LDOVL2   NO                 MODIFIED BY IDP TO A RJ
 +        JP     B7+1        JUMP TO NEW OVERLAY
 ERR      SPACE  4,10 
**        ERR - ERROR LOADING A QU OVERLAY/OVCAP. 
* 
*         ENTRY  (X2) = FWA OF ERROR MESSAGE TO BE DAYFILED.
*         EXIT   QU ABORTED.
  
  
 FDLERR   SA1    MSG2        * FDL ERR .* 
          MX0    54          *777777777 * 
          BX0    X0*X1       * FDL ERR  * 
          SX6    X6+33B      CONVERT ERROR CODE TO DISPLAY CODE 
          BX6    X6+X0       * FDL ERR N* 
          SA6    A1          STORE UPDATED ERROR MESSAGE
 ERR      MESSAGE X2         ISSUE ERROR MESSAGE
          ABORT              ABORT QU 
          TITLE  OVCAP LOADING ROUTINES.
          SPACE  4,10 
**        CAPSULE LOADING GLOBAL DEFINITIONS. 
  
  
 GROUP    DATA   C*QU*       GROUP NAME OF OVCAPS 
 LIBLIST  VFD    60/0LDMSLIB OVCAP LIBRARY IF QU LOADED FROM SYSTEM 
          CON    0                 END OF LIST
 CAPLIST  CON    CAPL00      CAPSULE LIST FOR (0,0) 
          CON    **          ALTERNATE CAPSULE LIST 
          CON    0           END OF LIST
 PASSLIST CON    ENTPL00     (0,0) ENTRY POINT PASSLOC LIST 
          CON    **          ALTERNATE EXTERNAL PASSLOC LIST
          CON    **          ALTERNATE ENTRY POINT PASSLOC LIST 
          CON    0           END OF LIST
          SPACE  4,10 
**        CAPSULE LIST. 
  
  
 CAPL00   CAPSULE ALPHAED    ALPHABETIC EDITING 
          CAPSULE DIAGS      DIAGNOSTIC/HELP TEXT PROCESSING
          CAPSULE FIGSUB     FIGURATIVE SUBSCRIPT 
          CAPSULE MATH=      EXPONENT PROCESSING
          CAPSULE NUMERED    NUMERIC EDITING
          CAPSULE QU2CONV    DECIMAL POINT SCALING
          CAPSULE QU2KOD     FLOATING POINT TO DISPLAY CODE 
          CAPSULE SCAN       SCAN FUNCTION
          CON    0           END OF TABLE 
          SPACE  4,10 
**        CAPSULE ENTRY POINTS. 
* 
*              THESE ENTRIES MUST BE IN ALPHANUMERIC ORDER FOR FDL. 
  
  
 ALPHAED  INCAP  ALPHAED
 DADD     INCAP  MATH=
 DDIV     INCAP  MATH=
 DMULT    INCAP  MATH=
 DSUB     INCAP  MATH=
 DTOD     INCAP  MATH=
 FIGSUB   INCAP  FIGSUB 
 ITOJ     INCAP  MATH=
 NUMERED  INCAP  NUMERED
 PDT      INCAP  DIAGS
 QU2CONV  INCAP  QU2CONV
 QU2KOD   INCAP  QU2KOD 
 SCALEFL  INCAP  QU2CONV
 SCALEIN  INCAP  QU2CONV
 SCAN     INCAP  SCAN 
 XTOY     INCAP  MATH=
          SPACE  4,10 
**        (0,0) ENTRY POINT PASSLOC LIST. 
  
  
 ENTPL00  PASSLOC            BUILD PASSLOC TABLES 
 QU.LNK   SPACE  4,10 
**        QU.LNK - LINK ALTERNATE CAPSULE/PASSLOC LISTS.
* 
*         THERE MUST BE AN EXTERNAL PASSLOC LIST OTHERWISE THE ENTRY
*         POINT PASSLOC LIST WILL BE IGNORED. 
* 
*         QU.LNK(CAPLIST,ENTLIST,EXTLIST) 
* 
*         CAPLIST = 0 OR A LIST OF CAPSULES TERMINATED BY A ZERO WORD.
*         ENTLIST = 0 OR AN ENTRY POINT PASSLOC LIST. 
*         EXTLIST = EXTERNAL PASSLOC LIST.
* 
*         ENTRY  (A1) = PARAMETER LIST. 
  
  
 QU.LNK   SUBR   =           ENTRY/EXIT 
          SA2    A1+1        SAVE POINTERS TO LISTS IN OUR TABLES 
          SA3    A1+2 
          BX6    X1 
          BX7    X2 
          SA6    CAPLIST+1   SAVE ALTERNATE CAPSULE LIST
          SA7    PASSLIST+2  SAVE ALTERNATE ENTRY PASSLOC LIST
          BX6    X3 
          SA6    PASSLIST+1  SAVE ALTERNATE EXTERNAL PASSLOC LIST 
          EQ     EXIT.
 QU.LOC   SPACE  4,10 
**        QU.LOC - OVCAP LOADING ROUTINE. 
* 
*              THIS ROUTINE WILL CALL THE CAPSULE INDICATED AFTER FIRST 
*         CHECKING TO SEE IF IT IS ALREADY LOADED.
* 
*         ENTRY  (X5) = ENTRY IN PASSLOC LIST OF THE CALLED ENTRY POINT.
*                (QU.LOC) = RETURN WORD HAS THE FOLLOWING FORMAT. 
*                VFD  30/JUMP,12/0,18/CAP 
*                CAP = ADDRESS OF CAPSULE ENTRY IN CAPSULE LIST.
*                (A1) = FWA OF PARAMETER LIST FOR CAPSULE.
*                (X1) = ADDRESS OF FIRST PARAMETER IN PARAMETER LIST. 
*         EXIT   JUMP TO CAPSULE. 
*         CALLS  FDL.LOC
*         USES   X - 1, 2, 3, 4, 6, 7.
*                B - 2, 4, 5, 6, 7. 
*                A - 1, 2, 3, 4, 5, 6, 7. 
  
  
 QU.LOC   SUBR   =           ENTRY/EXIT 
          SA3    QU.LOC 
          LX3    30 
          SA4    X3          RETURN WORD
          SA3    X4 
          SX6    X3          FLAGS
          MI     X6,QU.LOC1  IF CAPSULE ALREADY LOADED
          SX6    A1 
          MX2    42 
          SA6    QU.LOCA     SAVE PARAMETER LIST
          MX6    1
          BX2    X2*X3       CAPSULE NAME 
          LX6    18 
          BX6    X6+X3       ADD CAPSULE LOADED FLSG
          BX7    X2 
          SA6    A3 
          SA7    MSG2+2      SAVE CAPSULE NAME
          SA1    GROUP       QU GROUP NAME
          SX3    LIBLIST     ALTERNATE LIBRARY LIST FOR QU IN SYETM 
          SX4    PASSLIST    PASSLOC LIST ADDRESSES 
          RJ     =XFDL.LOC   LOAD OVCAP 
          SA1    QU.LOCA
          SX2    MSG2 
          SA1    X1          RESTORE PARAMETER LIST 
          NZ     X6,FDLERR   IF AN ERROR LOADING AN OVCAP 
 QU.LOC1  SA2    X5          GET ONE WORD PASSLOC ENTRY 
          SA3    QU.LOC 
          BX6    X3 
          SB2    X2+1        JUMP ADDRESS 
          SA6    X2          STORE JUMP BACK TO CALLER
          RJ     CLR.IS2     CLEAR INSTRUCTION STACK
 CLR.IS2  DATA   0
          JP     B2          CALL CASPULE 
  
 QU.LOCA  CON    0           PARAMETER SAVE AREA
 QU.UOC   SPACE  4,10 
**        QU.UOC - UNLOAD OVERLAY CAPSULES. 
* 
*              THE QU OVERLAY CAPSULES ARE UNLOADED AT THE START OF 
*         EACH NEW PRIMARY. 
* 
*         CALLS  FDL.UOC
*         USES   X - 1, 2, 3, 4, 5, 6, 7. 
*                B - 3, 4, 5, 6, 7. 
*                A - 1, 2, 3, 4, 5, 6, 7. 
  
  
 QU.UOC   SUBR   =           ENTRY/EXIT 
          SX5    CAPLIST
          SX6    B0 
          SA6    PASSLIST+1  CLEAR LATERNATE PASSLOC LISTS
          SA6    PASSLIST+2 
 QU.UOC1  SA3    X5          ADDRESS OF CAPSULE LIST
          SB3    X3 
          ZR     X3,QU.UOC5  IF NO MORE CAPSULE LISTS 
 QU.UOC2  SA3    B3 
          ZR     X3,QU.UOC4  IF END OF CAPSULE LIST 
          SX6    X3 
          MX2    42 
          PL     X6,QU.UOC3  IF CAPSULE IS UNLOADED 
          BX2    X2*X3
          SX4    PASSLIST    PASSLOC LIST ADDRESSES 
          BX6    X2 
          SA6    A3          CLEAR FLAGS IN CAPSULE TABLE ENTRY 
          SA1    GROUP       SET GROUP NAME FOR FDL TRACING 
          RJ     =XFDL.UOC   UNLOAD OVERLAY CAPSULES
 QU.UOC3  SB3    B3+1        GET NEXT CAPSULE LIST ENTRY
          EQ     QU.UOC2
  
 QU.UOC4  SX5    X5+1        GET NEXT CASPULE LIST
          EQ     QU.UOC1
  
 QU.UOC5  SX6    B0 
          SA6    CAPLIST+1   CLEAR ALTERNATE CAPSULE LIST 
          EQ     EXIT.
          TITLE  DIAGNOSTIC AND HELP TEXT PROCESSING. 
          SPACE  4,10 
**        DIAGNOSTIC AND HELP TEXT PROCESSING DEFINITIONS.
  
  
*CALL COMSOVL 
  
  
 DIAGCNT  CON    0           REPEAT COUNT FOR LAST DIAGNOSTIC ISSUED
 DIAGLEV  CON    0           0 IF *DIAG,PART* AND 1 IF *DIAG,FULL*
 DIAGN    CON    0           DIAGNOSTIC NUMBER OR LEXICAL ID
 DIAGOLD  CON    0           LAST DIAGNOSTIC NUMBER 
 DIAGPRM  CON    0           ADDRESS OF LAST *DIAG* PARAMETER USED
 HELPFLG  CON    0           HELP FLAG (1=HELP, 0=DIAGNOSTIC) 
 HELPLEX  CON    0           LEXICAL ID OR DIAG NUMBER FOR *HELP* 
 HELPOVL  CON    0           NZ IF WE ARE LOOKING FOR HELP OVERLAY
 DIAG     SPACE  4,10 
***       DIAG - DIAGNOSTIC PROCESSOR.
* 
*         DIAG(N,P1,...,PN) 
* 
*         N    = DIAGNOSTIC NUMBER. 
*         PI   = PARAMETERS NEEDED FOR DIAGNOSTIC MESSAGE IF ANY. 
* 
*                THIS ROUTINE IS A PREPROCESSOR FOR ALL DIAGNSOTIC/HELP 
*         TEXT MESSAGES.  IF A DIAGNOSTIC REPEATS ITSELF THIS ROUTINE 
*         KEEPS THE REPEAT COUNT AND ISSUES A MESSAGE GIVING THE
*         NUMBER OF TIMES THIS ERROR OCCURED INSTEAD OF ISSUING THE 
*         ERROR EACH OCCURENCE. 
* 
*         CALLS  DIAGFLU, PDT.
*         USES   ALL REGISTERS. 
  
  
 DIAG     SUBR               ENTRY/EXIT 
          MX6    0
          SA6    HELPFLG     LOOK FOR DIAGNOSTIC TEXT 
          SA6    HELPOVL     LOOK FOR DIAGNOSTIC OVERLAY
          SX6    A1          SAVE A1 SO THAT DIAPARM WILL BE ABLE TO
          SA6    DIAGPRM     ACCESS SUBSEQUENT PARAMETERS 
          SA1    X1          GET DIAGNOSTIC NUMBER (1ST PARAMETER)
          LX6    X1 
          SA6    DIAGN       STORE DIAG NUMBER FOR DIAGXEQ
          SA1    DIAGLEV     CHECK IF FULL DIAGNOSTIC MODE
          NZ     X1,DIAG2    IF DIAGNOSTIC FULL MODE
          SA1    DIAGOLD
          ZR     X1,DIAG2    IF FIRST DIAGNOSTIC THIS TRANSMISSION
          IX1    X1-X6       CHECK IF SAME DIAG AS LAST TIME
          SA3    DIAGCNT     INCREMENT DIAGNOSTIC REPEAT COUNT
          NZ     X1,DIAG1    IF DIAGNOSTICS ARE DIFFERENT 
          SX1    X6-1000D    DIAGNOSTIC NUMBER - 1000D
          PL     X1,DIAG1    IF DIAG OVER 999 PRINT IT ANYWAY 
          SX6    X3+1 
          SA6    A3 
          SX6    X6-100      CHECK IF MORE THAN 100 DUPLICATES
          MI     X6,EXIT.    IF LESS THAN 100 REPETITIONS 
          RJ     =XDIAGFLU   PRINT A MESSAGE WITH REPEAT COUNT
          EQ     EXIT.
  
 DIAG1    RJ     =XDIAGFLU   FLUSH REPEAT COUNT MESSAGE 
 DIAG2    RJ     =XPDT       PROCESS DIAGNOSTIC TEXT
          SA1    DIAGN
          BX6    X1 
          SA6    DIAGOLD     SAVE DIAGNOSTIC NUMBER FOR *DIAGFLU* 
          SA1    =XFATFLAG   GET FATAL INDICATOR
          ZR     X1,EXIT.    IF THIS IS NON-FATAL DIAGNOSTIC
          SA3    =XFATALCT   (X3) = COUNT OF FATAL DIAGNOSTICS SO FAR 
          MX6    -1 
          IX6    X3-X6       INCREMENT COUNT OF FATAL DIAGNOSTICS 
          SA6    A3 
          SA2    =XIPROCES   ITEM *IPROCESSED* - INTERACTIVE OR BATCH 
          ZR     X2,EXIT.    NO ABORT FOR INTERACTIVE USERS 
          SA2    =XUPROCES   ITEM *UPROCESSED* - ABORT OR NOT ON FATALS 
          NZ     X2,EXIT.    IF SHOULDNT ABORT ON FATAL DIAGNOSTICS 
          SA1    =XDIAGABT
          NZ     X1,EXIT.    IF ALREADY ABORTED ON FATAL DIAGNOSTIC 
          SX6    1
          SA6    A1          SET FLAG FOR DIAGNOSTIC ABORT
          RJ     =XABORT     ABORT THE JOB
          EQ     EXIT.
 DIAGFLU SPACE 4,8
**        DIAGFLU - FLUSH DIAGNOSTIC MESSAGES.
* 
*              THIS ROUTINE FLUSHES THE DIAGNOSTIC REPETITION COUNT.
* 
*         ENTRY  (DIAGOLD) = LAST DIAGNOSTIC NUMBER.
*                (DIAGCNT) = REPETITION COUNT.
*         USES   ALL REGISTERS
*         CALLS  BINDEC, WRITE
  
  
 DIAGFLU  SUBR               ENTRY/EXIT 
          SA2    DIAGCNT
          ZR     X2,DIAGFLU1 IF NO REPITITIONS THEN CLEAR DIAG NUMBER 
          SA1    DIAGFLUA 
          BX6    X2 
          SA6    DIAGFLUB    SAVE NUMBER TO BE CONVERTED
          RJ     =XBINDEC    CONVERT TO DECIMAL NUMBER
          SA3    DIAGFLUD+1 
          MX7    18 
          LX6    -12
          LX7    -12
          BX6    X7*X6       ADD NUMBER TO MESSAGE
          SA2    DIAGOLD
          BX3    -X7*X3 
          SA1    DIAGFLUA 
          BX6    X6+X3
          BX7    X2 
          SA6    A3 
          SA7    DIAGFLUB    SAVE NUMBER TO BE CONVERTED
          RJ     =XBINDEC    CONVERT TO DECIMAL NUMBER
          SA3    DIAGFLUD+2  ADD NUMBER TO MESSAGE
          MX7    18 
          LX6    -6 
          LX7    -6 
          BX6    X7*X6
          BX3    -X7*X3 
          BX6    X6+X3
          SA6    A3 
          SA1    DIAGFLUC 
          RJ     =XWRITE
 DIAGFLU1 SX6    B0 
          SA6    DIAGOLD     CLEAR REPETITION COUNT AND LAST DIAG 
          SA6    DIAGCNT
          EQ     EXIT.
  
 DIAGFLUA CON    DIAGFLUB    *BINDEC* PARAMETER LIST
          CON    =3 
 DIAGFLUB CON    0           NUMBER TO BE CONVERTED BY *BINDEC* 
 DIAGFLUC CON    DIAGFLUD    *WRITE* PARAMETER LIST 
          CON    =40
          CON    DIAGFLUE    RETURN CODE
 DIAGFLUD DATA   H* THERE WERE ... MORE ... DIAGNOSTIC(S).* 
 DIAGFLUE CON    0           RETURN CODE FROM *WRITE* 
          TITLE  OVERLAY INITIALIZATION.
 INIOVL   SPACE  4,8
**        INIOVL - INITIALIZE OVERLAY LOADING.
* 
*              THIS ROUTINE IS USED TO INITIALIZE QU OVERLAY LOADING. 
*         THE RA COMMUNICATION FLAGS EFFECTING OVERLAY LOADS ARE
*         SAVED FOR USE IN LOADING QU OVERLAYS FROM THE SAME SOURCE.
*         *DIAGBUF* IS THE FWA OF THE INDEX OVERLAY WHICH OVERWRITES
*         THE FOLLOWING INITIALIZATION CODE.  THE INDEX OVERLAY MUST
*         START WITH A 54 TABLE (5 WORD HEADER BECAUSE THE FIRST 5
*         WORDS ARE SKIPPED BY THE DIAGNOSTIC AND HELP TEXT PROCESSORS).
*         IF QU WAS LOADED FROM A SYSTEM LIBRARY THEN QUS OVCAPS
*         MUST BE ON LIBRARY SYSOVL.  HENCE WE SET UP THE ALTERNATE 
*         LIBRARY LIST FOR THE CAPSULE LOADING ROUTINE. 
  
  
 INIOVL4  RJ     =XFOL.LOD   LOAD OVERLAY AT SPECIFIED FWA
          SX2    MSG1 
          MI     B6,ERR      IF ERROR LOADING OVERLAY 
  
 INIOVL   SUBR               ENTRY/EXIT 
 DIAGBUF  BSS    0           FWA OF DIAGNOSTIC INDEX OVERLAY
          MX0    1
          SA1    65B
          LX1    59-18
          BX6    X0*X1              FROM LOCN 65B 
          SA2    FLAGS
          BX6    X2+X6             ADD IT IN IF SET 
          SA6    A2 
          SA1    MINFL00
          SX6    X1 
          SA6    BASEX0      SAVE LWA+1 OF 0-0 AS FWA OF X-0
          SA1    HHA
          SX6    X1 
          SA6    HIGHEST     SAVE HHA FOR REFERENCE BY SYMPL PROCS
          SX1    2RRO 
          MX3    42 
          LX1    48 
          SB1    1
          SA2    B1          START LOOKING FOR -RO- IN RA+2 TO RA+N 
 INIOVL2  SA2    A2+B1       GET NEXT PARAMETER FROM COMMUNICATION AREA 
          ZR     X2,INIOVL3  IF NO *RO* FOUND 
          BX2    X2*X3       DROP CONTROL CARD DELIMITER
          BX2    X2-X1       COMPARE WITH CHARACTERS -RO- 
          NZ     X2,INIOVL2  GO BACK FOR MORE IF NO *RO* FOUND
          MX6    59          -1 OR TRUE 
          SA6    =XRO        SET RO MODE FLAG 
 INIOVL3  SA1    INIOVLA     GET PARAMETERS FOR FOL 
          MX7    42 
          BX7    X7*X1
          SA7    OVLNAME     SAVE INDEX OVERLAY NAME
          EQ     INIOVL4     GET OUT OF BUFFER BEFORE OVERLAY LOAD
  
 INIOVLA  VFD    42/0LQU0700,18/DIAGBUF  FOL.LOD PARAMETERS 
  
 A        SET    DIAGBUF+ND+5-*  NUMBER OF WORDS TO FILL BUFFER 
          IFGT   A,0,1
          BSS    A           FILL IN ENOUGH SO INDEX OVERLAY WILL FIT 
          END                                                           002260
