COMPSNT 
COMMON
          CTEXT  COMPSNT - SET NEXT TRACK.
 SNT      SPACE  4
          IF     -DEF,QUAL$,1 
          QUAL   COMPSNT
*         COMMENT  COPYRIGHT CONTROL DATA SYSTEMS INC.  1992. 
 SNT      SPACE  4
***       SNT - SET NEXT TRACK. 
*         G. R. MANSFIELD.  70/08/09. 
          SPACE  4
***              SNT DETERMINES THE NEXT TRACK IN THE TRACK LINK
*         TABLE.
* 
*         IF *IRA$* IS DEFINED, INITIALIZATION IS ASSUMED TO BE 
*         PERFORMED.  DECK -COMPIRA- CAN BE USED TO DO THIS.
* 
*         ENTRY  (T5) = EST ORDINAL.
*                (T6) = CURRENT TRACK.
* 
*         EXIT   (A) = NEXT TRACK LINK. 
*                (CM - CM+4) = WORD READ FROM TRT.
*                (T1) = BYTE NUMBER.
* 
*         USES   T1, CM - CM+4. 
* 
*         MACROS SFA. 
* 
*         XREF   COMSPIM. 
  
  
 SNT      SUBR               ENTRY/EXIT 
  
          IF     -DEF,IRA$
          SFA    EST,T5      READ EST ENTRY 
          ADK    EQDE 
          CRD    CM 
          LDD    CM+4        SET FWA OF TRT 
          SHN    3
          ADN    TRLL 
          CRD    CM 
          LDD    CM+3 
          LPN    77 
          SHN    14 
          LMD    CM+4 
          SBD    TH          4000/2 
          STM    SNTA+1 
          SHN    -14
          LMC    ADCI 
          STM    SNTA 
          ENDIF 
  
          LDD    T6          READ TRT WORD
          SHN    -2 
 SNTA     ADC    TRTS 
          CRD    CM 
          LDD    T6          SET BYTE INDEX 
          LPN    3
          STD    T1 
          LDM    CM,T1       RETURN WITH NEXT LINK
          UJP    SNTX        RETURN 
          SPACE  4
 QUAL$    IF     -DEF,QUAL$ 
          QUAL   *
 SNT      EQU    /COMPSNT/SNT 
 SNTA     EQU    /COMPSNT/SNTA
 QUAL$    ENDIF 
          ENDX
