COMPUPP 
COMMON
          CTEXT  COMPUPP - UPDATE POT POINTER.
          IF     -DEF,QUAL$,1 
          QUAL   COMPUPP
*         COMMENT  COPYRIGHT CONTROL DATA SYSTEMS INC.  1992. 
 UPP      SPACE  4
***       UPP - UPDATE POT POINTER. 
*         R. E. TATE.        02/19/70.
 UPP      SPACE  4
***              UPP GIVEN A CURRENT POT POINTER GETS THE LINK TO 
*         THE NEXT POT IN THE CHAIN AND RETURNS IT. 
*         IF *TA* IS DEFINED IT IS ASSUMED TO CONTAIN THE RA FOR
*         TELEX.
* 
*         ENTRY-
*         (PP) = CURRENT POT POINTER. 
* 
*         EXIT- 
*         (A) = POT POINTER.
*         (PP) = UPDATED POT POINTER OR 
*         (PP) = 0 IF AT END OF POT CHAIN.
* 
*         USES- 
*         T1, CM - CM+4.
*         CALLS-
*         NONE. 
  
  
 UPP1     LDD    PP 
          LPN    3
          STD    T1          BYTE POSITION IN LINK TABLE
          LDD    PP 
          SHN    -2 
 UPPB     ADC    *           LINK TABLE ABSOLUTE ADDRESS
          CRD    CM 
          LDM    CM,T1
          STD    PP          SET NEW POT POINTER
  
 UPP      SUBR               ENTRY/EXIT 
          IF     -DEF,TA
 UPPA     LDD    RA          SET UP ABSOLUTE ADDRESS OF LINK TABLE
          ELSE   1
 UPPA     LDD    TA          SET UP ABSOLUTE ADDRESS OF LINK TABLE
          SHN    6
          IF     DEF,/REM/VPLP
          ADN    /REM/VPLP   POT LINK POINTER 
          ELSE   1
          ADN    VPLP        POT LINK POINTER 
          CRD    CM 
          LDD    CM+1 
          SHN    6
          IF     -DEF,TA
          ADD    RA 
          ELSE   1
          ADD    TA 
          SHN    6
          ADD    CM+2 
          STM    UPPB+1 
          SHN    -14
          RAM    UPPB 
          LDM    UPPC 
          STM    UPPA 
          UJN    UPP1 
  
 UPPC     BSS    0
          LOC    UPPA 
          UJN    UPP1 
          LOC    *O 
          SPACE  4
 QUAL$    IF     -DEF,QUAL$ 
          QUAL   *
 UPP      EQU    /COMPUPP/UPP 
 QUAL$    ENDIF 
          ENDX
