COMPECX 
COMMON
          CTEXT  COMPECX - COMPUTE USER EXTENDED MEMORY MAXIMUM FL. 
          SPACE  4,10 
          IF     -DEF,QUAL$,1 
          QUAL   COMPECX
          BASE   MIXED
*         COMMENT  COPYRIGHT CONTROL DATA SYSTEMS INC.  1992. 
 ECX      SPACE  4,10 
***       ECX - COMPUTE ECS MAXIMUM FIELD LENGTH. 
*         J. L. LARSON.      75/05/22.
          SPACE  4,20 
***       ECX COMPUTES THE MAXIMUM POSSIBLE ECS FIELD LENGTH
*         FOR ANY JOB BASED ON THE USER ECS SIZE AND THE GIVEN
*         VALIDATION LIMITATIONS.  THE CALCULATIONS INCLUDED IN THE 
*         SUPPLIED VERSION OF THIS DECK ARE THE FOLLOWING - 
* 
*         MAXFL (ECS) = MINIMUM (MACHINE USER ECS FL - CONSTANT,
*                       VALIDATION ECS FL)
* 
*         REQUIRES COMMON DECK *COMPCVI* WITH *ECI$* SELECTED.
* 
*         ENTRY  (A) = ECS VALIDATION INDEX.
* 
*         EXIT   (A) = MAXFL (ECS) IN *UEBS* WORD BLOCKS. 
* 
*         USES   T1, T2, CM - CM+4. 
* 
*         CALLS  ECI. 
  
  
 ECX1     ADD    T2 
  
 ECX      SUBR               ENTRY/EXIT 
          RJM    ECI         CONVERT ECS FL INDEX 
          STD    T1          VALIDATION SIZE (IN *UEBS* WORD BLOCKS)
          LDN    ECRL        MACHINE USER ECS (IN *UEBS* WORD BLOCKS) 
          CRD    CM 
          LDD    CM+1 
          SBD    CM+4        USER ECS FL - SYSTEM RESERVED ECS FL 
          SBN    ECXA        CALCULATE MACHINE ECS SIZE - CONSTANT
          STD    T2 
          LDD    T1          VALIDATION SIZE
          SBD    T2          MACHINE ECS SIZE 
          MJN    ECX1        IF VALIDATION .LT. MACHINE SIZE
          LDD    T2 
          SHN    -13
          ZJN    ECX1        IF MACHINE SIZE .LE. 3777B BLOCKS
          LDC    3777 
          UJN    ECXX        EXIT WITH ECS VALIDATION SIZE
  
  
 ECXA     EQU    0           RESERVED SECTION OF USER ECS FL
 ECX      SPACE  4,10 
          BASE   *
 QUAL$    IF     -DEF,QUAL$ 
          QUAL   *
 ECX      EQU    /COMPECX/ECX 
 QUAL$    ENDIF 
          ENDX
