*DECK     ZFN 
          IDENT  CPU.ZFN
          B1=1
          ENTRY  ZFN= 
          TITLE  CPU.ZFN - ZERO FILL NAME.
          COMMENT ZERO FILL NAME. 
          COMMENT COPYRIGHT (C) UNIVERSITY OF MINNESOTA - 1973. 
*         CTEXT  COMCZFN - ZERO FILL NAME.
          IF     -DEF,QUAL$,1 
          QUAL   COMCZFN
          BASE   D
*         COMMENT COPYRIGHT (C) UNIVERSITY OF MINNESOTA - 1973. 
 ZFN      SPACE  4
***       ZFN - ZERO FILL NAME. 
*         D. W. MEARS.  73/30/01. 
* BRING DOCUMENTATION UP TO CODING STANDARDS. 
 ZFN      SPACE  4,10 
***       ZFN REPLACES 55 CODES WITH 00 CODES IN A WORD 
*         (THE OPPOSITE OF SFN).
* 
*         ENTRY  (X1) = WORD TO BE ZERO FILLED. 
*                (B1) = 1.
* 
*         EXIT   (X6) = ZERO FILLED WORD. 
* 
*         USES    A - 2.
*                 B - NONE. 
*                 X - 1,2,3,4,6,7.
* 
*         CALLS   NONE. 
* 
*         MACROS NONE.
  
  
 ZFN=     PS                 ENTRY/EXIT 
          SA2    ZFNA          =10HAAAAAAAAAA 
          BX3    X1 
          AX1    3
          BX4    X1*X3
          BX1    X1+X3
          AX6    X1,B1
          BX7    -X6*X4 
          AX4    2
          BX7    X7*X4
          BX6    X7*X2
          BX1    X7*X2
          LX6    2
          BX1    X6+X1
          BX3    X3-X1
          LX1    3
          BX6    X3-X1
          EQ     ZFN=        RETURN 
  
 ZFNA     DATA   10HAAAAAAAAAA
 ZFN      SPACE  4
          IF     -DEF,QUAL$,2 
          QUAL   *
 ZFN=     EQU    /COMCZFN/ZFN=
          BASE    * 
*         ENDX
 ZFN      SPACE  4
          END 
