COMPRSI 
COMMON
          CTEXT  COMPRSI - REQUEST STORAGE INCREASE.
 RSI      SPACE  4
          IF     -DEF,QUAL$,1 
          QUAL   COMPRSI
*         COMMENT  COPYRIGHT CONTROL DATA SYSTEMS INC.  1992. 
 RSI      SPACE  4
***       RSI - REQUEST STORAGE INCREASE. 
*         G. R. MANSFIELD.  70/08/30. 
*         R. J. PRIEVE.      79/08/28.
 RSI      SPACE  4
***              RSI PROCESSES STORAGE CHANGES WHERE IT IS
*         DESIRED TO USE *FLIW* FOR INCREASES.
* 
*         ENTRY  (A) = DESIRED FL/100B. 
* 
*         EXIT   (A) = 0 IF INCREASE ASSIGNED.
*                (A) < 0 IF INCREASE NOT AVAILABLE. 
*                (A) > 0 IF INCREASE PENDING. 
* 
*         USES   CM - CM+4. 
* 
*         MACROS MONITOR. 
  
*         CHECK FOR *FLIW* REQUEST PENDING. 
  
 RSI2     LDD    CP          READ *FLIW*
          ADN    FLIW 
          CRD    CM 
          LDD    CM+4 
          NJN    RSI1        IF REQUEST PENDING 
  
  
 RSI      SUBR               ENTRY/EXIT 
          STD    T0          SAVE DESIRED FL
          LMD    FL 
          ZJN    RSI2        IF NO CHANGE REQUESTED 
 RSI1     LDD    T0 
          STD    CM+1        SAVE FL REQUEST
          LDD    HN          SET CM REQUEST TO USE *FLIW* 
          STD    CM+2 
          MONITOR  RSTM      REQUEST STORAGE
          LDD    CM+1 
          ZJN    RSIX        IF STORAGE ASSIGNED
          LDD    CP          READ FL INCREASE CONTROL WORD
          ADN    FLIW 
          CRD    CM 
          LDD    CM+1 
          SHN    21-0 
          MJN    RSIX        IF INCREASE REJECTED BY SCHEDULER
          LDN    1           SET INCREASE PENDING 
          UJN    RSIX        RETURN 
          SPACE  4
 QUAL$    IF     -DEF,QUAL$ 
          QUAL   *
 RSI      EQU    /COMPRSI/RSI 
 QUAL$    ENDIF 
          ENDX
