COMPLDB 
COMMON
          CTEXT  COMPLDB - LOAD PPR OVERLAY BOOTSTRAPS. 
          SPACE  4,10 
          IF     -DEF,QUAL$,1 
          QUAL   COMPLDB
          BASE   M
*         COMMENT  COPYRIGHT CONTROL DATA SYSTEMS INC.  1992. 
          SPACE  4,10 
***       LDB - LOAD PPR OVERLAY BOOTSTRAPS.
* 
*         P. D. HAAS.        79/05/08.
          SPACE  4,10 
***              *LDB* CONTAINS CODE TO GENERATE AND INITIALIZE THE 
*         BOOTSTRAP NEEDED TO LOAD THE *PPR* OVERLAY *1DD*.  *LDB*
*         WRITES THE BOOTSTRAP TO CENTRAL MEMORY. 
 LDB      SPACE  4,10 
**        LDB - LOAD PPR OVERLAY BOOTSTRAPS.
* 
*         USES   CM - CM+4. 
* 
*         MACROS EXECUTE, MONITOR.
* 
*         NOTES  THIS COMMON DECK REQUIRES *COMSMSC*. 
  
  
 LDB      SUBR               ENTRY/EXIT 
          EXECUTE  1DD,*     FIND *1DD* IN RPL
          STD    CM+3 
          SHN    -14
          STD    CM+2 
          MONITOR  SPLM 
          LDD    CM+1        SET RPL ADDRESS IN BOOTSTRAP LOADER
          LPN    77 
          RAM    LDBB 
          LDD    CM+2 
          STM    LDBB+1 
          LDD    CM+3        SET *1DD* LENGTH 
          STM    LDBC 
          LDN    DFPP        GET FWA OF PP DUMP BUFFER
          CRD    CM 
          LDD    CM+2        STORE BOOTSTRAP IN DUMP BUFFER 
          SHN    14 
          LMD    CM+3 
          CWM    LDBA,TR
          UJP    LDBX        RETURN 
  
*         *1DD* BOOTSTRAP.
  
 LDBA     CWM    EPFW,CM+3   SAVE MS ERROR PROCESSOR AND LOW CORE 
          CWM    MSFW,T2     SAVE MS DRIVER AND PROGRAM 
 LDBB     LDC    *           LOAD *1DD* 
          CRM    DDFW-5,T1
          LJM    DDFW        EXECUTE *1DD*
          BSSZ   LDBA+3*5-3-*  SPARES 
          CON    10003-3*5-1 (T0) BECOMES P 
 LDBC     CON    0           (T1) 
          CON    DFDS-65     (T2) 
 LDB      SPACE  4,10 
          BASE   *
 QUAL$    IF     -DEF,QUAL$ 
          QUAL   *
 LDB      EQU    /COMPLDB/LDB 
 QUAL$    ENDIF 
          ENDX
