COMPRFI 
COMMON
          CTEXT  COMPRFI - RETURN FILE SIZE INDEX.
          SPACE  4,10 
          IF     -DEF,QUAL$,1 
          QUAL   COMPRFI
*         COMMENT  COPYRIGHT CONTROL DATA SYSTEMS INC.  1992. 
          SPACE  4,10 
***       RFI - RETURN FILE SIZE INDEX. 
*         J. HOLLISTER.      84/01/25.
          SPACE  4,10 
***              *RFI* RETURNS A FILE SIZE INDEX, A DIGIT BETWEEN 1 AND 
*         7, INDICATING RELATIVE FILE SIZE, FROM SMALLEST TO LARGEST. 
*         THE RANGE OF FILE SIZES CORRESPONDING TO EACH INDEX MAY BE
*         ADJUSTED BY CHANGING THE VALUES IN TABLE *TFSI*, WHICH
*         SPECIFIES THE LARGEST FILE SIZE FOR EACH INDEX.  THE SIZE 
*         FOR FILE SIZE INDEX 7 SHOULD ALWAYS BE THE LARGEST POSSIBLE 
*         FILE SIZE.
* 
*         ENTRY  (A) = ADDRESS OF TWO WORD FILE SIZE. 
* 
*         EXIT   (IOSS+ENTQ*5+2) = FILE SIZE INDEX. 
* 
*         USES   T1, T2, T3.
  
  
 RFI3     LDM    IOSS+ENTQ*5+2  CLEAR FIELD FOR SIZE INDEX IN QFT ENTRY 
          SCN    7
          LMD    T2          INSERT SIZE INDEX INTO QFT ENTRY 
          STM    IOSS+ENTQ*5+2  SAVE NEW QFT ENTRY WORD 
  
 RFI      SUBR               ENTRY/EXIT 
          STD    T1          SAVE FILE SIZE ADDRESS 
          LDN    1           PRESET FILE SIZE INDEX 
          STD    T2 
          LDN    0           PRESET TABLE OFFSET
          STD    T3 
 RFI1     LDM    TFSI,T3     GET FILE SIZE LIMIT FOR CURRENT INDEX
          SBI    T1          CHECK FIRST WORD OF FILE SIZE
          MJN    RFI2        IF FILE SIZE .GT. LIMIT
          NJN    RFI3        IF FILE SIZE .LT. LIMIT
          LDM    TFSI+1,T3   CHECK SECOND WORD OF FILE SIZE 
          SBM    1,T1 
          PJN    RFI3        IF FILE SIZE .LE. LIMIT
 RFI2     AOD    T2          INCREMENT FILE SIZE INDEX
          LDN    2           INCREMENT TABLE OFFSET 
          RAD    T3 
          UJN    RFI1        CHECK NEXT FILE SIZE INDEX 
          SPACE  4,10 
**        TFSI - TABLE OF MAXIMUM FILE SIZES FOR EACH FILE SIZE INDEX.
  
  
 TFSI     BSS    0
          VFD    24/FSI1     FILE SIZE INDEX 1
          VFD    24/FSI2     FILE SIZE INDEX 2
          VFD    24/FSI3     FILE SIZE INDEX 3
          VFD    24/FSI4     FILE SIZE INDEX 4
          VFD    24/FSI5     FILE SIZE INDEX 5
          VFD    24/FSI6     FILE SIZE INDEX 6
          VFD    24/77777777 FILE SIZE INDEX 7
          SPACE  4,10 
 QUAL$    IF     -DEF,QUAL$ 
          QUAL   *
 RFI      EQU    /COMPRFI/RFI 
 QUAL$    ENDIF 
          ENDX
