COMPWEI 
COMMON
          CTEXT  COMPWEI - WRITE EOI SECTOR.
          IF     -DEF,QUAL$,1 
          QUAL   COMPWEI
*         COMMENT  COPYRIGHT CONTROL DATA SYSTEMS INC.  1992. 
 WEI      SPACE  4
***       WEI - WRITE EOI SECTOR. 
*         P. D. HAAS.        76/05/20.
 WEI      SPACE  4
***              WEI WRITES THE EOI SECTOR FOR A MASS STORAGE FILE. 
* 
*         IF *WEI$* IS DEFINED, WEI WILL BE ASSEMBLED TO USE EOI
*         BUFFER SPECIFIED BY THE CALLING ROUTINE ON ENTRY. 
* 
*         CONTROL BYTES - 
*         CON    0,0
* 
*         INFORMATION WRITTEN - 
*T        60/ 
*T        12/,12/ FT,12/ ET,12/ ES,12/
*T        60/ PACKED DATE AND TIME
* 
*         FT = FIRST TRACK
*         ET = CURRENT (EOI) TRACK
*         ES = CURRENT (EOI) SECTOR 
* 
*         ENTRY  (A) = BUFFER ADDRESS IF *WEI$* DEFINED.
*                (FA) = RELATIVE FNT ADDRESS IN NFL.
*                (RA) = REFERENCE ADDRESS IF (FA) .NE. 0. 
*                (T6) = EOI TRACK.
*                (T7) = EOI SECTOR. 
*                DRIVER PRESET. 
* 
*                IF (FA) = 0, FT IS ASSUMED TO BE 
*                PRESTORED BY THE CALLER. 
* 
*         EXIT   (A) = STATUS FROM DRIVER.
* 
*         USES   T3.
* 
*         CALLS  WDS. 
* 
*         MACROS NFA. 
  
  
          IF     DEF,WEI$,3 
 WEIA     EQU    0
 TX       EQU    T3          BUFFER ADDRESS 
          SKIP
 TX       EQU    0
          IF     -DEF,WEIA
 WEIA     EQU    BFMS        DEFINE EOI BUFFER
          ENDIF 
  
  
 WEI      SUBR               ENTRY/EXIT 
          IF     DEF,WEI$ 
          STD    TX          SET BUFFER ADDRESS 
          ADN    DTEI        ADDRESS FOR DATE/TIME
          STM    WEIC 
          IF     DEF,FA 
          SBN    DTEI-FNEI   ADDRESS FOR FNT/FST
          STM    WEIB 
          ENDIF 
 FA       IF     DEF,FA 
          LDD    FA 
          ZJN    WEI1        IF FNT UNDEFINED 
          NFA    FA,R 
          CRM    WEIA+FNEI,TR  READ FNT/FST TO EOI BUFFER 
 WEIB     EQU    *-1
 FA       ENDIF 
 WEI1     LDN    PDTL        READ DATE/TIME 
          CRM    WEIA+DTEI,ON 
 WEIC     EQU    *-1
          LDD    T6          ENTER EOI TRACK
          STM    WEIA+ETEI,TX 
          LDD    T7          ENTER EOI SECTOR 
          STM    WEIA+ESEI,TX 
 WEI2     LDN    0           SET EOI LINKAGE BYTES
          STM    WEIA+1,TX
 .ML      IF     DEF,WEI$ 
          STI    TX 
          LDD    TX          WRITE EOI SECTOR 
          IFNE   WLSF,0,1 
          LMC    WLSF 
 .ML      ELSE
          STM    WEIA 
          LDC    WEIA+WLSF   WRITE EOI SECTOR 
          ENDIF 
          RJM    WDS
          UJP    WEIX        RETURN 
 WEI      SPACE  4
 QUAL$    IF     -DEF,QUAL$ 
          QUAL   *
 WEI      EQU    /COMPWEI/WEI 
          IF     -DEF,WEIA,1
 WEIA     EQU    /COMPWEI/WEIA
 QUAL$    ENDIF 
          ENDX
