COMPSTA 
COMMON
          CTEXT  COMPSTA - SET TERMINAL TABLE ADDRESS.
          IF     -DEF,QUAL$,1 
          QUAL   COMPSTA
*         COMMENT  COPYRIGHT CONTROL DATA SYSTEMS INC.  1992. 
 STA      SPACE  4
***       STA - SET TERMINAL TABLE ADDRESS. 
*         R. E. TATE.        02/19/70.
 STA      SPACE  4
***              SETS UP THE ABSOLUTE ADDRESS OF THE FIRST WORD 
*         ADDRESS OF THE TERMINAL TABLE FOR THE GIVEN TERMINAL. 
*         IF *TA* IS DEFINED, IT IS ASSUMED TO CONTAIN THE RA FOR 
*         TELEX.
* 
*         ENTRY-
*         (TN) = TERMINAL NUMBER. 
* 
*         EXIT- 
*         (A) = TERMINAL TABLE ADDRESS (ABSOLUTE).
*         (TT - TT+1) = TERMINAL TABLE ADDRESS (ABSOLUTE).
* 
*         USES- 
*         CM - CM+4.
* 
*         CALLS-
*         NONE. 
  
  
 STA      SUBR               ENTRY/EXIT 
          IF     -DEF,TA
          LDD    RA 
          ELSE   1
          LDD    TA 
          SHN    6
          IF     DEF,/REM/VTTP
          ADN    /REM/VTTP   TELEX TERMINAL TABLE POINTER WORD
          ELSE   1
          ADN    VTTP        TELEX TERMINAL TABLE POINTER WORD
          CRD    CM 
          TTAP
          SHN    6
          ADD    CM+1 
          SHN    6
          IF     -DEF,TA
          ADD    RA 
          ELSE   1
          ADD    TA 
          SHN    6
          ADD    CM+2 
          STD    TT+1        SET TERMINAL TABLE ADDRESS 
          SHN    -14
          STD    TT 
          SHN    14 
          ADD    TT+1 
          UJN    STAX        EXIT WITH TERMINAL ADDRESS IN A REGISTER 
          SPACE  4
 QUAL$    IF     -DEF,QUAL$ 
          QUAL   *
 STA      EQU    /COMPSTA/STA 
 QUAL$    ENDIF 
          ENDX
