COMPSUD 
COMMON
          CTEXT  COMPSUD - SPIN UP/DOWN MASS STORAGE DEVICES. 
 SUD      SPACE  4,10 
          IF     -DEF,QUAL$,1 
          QUAL   COMPSUD
*         COMMENT  COPYRIGHT CONTROL DATA SYSTEMS INC.  1992. 
 SUD      SPACE  4,10 
***       SUD - SPIN UP/DOWN MASS STORAGE DEVICES.
*         M. L. SWANSON.     85/10/11.
 SUD      SPACE  4,10 
***              SUD PROVIDES THE UTILITY TO EITHER SPIN UP 
*         OR SPIN DOWN MASS STORAGE DEVICES.  IF SPIN UP IS 
*         SELECTED, ONLY THOSE DEVICES THAT ARE ON AND NOT
*         UNLOADED WILL BE ACTED UPON.
* 
*         ENTRY  (A) = 0 TO SPIN UP DEVICES.
*                    = 20 TO SPIN DOWN DEVICES. 
* 
*         EXIT   (A) = 0. 
* 
*         USES   CM - CM+4. 
* 
*         MACROS EXECUTE, SFA.
  
  
 SUD      SUBR               ENTRY/EXIT 
          LPN    20 
          STM    OVL0        SET OPTION 
          EXECUTE  0SD,OVL0+2 
          STM    SUDA        SET PROCESSOR ENTRY ADDRESS
          LDN    ESTP 
          CRD    CM 
          LDD    CM+3        LAST MASS STORAGE EST ORDINAL + 1
          STM    OVL0+1 
 SUD1     SOM    OVL0+1 
          ZJN    SUDX        IF END OF MASS STORAGE DEVICES 
          SFA    EST
          ADK    EQDE 
          CRD    CM          READ EST ENTRY 
          LDD    CM 
          SHN    21-13
          PJN    SUD1        IF NOT A MASS STORAGE DEVICE 
          LDM    OVL0 
          NJN    SUD2        IF SPIN DOWN OPERATION 
          LDD    CM 
          LPN    2
          NJN    SUD1        IF DEVICE IS OFF OR DOWN 
          LDD    CM+4 
          SHN    3
          ADN    STLL        FETCH MST STATUS WORD
          CRD    CM 
          LDD    CM 
          LPN    MLDUL
          NJN    SUD1        IF DEVICE UNLOADED 
 SUD2     RJM    0
 SUDA     EQU    *-1
          UJN    SUD1        PROCESS NEXT EST ENTRY 
 SUD      SPACE  4,10 
          IF     -DEF,QUAL$ 
          QUAL   *
 SUD      EQU    /COMPSUD/SUD 
          ENDIF 
          ENDX
