COMPSRA 
COMMON
          CTEXT  COMPSRA - SET RANDOM ADDRESS.
 SRA      SPACE  4
          IF     -DEF,QUAL$,1 
          QUAL   COMPSRA
*         COMMENT  COPYRIGHT CONTROL DATA SYSTEMS INC.  1992. 
 SRA      SPACE  4
***       SRA - SET RANDOM ADDRESS. 
*         G. R. MANSFIELD.  70/08/09. 
          SPACE  4
***              SRA DETERMINES THE RANDOM ADDRESS CORRESPONDING TO 
*         A GIVEN TRACK AND SECTOR. 
* 
*         IF *IRA$* IS DEFINED, INITIALIZATION IS ASSUMED TO BE 
*         PERFORMED.  DECK -COMPIRA- CAN BE USED TO DO THIS.
* 
*         ENTRY  (A) = FIRST TRACK. 
*                (T5) = EST ORDINAL.
*                (T6) = CURRENT TRACK.
*                (T7) = CURRENT SECTOR. 
* 
*         EXIT   (RI - RI+1) = RANDOM ADDRESS.
*                (A) " 0 IF TRACK AND SECTOR NOT ON TRACK CHAIN.
* 
*         USES   T1, T3, CM - CM+4. 
* 
*         MACROS SFA. 
* 
*         XREF   COMSPIM. 
  
  
 SRA1     SHN    -6          CHECK TRACK
          LMD    T6 
          ZJN    SRAX        IF CURRENT TRACK REACHED 
          LMD    T6          SET NEXT TRACK 
          STD    T0 
          LPN    3
          STD    T1 
          LDP    SLM
          RAD    RI+1 
          SHN    -14
          RAD    RI 
          LDD    T0          READ TRT WORD
          SHN    -2 
 SRAA     ADC    TRTS 
          CRD    CM 
          LDM    CM,T1       CHECK NEXT LINK
 SRA2     SHN    6
          MJN    SRA1        IF NOT END OF CHAIN
          LDN    1           RETURN ERROR RESPONSE
  
 SRA      SUBR               ENTRY/EXIT 
          STD    T3          SAVE FIRST TRACK 
          LDD    T7 
          STD    RI+1 
          SHN    -14         INITIAL ADDRESS = CURRENT SECTOR 
          STD    RI 
  
          IF     -DEF,IRA$
          SFA    EST,T5      READ EST ENTRY 
          ADK    EQDE 
          CRD    CM 
          LDD    CM+4 
          SHN    3
          ADK    MDGL 
          CRD    CM 
          ADK    TRLL-MDGL
          CRD    T7 
          LDD    CM+4        SET SECTOR LIMIT 
          STP    SLM
          LDD    RI+1        RESTORE SECTOR 
          STD    T7 
          LDD    T7+3        SET TRT FWA
          LPN    77 
          SHN    14 
          LMD    T7+4 
          SBD    TH          4000/2 
          STM    SRAA+1 
          SHN    -14
          LMC    ADCI 
          STM    SRAA 
          ENDIF 
  
          LDD    T3          BEGIN WITH FIRST TRACK 
          UJP    SRA2        ENTER LOOP 
          SPACE  4
 QUAL$    IF     -DEF,QUAL$ 
          QUAL   *
 SRA      EQU    /COMPSRA/SRA 
 SRAA     EQU    /COMPSRA/SRAA
 QUAL$    ENDIF 
          ENDX
