COMPSRU 
COMMON
          CTEXT  COMPSRU - SET SRU CONTROL FIELDS.
          SPACE  4,10 
          IF     -DEF,QUAL$,1 
          QUAL   COMPSRU
*         COMMENT  COPYRIGHT CONTROL DATA SYSTEMS INC.  1992. 
          SPACE  4,10 
***       SRU - SET SRU CONTROL FIELDS. 
*         S. L. BETH         78/07/27.
          SPACE  4,10 
***       *SRU* SETS THE *SRU* CONTROL FIELDS IN CONTROL POINT
*         WORDS *STLW*, *SRJW* AND *FPFW*.
* 
*         ENTRY  (A) = VALIDATION LIMIT.
* 
*         USES   CM - CM+4, CN - CN+4, FN - FN+4. 
* 
*         MACROS MONITOR. 
  
  
 SRU      SUBR               ENTRY/EXIT 
          SHN    3           VALIDATION LIMIT * 10B 
          STD    CM+4 
          SHN    -14
          STD    CM+3 
          LDD    CP          READ SRU CONTROL WORDS 
          ADN    STLW 
          CRD    CN 
          ADN    FPFW-STLW
          CRD    FN 
          LDD    CM+3        SET SRU FIELDS 
          SHN    14 
          LMD    CM+4 
          SHN    22-6        SET (VALIDATION LIMIT)/100B IN *FPFW*
          STD    FN+1 
          STD    CN 
          SHN    14 
          LMD    CN+1 
          SCN    77 
          LMD    CN+1 
          STD    CN+1 
          LDD    CP          REWRITE FIELDS 
          ADN    STLW 
          CWD    CN 
          ADN    FPFW-STLW
          CWD    FN 
          LDN    RLSL        SET NEW JOB STEP LIMIT 
          STD    CM+1 
          MONITOR  RLMM 
          LJM    SRUX        RETURN 
          SPACE  4,10 
 QUAL$    IF     -DEF,QUAL$ 
          QUAL   *
 SRU      EQU    /COMPSRU/SRU 
 QUAL$    ENDIF 
          ENDX
