COMPSSE 
COMMON
          CTEXT  COMPSSE - SYSTEM SECTOR ERROR PROCESSOR. 
 SSE      SPACE  4
          BASE   MIXED
          IF     -DEF,QUAL$,1 
          QUAL   COMPSSE
*         COMMENT  COPYRIGHT CONTROL DATA SYSTEMS INC.  1992. 
 SSE      SPACE  4
***       SSE - SYSTEM SECTOR ERROR PROCESSOR.
*         L. C. HAAS.        75/06/04.
*         R. M. DESSEL.      82/02/15.
 SSE      SPACE  4
***              SSE BUILDS AND ISSUES A SYSTEM SECTOR ERROR MESSAGE. 
* 
*         IF *REL$* = 1 IS DEFINED, *COMPSSE* USES THE CONTENTS 
*         OF *LA* TO RELOCATE INSTRUCTIONS OTHER THAN THOSE 
*         ASSEMBLED WITH RELOCATION BY USE OF *COMPREL*.
* 
*         ENTRY  (A) = OFFSET ADDRESS 
*                (A) = 0 IF ONLY TRACK NUMBER IS TO BE REPORTED.
*                (T3) = 0, IF (A) = NFL ADDRESS.
*                     = 1, IF (A) = EJT ADDRESS.
*                     = 2, IF (A) = QFT ADDRESS.
*                (T5) = EST ORDINAL.
*                (T6) = FIRST TRACK.
* 
*         EXIT   MESSAGE ISSUED TO ERROR LOG AND DAYFILE. 
* 
*         USES   T1, T2, T3, CM - CM+4. 
* 
*         CALLS  C2D, DFM.
* 
*         MACROS SFA. 
  
  
 SSE5     LDC    SSEA+ERLN   MESSAGE TO ERRLOG
 REL$     IF     DEF,REL$ 
 REL$     IFEQ   REL$,1 
          ADD    LA          RELOCATE ADDRESS 
 REL$     ENDIF 
          RJM    DFM
          LDC    SSEA        MESSAGE TO DAYFILE 
 REL$     IF     DEF,REL$ 
 REL$     IFEQ   REL$,1 
          ADD    LA          RELOCATE ADDRESS 
 REL$     ENDIF 
          RJM    DFM
  
 SSE      SUBR               ENTRY/EXIT 
          STD    T2 
          SHN    -14
          STD    T1 
 REL$     IF     DEF,REL$ 
 REL$     IFEQ   REL$,1 
          LDC    SSEA+14     RELOCATE INSTRUCTION ADDRESSES 
          ADD    LA 
          STM    SSEC 
 REL$     ENDIF 
          SFA    EST,T5      SET EQUIPMENT MNEMONIC 
          ADK    EQDE 
          CRD    CM 
          LDD    CM+3 
          STM    SSEA 
          LDD    T5          CONVERT UPPER TWO DIGITS OF EST ORDINAL
          SHN    -3 
          RJM    C2D
          STM    SSEA+1 
          LDD    T5          CONVERT LOWER DIGIT OF EST ORDINAL 
          LPN    7
          SHN    6
          ADC    2R0, 
          STM    SSEA+2 
          LDD    T6          CONVERT FIRST TRACK
          SHN    -6 
          RJM    C2D
          STM    SSEA+7 
          LDD    T6 
          RJM    C2D
          STM    SSEA+10
          LDD    T1          READ FILE NAME 
          SHN    14 
          LMD    T2 
          NJN    SSE1        IF ADDRESS PRESENT 
          STM    SSEA+12     SET END OF MESSAGE 
          LDC    2R.
          STM    SSEA+11
          LJM    SSE5 
  
 REL$     IF     DEF,REL$ 
 REL$     IFEQ   REL$,1 
 SSE1     CRM.   SSEA+14,ON 
 REL$     ELSE
 SSE1     CRM    SSEA+14,ON 
 REL$     ENDIF 
 SSEC     EQU    *-1
          LDC    SSEA+17+1
 REL$     IF     DEF,REL$ 
 REL$     IFEQ   REL$,1 
          ADD    LA          RELOCATE ADDRESS 
 REL$     ENDIF 
          STD    T1 
          LDM    SSEA+17     CLEAR FILE BITS
          SCN    77 
          STM    SSEA+17
          LDD    T3 
          ZJN    SSE1.1      IF FNT NAME TYPE 
          LDN    0
          STM    SSEA+16     REMOVE FO, UI ENTRY
          STM    SSEA+17
          UJN    SSE1.2      PROCESS QFT OR EJT TYPE
  
 SSE1.1   LDI    T1          GET FILE TYPE
          SHN    -6 
          STD    T2 
          SBN    MXFT 
          PJN    SSE2        IF ILLEGAL TYPE
          LDC    SSEB 
          UJN    SSE1.4      SET FILE TYPE
  
 SSE1.2   LDD    T3 
          LMN    1
          NJN    SSE1.3      IF NOT EJT TYPE
          LDC    2HEX 
          SHN    -6 
          UJN    SSE1.5      STORE JOB STATUS 
  
 SSE1.3   LMN    2&1
          NJN    SSE2        IF NOT QFT TYPE
          LDI    T1          GET DISPOSITION TYPE 
          SHN    -11
          STD    T2 
          SBN    NRQT 
          PJN    SSE2        IF ILLEGAL TYPE
          LDC    SSED 
 SSE1.4   BSS    0
 REL$     IF     DEF,REL$ 
 REL$     IFEQ   REL$,1 
          ADD    LA 
 REL$     ENDIF 
          RAD    T2 
          LDI    T2 
 SSE1.5   STM    SSEA+12
 SSE2     LDN    0
          STI    T1 
 SSE3     SOD    T1          DECREMENT POINTER
          LDI    T1 
          ZJN    SSE3        IF NAME NOT IN THIS BYTE 
          LPN    77          CHECK LOWER CHARACTER
          ZJN    SSE4        IF LOWER CHARACTER ZERO
          AOD    T1 
          LDC    2R. &1R. 
 SSE4     LMN    1R.
          RAI    T1 
          LJM    SSE5 
  
  
 SSEA     DATA   C/EQXXX, SSER, TNNNN, **, FILENAM./
 SSEB     DATA   C*"NMFT"*
 SSED     DATA   C*"NMQT"*
 SSE      SPACE  4
          BASE   *
 QUAL$    IF     -DEF,QUAL$ 
          QUAL   *
 SSE      EQU    /COMPSSE/SSE 
 QUAL$    ENDIF 
          ENDX
