COMPSPA 
COMMON
          CTEXT  COMPSPA - SET POT ADDRESS. 
          IF     -DEF,QUAL$,1 
          QUAL   COMPSPA
*         COMMENT  COPYRIGHT CONTROL DATA SYSTEMS INC.  1992. 
 SPA      SPACE  4
***       SPA - SET POT ADDRESS.
*         R. E. TATE.        02/19/70.
 SPA      SPACE  4
***              SPA GIVEN A POT POINTER WILL SET UP A POT ADDRESS. 
*         IF THE SYMBOL *TA* IS DEFINED THAT WILL BE ASSUMED TO 
*         CONTAIN THE RA OF THE TELEX CONTROL POINT.
* 
*         ENTRY-
*         (PP) = POT POINTER. 
* 
*         EXIT- 
*         (PA - PA+1) = POT ADDRESS (ABSOLUTE). 
*         (A) = POT ADDRESS (ABSOLUTE). 
* 
*         USES- 
*         CM - CM+4.
* 
*         CALLS-
*         NONE. 
  
  
 SPA      SUBR               ENTRY/EXIT 
          IF     -DEF,TA
          LDD    RA 
          ELSE   1
          LDD    TA 
          SHN    6
          IF     DEF,/REM/VBMP
          ADN    /REM/VBMP   BUFFER MEMORY POINTER IN TELEX 
          ELSE   1
          ADN    VBMP        BUFFER MEMORY POINTER IN TELEX 
          CRD    CM 
          LDD    CM+3 
          SHN    6
          IF     -DEF,TA
          ADD    RA 
          ELSE   1
          ADD    TA 
          SHN    3
          ADD    PP 
          SHN    3
          ADD    CM+4 
          STD    PA+1        SET POT ADDRESS
          SHN    -14
          STD    PA 
          SHN    14 
          ADD    PA+1 
          UJN    SPAX        RETURN 
          SPACE  4
 QUAL$    IF     -DEF,QUAL$ 
          QUAL   *
 SPA      EQU    /COMPSPA/SPA 
 QUAL$    ENDIF 
          ENDX
