COMPIRA 
COMMON
          CTEXT  COMPIRA - INITIALIZE RANDOM ACCESS PROCESSORS. 
 IRA      SPACE  4
          IF     -DEF,QUAL$,1 
          QUAL   COMPIRA
*         COMMENT  COPYRIGHT CONTROL DATA SYSTEMS INC.  1992. 
 IRA      SPACE  4
***       IRA - INITIALIZE RANDOM ACCESS PROCESSORS.
*         G. R. MANSFIELD.  70/08/09. 
          SPACE  4
***              IRA INITIALIZES THE SEVERAL RANDOM ACCESS PROCESSORS.
*         IT MUST BE ASSEMBLED AFTER ALL RANDOM ACCESS PROCESSORS.
* 
*         ENTRY  (T5) = EST ORDINAL.
* 
*         EXIT   NONE.
* 
*         USES   T7, CM - CM+4. 
* 
*         MACROS SFA. 
  
  
 IRA      SUBR               ENTRY/EXIT 
          SFA    EST,T5      READ EST ENTRY 
          ADK    EQDE 
          CRD    CM 
          LDD    CM+4 
          SHN    3
          ADK    MDGL 
          CRD    CM 
          ADK    TRLL-MDGL
          CRD    T7 
          LDD    CM+4        SET SECTOR LIMIT 
          STP    SLM
          LDD    T7+3        SET TRT FWA
          LPN    77 
          SHN    14 
          LMD    T7+4 
          SBD    TH          4000/2 
  
          IF     DEF,CRA,1
          STM    CRAA+1 
          IF     DEF,SEI,1
          STM    SEIA+1 
          IF     DEF,SNT,1
          STM    SNTA+1 
          IF     DEF,SRA,1
          STM    SRAA+1 
  
          SHN    -14
          LMC    ADCI 
  
          IF     DEF,CRA,1
          STM    CRAA 
          IF     DEF,SEI,1
          STM    SEIA 
          IF     DEF,SNT,1
          STM    SNTA 
          IF     DEF,SRA,1
          STM    SRAA 
  
          LJM    IRAX        RETURN 
          SPACE  4
 QUAL$    IF     -DEF,QUAL$ 
          QUAL   *
 IRA      EQU    /COMPIRA/IRA 
 QUAL$    ENDIF 
          ENDX
