COMPRLA 
COMMON
          CTEXT  COMPRLA - READ SECTOR OF LOCAL AREAS.
          SPACE  4,10 
          IF     -DEF,QUAL$,1 
          QUAL   COMPRLA
          BASE   M
*         COMMENT  COPYRIGHT CONTROL DATA SYSTEMS INC.  1992. 
          SPACE  4,10 
*****     RLA - READ SECTOR OF LOCAL AREAS. 
* 
*         P. D. HAAS.        79/05/01.
          SPACE  4,10 
***              *RLA* READS THE SECTOR OF LOCAL AREAS FROM A 
*         SPECIFIED MASS STORAGE DEVICE.  THE SECTOR OF LOCAL 
*         AREAS (SLA) WILL BE READ IF SUCH EXISTS, AS INDICATED 
*         BY THE SLA FLAG IN THE *ACGL* WORD OF THE MST.
* 
*         IF THE SYMBOL *RLA$* IS DEFINED, THE DRIVER IS ASSUMED TO 
*         BE LOADED, (T6) = LABEL TRACK, AND A SECTOR OF LOCAL AREAS
*         IS ASSUMED TO BE PRESENT. 
 RLA      SPACE  4,20 
**        RLA - READ SECTOR OF LOCAL AREAS (SLA). 
* 
*         ENTRY  (T5) = EST ORDINAL.
* 
*         EXIT   (A) = ADDRESS OF DAYFILE DATA IN SLA ENTRY.
*                    = 0 IF NO SLA, OR NO ENTRY FOR THIS MACHINE. 
*                    .LT. 0 IF ERROR READING SLA. 
*                (T3) = ADDRESS OF SLA ENTRY. 
*                (T6) = LABEL TRACK.
*                (T7) = SLA SECTOR. 
*                (BFMS) = SLA SECTOR. 
* 
*         USES   T2, CM - CM+7. 
* 
*         CALLS  RDS. 
* 
*         MACROS ENDMS, SETMS.
* 
*         NOTES  THIS COMMON DECK REQUIRES *COMSMMF*, *COMSMST*.
  
  
 RLA      SUBR               ENTRY/EXIT 
          IF     -DEF,RLA$
          SETMS  IO 
          LDD    CM+4        READ MST 
          SHN    3
          ADN    ACGL 
          CRD    CM+2 
          ADN    ALGL-ACGL
          CRD    CM 
          LDD    CM+6        CHECK SLA PRESENT
          LPC    MGLAP
          ZJN    RLAX        IF NO SLA
          LDD    CM+1        SET LABEL TRACK
          STD    T6 
          ENDIF 
          LDN    LMLT        SET SLA SECTOR 
          STD    T7 
          LDC    BFMS-10     INITIALIZE SEARCH ADDRESS
          STD    T3 
          ADN    10          READ SLA 
          RJM    RDS
          MJN    RLAX        IF MASS STORAGE ERROR
          ENDMS              RELEASE CHANNEL
          LDM    BFMS 
          SBN    1
          MJN    RLA3        IF SECTOR NOT REFORMATTED
          LDM    BFMS+1      SET END OF DATA IN SLA 
          STD    T2 
          SHN    2
          ADC    BFMS+2 
          RAD    T2 
          LDC    MMFL        GET MACHINE ID 
          CRD    CM 
 RLA1     LDN    2*5         ADVANCE SLA ADDRESS
          RAD    T3 
          LMD    T2 
          ZJN    RLA3        IF END OF DATA 
          LDI    T3 
          LMD    CM 
          NJN    RLA1        IF NOT SLA ENTRY FOR THIS MACHINE
          LDM    2,T3 
          NJN    RLA2        IF LAST USED ON POST LEVEL 509 SYSTEM
          STM    10,T3       CLEAR MAINTENANCE LOG POINTER
 RLA2     LDD    T3          SET ADDRESS OF DAYFILE DATA
          ADN    5
 RLA3     LJM    RLAX        RETURN 
 RLA      SPACE  4,10 
          BASE   *
 QUAL$    IF     -DEF,QUAL$ 
          QUAL   *
 RLA      EQU    /COMPRLA/RLA 
 QUAL$    ENDIF 
          ENDX
