COMPFLF 
COMMON
          CTEXT  COMPFLF - FLUSH LOCAL FILES. 
          SPACE  4
          IF     -DEF,QUAL$,1 
          QUAL   COMPFLF
*         COMMENT  COPYRIGHT CONTROL DATA SYSTEMS INC.  1992. 
 FLF      SPACE  4,10 
***       FLF - FLUSH LOCAL FILES.
*         S. L. BETH.        79/10/22.
*         P. T. BARNETT.     82/10/07.
 FLF      SPACE  4,10 
***       *FLF* WILL INSURE THAT ALL FILES LOCAL TO A JOB THAT ARE
*         RESIDING ON A BUFFERED DEVICE ARE FLUSHED TO THE DISK.
* 
*         ENTRY  (A) = NFL SIZE OF CONTROL POINT OR PSEUDO-CONTROL
*                      POINT TO PROCESS.
* 
*         USES   T3 - T7, CM - CM+5, CN - CN+4. 
* 
*         MACROS MONITOR, NFA, SFA. 
  
  
 FLF      SUBR               ENTRY/EXIT 
          ADN    1           SET LIMIT FOR FILE SEARCH
          STD    T3 
          LDK    BIOL        CHECK PRESENCE OF BUFFERED I/O 
          CRD    CM 
          LDD    CM+1 
          SHN    14 
          ADD    CM+2 
          ZJN    FLFX        IF BUFFERED I/O NOT IN USE 
          ADN    /COMSHIO/CBTP  READ CONTROL BUFFER ADDRESS 
          CRD    CM 
          LDD    CM+4 
          RAM    FLFA+1 
          SHN    -14
          ADD    CM+3 
          RAM    FLFA 
          LDC    FNTN        SET FIRST ENTRY
          STD    T4 
 FLF1     NFA    T4,R        READ NFL ENTRY 
          ADN    FSTL 
          CRD    T5 
          LDD    T5 
          LPC    777
          ZJN    FLF2        IF EMPTY ENTRY 
          SFA    EST         CHECK FOR BUFFERED DEVICE
          ADK    EQDE 
          CRD    CM 
          LDD    CM 
          SHN    21-13
          PJN    FLF2        IF NOT MASS STORAGE
          LDD    CM+4        MST ADDRESS / 10B
          SHN    3
          ADK    DILL 
          CRD    CM 
          LDD    CM+3 
          SHN    21-12
 FLF2     PJP    FLF5        IF NOT BUFFERED DEVICE 
          NFA    T4,R        READ FNT 
          ADK    FUTL 
          CRD    CN 
          LDD    CN+4 
          SHN    /COMSHIO/CBTLS 
          ZJN    FLF2        IF NO CONTROL BUFFER INDEX 
 FLFA     ADC    /COMSHIO/LSLK  READ CONTROL BUFFER 
          CRD    T7 
          SBN    -/COMSHIO/IOLK+/COMSHIO/LSLK 
          CRD    CM 
          SBN    -/COMSHIO/FSTC+/COMSHIO/IOLK 
          CRD    CM+1 
          LDD    T7 
          NJN    FLF4        IF BUFFER BEING ACCESSED 
          LDD    CM+1        COMPARE FST INFORMATION
          LMD    T5 
          LPC    777
          NJN    FLF4        IF BUFFER NOT FOR SAME EQUIPMENT 
          LDD    CM+2 
          ZJN    FLF3        IF NO FIRST TRACK (*PIOM* READ BUFFER) 
          LMD    T6 
          NJN    FLF4        IF NOT SAME TRACK
 FLF3     LDD    CM 
          LPC    5000 
          LMD    TH 
          ZJN    FLF6        IF WRITE DATA
 FLF4     LDN    0           CLEAR BUFFER INDEX 
          STD    CN+4 
          NFA    T4,R 
          ADK    FUTL 
          CWD    CN 
 FLF5     LDN    LENF        ADVANCE TO NEXT ENTRY
          RAD    T4 
          SBD    T3 
          MJP    FLF1        IF NOT END OF LOCAL FNT
          LJM    FLFX        RETURN 
  
 FLF6     LDD    T4          SET FNT ORDINAL
          STD    CM+4 
          LDC    FLBS*100    REQUEST BUFFER FLUSH 
          STD    CM+1 
          MONITOR  PIOM 
          UJN    FLF5        CONTINUE SCAN
  
  
 QUAL$    IF     -DEF,QUAL$ 
          QUAL   *
 FLF      EQU    /COMPFLF/FLF 
 QUAL$    ENDIF 
          ENDX
