COMPDV5 
COMMON
          CTEXT  COMPDV5 - DIVIDE BY FIVE.
          BASE   M
 DV5      SPACE  4
          IF     -DEF,QUAL$,1 
          QUAL   COMPDV5
*         COMMENT  COPYRIGHT CONTROL DATA SYSTEMS INC.  1992. 
 DV5      SPACE  4
***       DV5 - DIVIDE BY FIVE. 
*         P. D. HAAS.        76/09/08.
 DV5      SPACE  4
***              DV5 DIVIDES A 12 BIT QUANTITY BY FRACTIONAL
*         APPROXIMATION OF ONE FIFTH.  THE ALGORITHM IS ADAPTED FROM
*         SUBROUTINE *RTB* IN *STL*.  IF RND$ IS DEFINED, ROUNDING
*         WILL BE PERFORMED.
* 
*         ENTRY  (A) = QUANTITY TO BE DIVIDED.
* 
*         EXIT   (A) = QUANTITY / 5.
* 
*         USES   T0, T2.
  
  
 DV5      SUBR               ENTRY/EXIT 
          IF     DEF,RND$,1 
          ADN    4           ROUND
          STD    T2          SET BYTE COUNT 
          SHN    1           2*BYTES
          ADD    T2          3*BYTES
          SHN    2           12*BYTES 
          ADD    T2          13*BYTES 
          SHN    14   (-6)   13*BYTES/64
          STD    T0 
          SHN    6+2         4*13*BYTES = 52*BYTES
          SBD    T2          51*BYTES 
          ADD    T0          51*BYTES + 13*BYTES/64 
          SHN    -8D         (51*BYTES + 13*BYTES/64) / 256 
          UJN    DV5X        RETURN 
 DV5      SPACE  4
          BASE   *
          IF     -DEF,QUAL$ 
          QUAL   *
 DV5      EQU    /COMPDV5/DV5 
          ENDIF 
          ENDX
