COMPNFL 
COMMON
          CTEXT  COMPNFL - REQUEST NEGATIVE FL. 
          SPACE  4,10 
          IF     -DEF,QUAL$,1 
          QUAL   COMPNFL
          BASE   MIXED
*         COMMENT  COPYRIGHT CONTROL DATA SYSTEMS INC.  1992. 
          SPACE  4,10 
***       NFL - REQUEST NEGATIVE FL.
* 
*         R. J. PRIEVE.      79/09/12.
 NFL      SPACE  4,15 
***              *NFL* PROCESSES STORAGE CHANGES FOR NEGATIVE FL. 
*         FOR INCREASES OF NEGATIVE FL, THE ADDITIONAL FL IS
*         ALSO CLEARED.  *FLIW* IS USED IN THE CASE OF A REJECTED 
*         NEGATIVE FL INCREASE. 
* 
*         ENTRY  (A) = DESIRED NEGATIVE FL/100B.
* 
*         EXIT   (A) = 0 IF STORAGE OBTAINED. 
*                (A) .LT. 0 IF INCREASE NOT AVAILABLE.
*                (A) = 1 IF NFL INCREASE PENDING. 
* 
*         USES   T1, T2, CM - CM+4. 
* 
*         MACROS MONITOR. 
  
  
 NFL2     LDD    CP          READ FL INCREASE CONTROL WORD
          ADN    FLIW 
          CRD    CM 
          LDD    CM+1 
          SHN    21-0 
          MJN    NFLX        IF INCREASE REJECTED BY SCHEDULER
          LDN    1           SET INCREASE PENDING 
  
 NFL      SUBR               ENTRY/EXIT 
          STD    T1          SAVE NEGATIVE FL REQUEST 
          LDD    CP          READ FL STATUS WORD
          ADN    FLSW 
          CRD    CM 
          LDD    T1 
          STD    CM+1 
          SBD    CM 
          ZJN    NFLX        IF NEGATIVE FL ALREADY ASSIGNED
          STD    T2 
          LDC    500         INDICATE TO SET *FLIW* ON REJECT 
          STD    CM+2 
          MONITOR  RSTM      REQUEST STORAGE
          LDD    CM+1 
          NJN    NFL2        IF STORAGE NOT OBTAINED
*         LDN    0           SET *NFL* OBTAINED 
          UJN    NFLX        RETURN 
          SPACE  4,10 
          BASE   *
 QUAL$    IF     -DEF,QUAL$ 
          QUAL   *
 NFL      EQU    /COMPNFL/NFL 
 QUAL$    ENDIF 
          ENDX
