COMPSIC 
COMMON
          CTEXT  COMPSIC - SET PP INSTRUCTION CONSTANTS.
          IF     -DEF,QUAL$,1 
          QUAL   COMPSIC
          BASE   M
*         COMMENT  COPYRIGHT CONTROL DATA SYSTEMS INC.  1992. 
 SIC      SPACE  4,10 
***       SIC - SET PP INSTRUCTION CONSTANTS. 
* 
*         G. S. YODER.       91/06/21.
 SIC      SPACE  4,20 
***       *COMPSIC* RELOCATES PP INSTRUCTIONS ASSEMBLED BY THE TXXX 
*         MACROS WHERE XXX IS A PP INSTRUCTION MNEMONIC.  THE TXXX
*         MACROS REMOTELY ASSEMBLE A TWO WORD RELOCATION TABLE ENTRY
*         FOR EACH INSTRUCTION.  THE TABLE MUST BE TERMINATED BY THE
*         CALLER WITH A ZERO WORD.
* 
*         TABLE ENTRY FORMAT -
* 
*T        12/ IADD, 12/ RADD
* 
*                IADD = ADDRESS OF INSTRUCTION TO BE MODIFIED 
*                RADD = ADDRESS OF CELL CONTAINING AN 18 BIT VALUE TO 
*                         BE ADDED TO THE INSTRUCTION 
* 
*         ENTRY  (A) = ADDRESS OF INSTRUCTION MODIFICATION TABLE. 
* 
*         EXIT   INSTRUCTIONS MODIFIED. 
* 
*         USES   T1, T2, T3.
  
  
 SIC      SUBR               ENTRY/EXIT 
          STD    T1          SET RELOCATION TABLE ADDRESS 
 SIC1     LDI    T1 
          ZJN    SICX        IF END OF TABLE
          STD    T2          SET INSTRUCTION ADDRESS
          AOD    T1 
          LDI    T1          SET RELOCATION CELL ADDRESS
          STD    T3 
          LDM    1,T3        RELOCATE INSTRUCTION 
          RAM    1,T2 
          SHN    -14
          ADI    T3 
          RAI    T2 
          AOD    T1          ADVANCE TO NEXT ENTRY
          UJN    SIC1        PROCESS NEXT INSTRUCTION 
  
  
 QUAL$    IF     -DEF,QUAL$ 
          QUAL   *
 SIC      EQU    /COMPSIC/SIC 
 QUAL$    ENDIF 
          ENDX
