COMPWCB 
COMMON
          CTEXT  COMPWCB - WRITE CODED BUFFER.
          IF     -DEF,QUAL$,1 
          QUAL   COMPWCB
*         COMMENT  COPYRIGHT CONTROL DATA SYSTEMS INC.  1992. 
 WCB      SPACE  4
***       WCB - WRITE CODED BUFFER. 
*         G. R. MANSFIELD.  09/27/69. 
 WCB      SPACE  4
***              WCB WRITES A CODED LINE FROM A PP BUFFER TO A
*         CIRCULAR BUFFER.  THERE MUST BE ROOM IN THE CIRCULAR
*         BUFFER FOR THE CODED LIN.  DATA WILL BE TRANSFERRED TO
*         THE CIRCULAR BUFFER THROUGH A 0000 BYTE.  THIS BYTE WILL
*         TERMINATE THE CODED LINE, AND THE CURRENT CM WORD WILL BE 
*         ZERO FILLED.
*         ENTRY  (A) = ADDRESS OF PP BUFFER.
*                (FT - FT+1) = FIRST ADDRESS OF CM BUFFER.
*                (IN - IN+1) = NEXT INPUT ADDRESS.
*                (LM - LM+1) = LIMIT ADDRESS OF CM BUFFER.
*         EXIT   (IN - IN+1) UPDATED. 
*         USES   T1, T2, CM - CM+4. 
  
  
 WCB      SUBR               ENTRY/EXIT 
          STD    T1          SET PP BUFFER ADDRESS
 WCB1     LDN    CM          SET BYTE ADDRESS 
          STD    T2 
 WCB2     LDI    T1          MOVE BYTE
          STI    T2 
          AOD    T1          ADVANCE WORD ADDRESS 
          AOD    T2          ADVANCE BYTE ADDRESS 
          LMN    CM+5 
          NJN    WCB2        LOOP TO END OF WORD
          LDD    IN          STORE WORD 
          SHN    6
          ADD    RA 
          SHN    6
          ADD    IN+1 
          CWD    CM 
          AOD    IN+1        IN = IN+1
          SHN    -14
          RAD    IN 
          LMD    LM 
          NJN    WCB4 
          LDD    IN+1 
          LMD    LM+1 
          NJN    WCB4        IF LIMIT NOT REACHED 
          LDD    FT          IN = FIRST 
          STD    IN 
          LDD    FT+1 
          STD    IN+1 
 WCB4     LDD    CM+4 
          NJN    WCB1        LOOP TO END OF LINE
          LJM    WCBX        RETURN 
          SPACE  4
 QUAL$    IF     -DEF,QUAL$ 
          QUAL   *
 WCB      EQU    /COMPWCB/WCB 
 QUAL$    ENDIF 
          ENDX
