COMPVPA 
COMMON
          CTEXT  COMPVPA - VALIDATE PRIVILEGED ANALYST. 
          SPACE  4,10 
          IF -DEF,QUAL$,1 
          QUAL   COMPVPA
          BASE   MIXED
*         COMMENT  COPYRIGHT CONTROL DATA SYSTEMS INC.  1992. 
 VPA      SPACE  4,10 
***       VPA - VALIDATE PRIVILEGED ANALYST.
*         S. C. CHAMPION.    84/04/11.
*         P. C. SMITH.       87/11/16.
 VPA      SPACE  4,10 
***       *VPA* VALIDATES USER ACCESS TO PRIVILEGED ANALYST OPERATIONS. 
* 
*         EXIT   (A) = 0, IF PRIVILGED ANALYST OPERATIONS ALLOWED.
*                (A) .NE. 0, IF USER DOES NOT HAVE *CPAM* VALIDATION, 
*                            OR IF PRIVILEGED ANALYST MODE IS DISABLED. 
* 
*         USES   CM - CM+4. 
* 
*         MACROS NFA. 
  
  
 VPA3     LDN    1           DENY PRIVILEGED ANALYST OPERATIONS 
  
 VPA      SUBR               ENTRY/EXIT 
          LDD    CP 
          ADK    SEPW 
          CRD    CM 
          LDD    CM 
          SHN    21-2 
          PJN    VPA1        IF CALLER NOT *SSJ=* 
          LDD    CM+3 
          LPN    37 
          ADD    CM+4 
          ZJN    VPA1        IF NO *SSJ=* PARAMETER BLOCK PRESENT 
          NFA    SSJN+AACS   READ *AACW* FROM *SSJ=* PARAMETER BLOCK
          UJN    VPA2        CHECK FOR *CPAM* VALIDATION BIT
  
 VPA1     LDD    CP          READ *AACW* FROM CONTROL POINT AREA
          ADK    AACW 
 VPA2     CRD    CM 
          LDD    CM+2 
          SHN    21-3 
          PJN    VPA3        IF *CPAM* VALIDATION BIT NOT SET 
          LDK    SSTL        CHECK IF PRIVILEGED ANALYST MODE ENABLED 
          CRD    CM 
          LDD    CM+3 
          SHN    21-6 
          MJP    VPA3        IF PRIVILEGED ANALYST MODE DISABLED
          LDN    0           GRANT PERMISSION 
          UJP    VPAX        RETURN 
          SPACE  4,10 
          BASE   *
 QUAL$    IF     -DEF,QUAL$ 
          QUAL   *
 VPA      EQU    /COMPVPA/VPA 
 QUAL$    ENDIF 
          ENDX
