COMPSDR 
COMMON
          CTEXT  COMPSDR - SET BUFFERED DISK REQUESTS.
 COMPSDR  SPACE  4,10 
          IF     -DEF,QUAL$,1 
          QUAL   COMPSDR
*         COMMENT  COPYRIGHT CONTROL DATA SYSTEMS INC.  1992. 
 COMPSDR  SPACE  4,10 
***       SDR - SET BUFFERED DISK REQUESTS. 
*         S. L. BETH         86/08/04.
 SDR      SPACE  4,10 
**        SDR - SET BUFFERED DEVICE REQUEST.
* 
*         ENTRY  (A) = BIT TO SET.
*                (A) = 4000B + BIT TO SET, IF FIRMWARE IDENT REQUEST. 
*                (T5) = EST ORDINAL.
*                (T2) = NUMBER OF UNITS.
* 
*         USES   T1, T2, T3, CM - CM+4. 
* 
*         MACROS DELAY, MONITOR, PAUSE. 
  
  
 SDR3     DELAY 
          PAUSE  NE 
          LDD    T3 
 SDR4     SHN    PUTLS       READ UNIT DESCRIPTOR WORD
          ADC    0
 SDRD     EQU    *-1
          CRD    CM 
          STD    CM+4        SAVE ADDRESS FOR MONITOR CALL
          SHN    -14
          STD    CM+3 
          LDD    CM+1        CHECK EST ORDINAL
          LMD    T5 
          NJN    SDR5        IF NOT REQUESTED DEVICE
          LDD    T1 
          STD    CM+1 
          LDD    MA          STORE *UTEM* REQUESTS IN MESSAGE BUFFER
          CWM    SDRC,CM+1
          MONITOR  UTEM      SET FLAG FOR BUFFERED DEVICE DRIVER
          LDD    CM+1 
          NJN    SDR3        IF REQUEST NOT PROCESSED 
          SOD    T2 
          MJN    SDRX        IF NO MORE UNITS 
 SDR5     SOD    T3 
 SDR6     NJN    SDR4        IF NOT END OF *PUT*
  
 SDR      SUBR               ENTRY/EXIT 
          SHN    6           SET BIT IN REQUESTS
          STM    SDRC+1 
          STM    SDRC+1+1*5 
          SHN    0-21        SET *UTEM* PARAMETER COUNT 
          ADN    2
          STD    T1 
 SDR1     LDC    0
 SDRA     EQU    *-1
 SDR2     STD    T3          SET NUMBER OF ENTRIES IN *PUT* 
 SDRB     LDC    BIOL 
*         UJN    SDR6        (AFTER FIRST CALL) 
          CRD    CM 
          ISTORE SDRB,(UJN SDR6)
          LDD    CM+1        FETCH *PUT* TABLE POINTER WORD 
          SHN    14 
          LMD    CM+2 
          ADN    PUTP 
          CRD    CM 
          LDD    CM+4        SET FWA OF *UNCT* WORD IN *PUT*
          ADK    UNCT 
          STM    SDRD 
          SHN    -14
          ADD    CM+3 
          LPN    37 
          RAM    SDRD-1 
          LDD    CM          NUMBER OF ENTRIES IN TABLE 
          STM    SDRA 
          UJN    SDR2        SEARCH *PUT* FOR SPECIFIED DEVICE
  
  
 SDRC     VFD    1/1,5/PILL-UNCT,6/1,6/0,42/0  *UTEM* INTERLOCK 
          VFD    1/0,5/PILL-UNCT,6/1,6/0,42/1  *UTEM* REQUEST 
          VFD    1/0,5/PILL-UNCT,6/6,6/22,42/0 *UTEM* CHANNEL 
 COMPSDR  SPACE  4,10 
          IF     -DEF,QUAL$ 
          QUAL   *
 SDR      EQU    /COMPSDR/SDR 
          ENDIF 
          ENDX
