*DECK INIT
USETEXT TENVIRN 
USETEXT TREPORT 
USETEXT TRPTLST 
USETEXT TXSTD 
      PROC  INIT; 
  
#----------------------------------------------------------------------#
#                                                                      #
#  THE FOLLOWING PROCS ARE XDEF"D WITHIN THIS DECK:                    #
#                                                                      #
#     INIT                                                             #
#                                                                      #
#----------------------------------------------------------------------#
  
      BEGIN 
  
      ITEM ENDCOL       I;         # ENDING COLUMN POSITION            #
       DEF DFTRPWD #O"40000000000001000000"#;  #DEFAULT VALUE FOR 
                                                REPORTLIST WORD 1,
                                                BEYOND IS ON, 
                                                LINE NB IS 1# 
         DEF DFTRPWD2 #O"04010000000000000000"#;
  
           DEF COLUMN #XCOLUMN#;
          DEF CURTAB #XTAB#;
  
      XREF ITEM CALLTYP      I;    # CALLTYPE OF THIS REPORT ENTRY     #
      XREF ITEM CTR          I; 
      XDEF BASED ARRAY HEAD;       # TO LOOK AT REPORT HEAD LISTS      #
        BEGIN 
        ITEM HEADL        U(00,03,09);   #                             #
        END 
      XDEF ITEM HEADNDX      I;    # INDEX IN *HEAD* OF MATCHING LEVEL #
                                   # NUMBER, ELSE IT IS ZERO.          #
      XREF ITEM LEVELNB      I; 
      XREF ITEM MAX          I; 
      XREF ITEM SAMELINE     B; 
      XREF ITEM TLG          I; 
  
      XREF FUNC BINDEC C(10);      # BINARY TO DECIMAL CONVERSION      #
  
  
  
#----------------------------------------------------------------------#
  
  
  
  
       BEGIN                           #ING AND FOOTING#
          P<REPORTLIST> = AREPORTLIST;
           LEVELNB = ICWI[5];              #SAVE LEVEL NB#
          IF LEVELNB GR 63         # IF LEVEL NUMBER TOO LARGE         #
            OR LEVELNB LS 0        # OR LEVEL NUMBER TOO SMALL         #
          THEN
            BEGIN 
            STDNO;                 # BAD RETURN                        #
            END 
  
          C<8,2>KEYAREA = BINDEC(LEVELNB, 2);  # TWO DISP CODE DIGITS  #
          IF NOT FULLSYNTX THEN RETURN; 
           CURTAB = 0;                     #PRESET TAB TO 0#
          COLUMN = 1; 
          CTR = 0;
          ENDCOL = TABCOL(1); 
          TLG = 0;
           REPORTWORD1[REPORTINDEX] = DFTRPWD; #PRESET REPORT WORD 1# 
          REPORTWORD2[REPORTINDEX] = DFTRPWD2;
           SAMELINE = FALSE;               #PRESET SAMELINE#
          FOR HEADNDX = 0 STEP 1   # FOR EACH REPORT HEAD ENTRY        #
            UNTIL MAX              # UNTIL HAVE TRIED ALL THAT EXIST   #
          DO
            BEGIN 
            IF HEADL[HEADNDX] EQ LEVELNB  # IF THIS ENTRY MATCHES LEVEL#
            THEN
              BEGIN 
              RETURN;              # RETURN WHILE HEADNDX IS CORRECT   #
              END 
            END 
  
          HEADNDX = 0;             # NOT FOUND                         #
           RETURN;
       END
  
  
  
  
#----------------------------------------------------------------------#
  
  
      END 
      TERM
