COMPICT 
COMMON
          CTEXT  COMPICT - INITIALIZE *CPUMTR* TABLES.
          SPACE  4,10 
          IF     -DEF,QUAL$,1 
          QUAL   COMPICT
          BASE   M
*         COMMENT  COPYRIGHT CONTROL DATA SYSTEMS INC.  1992. 
          SPACE  4,10 
***       ICT - INTIALIZE *CPUMTR* TABLES.
* 
*         J. L. LARSON.      82/01/14.
          SPACE  4,10 
***              *ICT* INITIALIZES THE FAST PP LOADER TABLE AND THE 
*         *EJT* RA+1 *ENEJ* SUBFUNCTION PRE-PROCESSOR TABLE IN
*         *CPUMTR*. 
 ICT      SPACE  4,10 
**        ICT - INTIALIZE *CPUMTR* TABLES.
* 
*         ENTRY  (A) = 0 IF TO CLEAR *CPUMTR* TABLES. 
*                    .NE. 0 IF TO REBUILD *CPUMTR* TABLES.
* 
*         USES   T1, CM - CM+5, FN - FN+4.
* 
*         MACROS MONITOR. 
  
  
 ICT      SUBR               ENTRY/EXIT 
          STD    T1          SAVE CLEAR/REBUILD TABLE FLAG
          LDC    CMTP        GET *CPUMTR* FWA 
          CRD    FN 
          LDD    FN+3 
          SHN    14 
          ADD    FN+4 
          ADN    CFPP        GET FAST PP LOADER POINTERS
          CRD    FN 
          LDD    FN+2 
          SHN    14 
          STD    FN+1        PRE-PROCESSOR TABLE LENGTH 
          SHN    -14
          STD    FN+2        FAST PP LOADER TABLE LENGTH
 ICT1     LDD    FN+3        GET NEXT TABLE ENTRY 
          SHN    14 
          ADD    FN+4 
          CRD    CM+1 
          LDD    MA          WRITE TABLE ENTRY TO MESSAGE BUFFER
          CWD    CM+1 
          LDD    FN+2 
          NJN    ICT3        IF UPDATING FAST PP LOADER TABLE 
          SOD    FN+1 
          MJN    ICTX        IF END OF PRE-PROCESSOR TABLE
          LDD    T1 
          ZJN    ICT2        IF CLEARING TABLES 
          MONITOR  SCDM 
          LDD    CM+3        GET PST ENTRY ADDRESS
          SHN    14 
          ADD    CM+4 
          ZJN    ICT2        IF PROGRAM NOT FOUND 
          CRD    CM 
          LDD    CM          GET PROGRAM FL/100B
          LPC    1777 
 ICT2     STD    FN          SAVE TABLE VALUE 
          LDD    MA          GET TABLE ENTRY
          CRD    CM 
          LDD    FN 
          STD    CM+4 
          LDD    CM+3 
          SCN    77 
          STD    CM+3 
          UJN    ICT4        UPDATE TABLE ENTRY 
  
 ICT3     SOD    FN+2 
          LDD    T1 
          ZJN    ICT2        IF CLEARING TABLES 
          MONITOR  SPLM 
 ICT4     LDD    FN+3        UPDATE TABLE ENTRY 
          SHN    14 
          ADD    FN+4 
          CWD    CM 
          ADN    1           ADVANCE TABLE ADDRESS
          STD    FN+4 
          SHN    -14
          STD    FN+3 
          LJM    ICT1        CONTINUE TABLE UPDATE
          SPACE  4,10 
          BASE   *
 QUAL$    IF     -DEF,QUAL$ 
          QUAL   *
 ICT      EQU    /COMPICT/ICT 
 QUAL$    ENDIF 
  
          ENDX
