COMPREI 
COMMON
          CTEXT  COMPREI - REQUEST ECS STORAGE INCREASE.
          SPACE  4,10 
          IF     -DEF,QUAL$,1 
          QUAL   COMPREI
          BASE   MIXED
*         COMMENT  COPYRIGHT CONTROL DATA SYSTEMS INC.  1992. 
 REI      SPACE  4,10 
***       REI - REQUEST ECS INCREASE. 
*         L. C. HAAS.        75/06/05.
*         R. J. PRIEVE.      79/08/28.
 REI      SPACE  4,20 
*                *REI* PROCESSES ECS STORAGE CHANGES WHERE IT IS
*         DESIRED TO USE *FLIW* FOR INCREASES.
* 
*         ENTRY  (A) = ECS FL/1000B REQUIRED. 
*                (CP) = CONTROL POINT NUMBER. 
* 
*         EXIT   (A) = 0 IF INCREASE ASSIGNED.
*                (A) .LT. 0 IF INCREASE NOT AVAILABLE.
*                (A) .GT. 0 IF INCREASE PENDING.
* 
*         USES   T1, CM - CM+4. 
*         MACROS MONITOR. 
  
  
 REI      SUBR               ENTRY/EXIT 
          STD    T1          SAVE FLE REQUEST 
          LDD    CP          READ CURRENT FLE 
          ADN    ECSW 
          CRD    CM 
          LDD    T1          SET FLE REQUESTED
          STD    CM+1 
          LMD    CM+4 
          ZJN    REIX        IF STORAGE ALREADY ASSIGNED
          LDC    1*100+1     SET ECS REQUEST TO USE *FLIW*
          STD    CM+2 
          MONITOR  RSTM      REQUEST STORAGE
          LDD    CM+1 
          ZJN    REIX        IF STORAGE OBTAINED
          LDD    CP          READ FL INCREASE CONTROL WORD
          ADN    FLIW 
          CRD    CM 
          LDD    CM+1 
          SHN    21-1 
          MJN    REIX        IF INCREASE REJECTED BY SCHEDULER
          LDN    1           SET INCREASE PENDING 
          UJN    REIX        RETURN 
 REI      SPACE  4,10 
          BASE   *
 QUAL$    IF     -DEF,QUAL$ 
          QUAL   *
 REI      EQU    /COMPREI/REI 
 QUAL$    ENDIF 
          ENDX
