COMPGTN 
COMMON
          CTEXT  COMPGTN - GET TERMINAL NUMBER. 
          IF     -DEF,QUAL$,1 
          QUAL   COMPGTN
*         COMMENT  COPYRIGHT CONTROL DATA SYSTEMS INC.  1992. 
 GTN      SPACE  4
***       GTN - GET TERMINAL NUMBER.
*         M. H. HOLT.        87/11/09.
 GTN      SPACE  4
***       GTN - GET TERMINAL NUMBER.
* 
*         SEARCH IAF-S TERMINAL TABLE FOR A SPECIFIED JSN AND 
*         RETURN ITS TERMINAL NUMBER. 
* 
*         ENTRY  (AB - AB+1) = JSN. 
*                (AB+3) = 0.
*                (T7) = *IAF* *FLSW* BYTE 3 (IF NON-CME MACHINE). 
*                (T7) = *IAF* *FLSW*+1 BYTE 3 (IF CME MACHINE). 
*                R REGISTER SET FOR *IAF* IF CME MACHINE. 
* 
*         EXIT   (A) .LT. 0 IF JSN NOT FOUND. 
*                (AB+3) = TERMINAL NUMBER IF FOUND. 
*                (SR+1 - SR+2) = RELATIVE FWA OF TERMINAL TABLE ENTRY.
* 
*         USES   T5, LA, AB+3, CM - CM+4, SR - SR+4.
  
  
 GTN      SUBR               ENTRY/EXIT 
          LDD    T7          GET FWA TERMINAL TABLE 
          SHN    6
          ADN    /REM/VTTP
          CRD    SR 
          ADN    /REM/VMNL-/REM/VTTP  GET MAXIMUM NUMBER OF TERMINALS 
          CRD    CM 
          LDD    CM+4        SAVE MAXIMUM NUMBER OF TERMINALS 
          SBN    /REM/VPST
          STD    T5 
          LDD    SR+1 
 GTN1     SHN    6
          ADD    T7 
          SHN    6
          ADD    SR+2 
          ADK    /REM/VUIT
          CRD    CM 
          ADK    /REM/VFST-/REM/VUIT  GET NEXT JSN
          CRD    CM+1 
          LDD    CM 
          ZJN    GTN2        IF TERMINAL TABLE ENTRY NOT IN USE 
          LDD    CM+1 
          LMD    AB 
          NJN    GTN2        IF JSN DOES NOT MATCH
          LDD    CM+1+1 
          LMD    AB+1 
          ZJN    GTNX        IF JSN MATCHES 
 GTN2     AOD    AB+3        INCREMENT TERMINAL NUMBER
          SOD    T5          DECREMENT TERMINAL COUNT 
          MJN    GTNX        IF ALL TERMINALS SEARCHED
          LDN    /REM/VTTL   GET NEXT TERMINAL TABLE ENTRY
          RAD    SR+2 
          SHN    -14
          RAD    SR+1 
          UJN    GTN1        LOOP 
          SPACE  4
 QUAL$    IF     -DEF,QUAL$ 
          QUAL   *
 GTN      EQU    /COMPGTN/GTN 
 QUAL$    ENDIF 
          ENDX
