COMPRJC 
COMMON
          CTEXT  COMPRJC - CALCULATE JCB ADDRESS. 
 RJC      SPACE  4,10 
          IF     -DEF,QUAL$,1 
          QUAL   COMPRJC
*         COMMENT  COPYRIGHT CONTROL DATA SYSTEMS INC.  1992. 
 RJC      SPACE  4
***       RJC - READ JOB CONTROL WORD.
*         G. R. MANSFIELD.  70/07/20. 
 RJC      SPACE  4
***              *RJC* CALCULATES THE FIRST WORD ADDRESS OF THE 
*         JOB CONTROL BLOCK FOR A GIVEN SERVICE CLASS.
* 
*         ENTRY  (A) = SERVICE CLASS. 
* 
*         EXIT   (A) = ADDRESS OF FIRST WORD OF JOB CONTROL BLOCK.
*                    = 0 IF NO *JCB* EXISTS FOR THE SERVICE CLASS.
*                (T0) = *JCB* OFFSET. 
* 
*         USES   T0, CM - CM+4. 
* 
*         MACROS CFI. 
  
  
 RJC1     LDN    0           INDICATE NO *JCB*
  
 RJC      SUBR               ENTRY/EXIT 
          CFI    JCB         CONVERT ORDINAL TO OFFSET
          STD    T0          SAVE OFFSET OF *JCB* 
          ADC    -MXJC*JCBE 
          PJN    RJC1        IF NO *JCB* EXISTS FOR THIS SERVICE CLASS
          LDK    JBCP        READ JOB CONTROL AREA POINTER
          CRD    CM 
          LDD    CM          ASSEMBLE *JCB* ADDRESS 
          SHN    14 
          LMD    CM+1 
          ADD    T0 
          UJN    RJCX        RETURN 
          SPACE  4
 QUAL$    IF     -DEF,QUAL$ 
          QUAL   *
 RJC      EQU    /COMPRJC/RJC 
 QUAL$    ENDIF 
          ENDX
