COMPSDA 
COMMON
          CTEXT  COMPSDA - SET DEVICE AVAILABLE.
 SDA      SPACE  4,10 
          IF     -DEF,QUAL$,1 
          QUAL   COMPSDA
*         COMMENT  COPYRIGHT CONTROL DATA SYSTEMS INC.  1992. 
 SDA      SPACE  4,10 
***       SDA - SET DEVICE AVAILABLE. 
*         P. D. HAAS         86/04/16.
 SDA      SPACE  4,15 
***              SDA SETS A MASS STORAGE DEVICE AVAILABLE FOR 
*         USE BY THE SYSTEM.  PRIOR TO THIS, SDA WILL SET THE 
*         DEVICE SUSPECT FLAG IF DISK VALIDATION IS ENABLED,
*         THUS ENABLING *1MV* TO PERFORM PATH VERIFICATION. 
* 
* 
*         ENTRY  (T5) = EST ORDINAL.
* 
*         EXIT   (A) = 0. 
* 
*         USES   CM - CM+4. 
* 
*         MACROS MONITOR. 
  
  
 SDA      SUBR               ENTRY/EXIT 
          LDN    SSTL 
          CRD    CM          FETCH SYSTEM STATUS WORD 
          LDD    CM+1 
          LPN    40 
          NJN    SDA1        IF DISK VALIDATION DISABLED
          LDD    T5 
          STD    CM+1 
          LDN    SSES        SET SUBFUNCTION
          STD    CM+2 
          MONITOR  SEQM      SET DEVICE SUSPECT 
 SDA1     LDD    T5 
          STD    CM+1 
          LDC    -110        MASK (CLEAR UNAVAILABLE) 
          STD    CM+3 
          LDN    10          DEVICE ACTIVE FLAG 
          STD    CM+4 
          LDN    SB0S        SET DEVICE AVAILABLE 
          STD    CM+2 
          MONITOR  SEQM 
          UJN    SDAX        RETURN 
 SDA      SPACE  4,10 
          IF     -DEF,QUAL$ 
          QUAL   *
 SDA      EQU    /COMPSDA/SDA 
          ENDIF 
          ENDX
