COMPSEI 
COMMON
          CTEXT  COMPSEI - SEARCH FOR END OF INFORMATION. 
 SEI      SPACE  4
          IF     -DEF,QUAL$,1 
          QUAL   COMPSEI
*         COMMENT  COPYRIGHT CONTROL DATA SYSTEMS INC.  1992. 
 SEI      SPACE  4
***       SEI - SEARCH FOR END OF INFORMATION.
*         G. R. MANSFIELD.   70/08/09.
*         K. R. COMBS.       75/12/12.
 SEI      SPACE  4
***              SEI SETS THE TRACK AND SECTOR LOCATIONS FOR THE END
*         OF INFORMATION SECTOR OF A MASS STORAGE FILE. 
* 
*         IF *IRA$* IS DEFINED, INITIALIZATION IS ASSUMED TO BE 
*         PERFORMED.  DECK -COMPIRA- CAN BE USED TO DO THIS.
*         IF *SEI$* IS NOT DEFINED, UP TO DATE TRT IN MMF SYSTEM IS 
*         NOT GUARANTEED. 
* 
*         ENTRY  (T5) = 3/R, 9/EST ORDINAL. 
*                       R = 1, IF RETURN-ON-INACCESSIBLE REQUESTED. 
*                (T6) = FIRST TRACK.
*                (A) .EQ. 0 IF TRT MUST BE CURRENT (SEI$ DEFINED).
*                (A) .NE. 0 IF CURRENT TRT NOT REQUIRED (SEI$ DEFINED). 
* 
*         EXIT   (A) = TRACK COUNT, IF DEVICE ACCESSIBLE. 
*                (A) .LT. 0, IF DEVICE INACCESSIBLE.
*                (T5) = EST ORDINAL.
*                (T6) = LAST TRACK. 
*                (T7) = LAST SECTOR.
*                (T2 - T3) = SECTOR COUNT.
* 
*         USES   T1, CM - CM+4. 
* 
*         MACROS MONITOR, SFA.
* 
*         XREF   COMSPIM. 
  
  
 SEI      SUBR               ENTRY/EXIT 
  
 SEI$     IF     DEF,SEI$ 
          NJN    SEI1        IF NO TRT UPDATE NEEDED
          LDN    UTRS        SET SUBFUNCTION CODE 
          STD    CM+3 
          LDD    T5          SET RETURN-ON-INACCESSIBLE / EST ORDINAL 
          STD    CM+1 
          LPC    777
          STD    T5          EST ORDINAL
          MONITOR STBM
          LDD    CM+1        CHECK INACCESSIBLE STATUS
          SHN    21-11
          MJN    SEIX        IF DEVICE IS INACCESSIBLE
 SEI1     BSS    0
 SEI$     ENDIF 
 IRA$     IF     -DEF,IRA$
          SFA    EST,T5      READ EST ENTRY 
          ADK    EQDE 
          CRD    CM 
          LDD    CM+4 
          SHN    3
          ADK    MDGL 
          CRD    CM 
          ADK    TRLL-MDGL
          CRD    T7 
          LDD    CM+4        SET SECTOR LIMIT 
          STP    SLM
          LDD    T7+3        SET TRT FWA
          LPN    77 
          SHN    14 
          LMD    T7+4 
          SBD    TH          4000/2 
          STM    SEIA+1 
          SHN    -14
          LMC    ADCI 
          STM    SEIA 
 IRA$     ENDIF 
          LDN    0           CLEAR SECTOR COUNT 
          STD    T3 
          STD    T2 
          STD    T0 
 SEI2     LDD    T6          READ TRT WORD
          SHN    -2 
 SEIA     ADC    TRTS 
          CRD    CM 
          LDD    T6          SET BYTE INDEX 
          LPN    3
          STD    T1 
          LDM    CM,T1       CHECK NEXT LINK
          SHN    6
          PJN    SEI3        IF LAST SECTOR 
          SHN    -6 
          STD    T6 
          LDP    SLM
          RAD    T3 
          SHN    -14
          RAD    T2 
          AOD    T0          ADVANCE TRACK COUNT
          UJN    SEI2        LOOP 
  
 SEI3     SHN    -6          SET LAST SECTOR
          STD    T7 
          RAD    T3          COUNT SECTORS
          SHN    -14
          RAD    T2 
          AOD    T0          (A) = TRACK COUNT
          LJM    SEIX        RETURN 
          SPACE  4
 QUAL$    IF     -DEF,QUAL$ 
          QUAL   *
 SEI      EQU    /COMPSEI/SEI 
 SEIA     EQU    /COMPSEI/SEIA
 QUAL$    ENDIF 
          ENDX
