COMPWBB 
COMMON
          CTEXT  COMPWBB - WRITE BINARY BUFFER. 
          IF     -DEF,QUAL$,1 
          QUAL   COMPWBB
*         COMMENT  COPYRIGHT CONTROL DATA SYSTEMS INC.  1992. 
 WBB      SPACE  4
***       WBB - WRITE BINARY BUFFER.
*         G. R. MANSFIELD.  09/27/69. 
 WBB      SPACE  4
***              WBB WRITES THE CONTENTS OF A PP BUFFER TO A CIRCULAR 
*         BUFFER.  THE CIRCULAR BUFFER MUST CONTAIN ROOM FOR ALL
*         THE DATA SPECIFIED. 
*         ENTRY  (A) = ADDRESS OF PP BUFFER.
*                (T1) = WORD COUNT OF BUFFER. 
*                (FT - FT+1) = FIRST ADDRESS OF CM BUFFER.
*                (IN - IN+1) = NEXT INPUT ADDRESS.
*                (LM - LM+1) = LIMIT ADDRESS OF CM BUFFER.
*         EXIT   (IN - IN+1) UPDATED. 
*         USES   T1.
  
  
 WBB      SUBR               ENTRY/EXIT 
          STM    WBBA        SET WRITE ADDRESS
 WBB1     LDD    IN          STORE WORD 
          SHN    6
          ADD    RA 
          SHN    6
          ADD    IN+1 
          CWM    *,ON 
 WBBA     EQU    *-1
          AOD    IN+1        IN = IN + 1
          SHN    -14
          RAD    IN 
          LMD    LM 
          NJN    WBB2 
          LDD    IN+1 
          LMD    LM+1 
          NJN    WBB2        IF LIMIT NOT REACHED 
          LDD    FT          IN = FIRST 
          STD    IN 
          LDD    FT+1 
          STD    IN+1 
 WBB2     LDN    5           ADVANCE PP ADDRESS 
          RAM    WBBA 
          SOD    T1          DECREMENT WORD COUNT 
          NJN    WBB1        LOOP 
          UJN    WBBX        RETURN 
          SPACE  4
 QUAL$    IF     -DEF,QUAL$ 
          QUAL   *
 WBB      EQU    /COMPWBB/WBB 
 QUAL$    ENDIF 
          ENDX
