COMPSSF 
COMMON
          CTEXT  COMPSSF - SET SUBSYSTEM FLAG.
 COMPSSF  SPACE  4
          IF     -DEF,QUAL$,1 
          QUAL   COMPSSF
*         COMMENT  COPYRIGHT CONTROL DATA SYSTEMS INC.  1992. 
 COMPSSF  SPACE  4
***       SSF - SET SUBSYSTEM FLAG IN CONTROL POINT AREA. 
*         W. E. GOEBEL.      79/02/10.
 COMPSSF  SPACE  4
***              SSF INSURES THE CALLER IS VALIDATED FOR THE REQUESTED
*         SUBSYSTEM AND PLACES THE SUBSYSTEM INDEX IN THE CONTROL 
*         POINT AREA. 
* 
*         ENTRY  (A) = SUBSYSTEM INDEX. 
* 
*         EXIT   (A) .LT. 0 IF USER NOT VALIDATED FOR SUBSYSTEM.
* 
*         USES   T0, T1, CM - CM+4. 
* 
*         NOTE - THIS COMMON DECK REQUIRES THE PRESENCE OF *COMSREM*. 
  
  
 SSF2     SHN    14          SET BYTE POINTER 
          STD    T0 
          SHN    -14
          LMD    TH 
          STM    SSFA        INSERT SHIFT COUNT 
          LDD    CP          READ ACCOUNT ACCESS CONTROL WORD 
          ADK    AACW 
          CRD    CM 
          LDI    T0 
 SSFA     SHN    ** 
          MJN    SSF1        IF USER VALIDATED FOR SUBSYSTEM
 SSF3     LCN    0           SET ERROR RESPONSE 
  
 SSF      SUBR               ENTRY/EXIT 
          STD    T1 
          SBN    MSYS 
          PJN    SSF3        IF OUT OF RANGE
          LDM    TSAC,T1     GET AACW BYTE POINTER AND SHIFT COUNT
          NJN    SSF2        IF PERMISSION REQUIRED 
  
*         RESET SUBSYSTEM FLAG. 
  
 SSF1     LDD    CP          READ TELEX CONTROL WORD
          ADN    TXSW 
          CRD    CM 
          LDD    CM 
          LPN    77 
          SHN    14 
          LMD    T1 
          SHN    6
          STD    CM          INSERT SUBSYSTEM FLAG
          LDD    CP 
          ADN    TXSW 
          CWD    CM          WRITE TERMINAL INTERRUPT ADDRESS WORD
          UJN    SSFX        EXIT 
 TSAC     SPACE  4,10 
**        TSAC - TABLE OF SUBSYSTEM ACCESS CONTROLS.
* 
*T,       ONE WORD ENTRIES - 6/ B, 6/ S 
*         B      BYTE NUMBER + CM IN AACW CONTAINING VALIDATION BIT.
*         S      SHIFT COUNT TO PLACE VALIDATION BIT
*                IN A REGISTER SIGN BIT.
  
  
 TSAC     INDEX 
          INDEX  ACCS,21-1+4*100B+CM*100B 
          INDEX  MSYS 
          SPACE  4
          IF     -DEF,QUAL$,2 
          QUAL   *
 SSF      EQU    /COMPSSF/SSF 
          ENDX
