COMPDTS 
COMMON
          CTEXT  COMPDTS - DETERMINE TRACK INTERLOCK STATUS.
          SPACE  4
          IF     -DEF,QUAL$,1 
          QUAL   COMPDTS
*         COMMENT  COPYRIGHT CONTROL DATA SYSTEMS INC.  1992. 
          SPACE  4
***       DTS - DETERMINE TRACK INTERLOCK STATUS. 
*         J. L. WARDELL.     72/06/01.
*         S. L. KSANDER.     75/04/28.
          SPACE  4
***       COMPDTS DETERMINES IF THE TRACK INTERLOCK IS SET FOR THE
*         TRACK SPECIFIED.
* 
*         IF *DTS$* IS DEFINED, CHECK FOR INACCESSIBLE DEVICE.
* 
*         ENTRY  (T5) = EST ORDINAL.
*                (T6) = TRACK.
* 
*         EXIT   (A) .LT. 0 IF TRACK INTERLOCK SET. 
*                (A) = 0 IF INACCESSIBLE DEVICE (DTS$ DEFINED). 
* 
*         USES   CM - CM+4. 
* 
*         MACROS MONITOR, SFA.
          SPACE  4
**        INSTRUCTIONS USED AS CONSTANTS. 
  
  
 SHNI     EQU    1000        SHN
  
  
 DTS$     IF     DEF,DTS$ 
 DTS4     LDN    0           RETURN INACCESSIBLE-DEVICE FLAG
 DTS$     ENDIF 
  
 DTS      SUBR               ENTRY/EXIT 
          SFA    EST,T5      READ EST ENTRY 
          ADK    EQDE 
          CRD    CM 
          LDD    CM 
          SHN    21-11
          PJN    DTS1        IF NOT SHARED DEVICE 
          LDD    T5          REQUEST UP-TO-DATE TRT 
 DTS$     IF     DEF,DTS$ 
          ADD    TH 
 DTS$     ENDIF 
          STD    CM+1 
          LDN    UTRS 
          STD    CM+3 
          MONITOR STBM
 DTS$     IF     DEF,DTS$ 
          LDD    CM+1 
          SHN    21-11
          MJN    DTS4        IF DEVICE IS INACCESSIBLE
 DTS$     ENDIF 
 DTS1     LDD    T6          GET WORD OFFSET
          LPC    3774 
          SHN    -2 
          STD    T0 
          LDD    CM+4        GET FWA OF TRT 
          SHN    3
          ADN    TRLL 
          CRD    CM 
          LDD    CM+3 
          LPN    77 
          SHN    14 
          LMD    CM+4 
          ADD    T0          ADD TRT WORD OFFSET
          CRD    CM          READ TRT WORD
          LDD    T6          SET SHIFT COUNT
          LPN    3
          ADC    SHNI+12
          STM    DTSA 
          LDD    CM+4 
 DTSA     SHN    12 
 DTS3     UJP    DTSX        RETURN 
          SPACE  4
 QUAL$    IF     -DEF,QUAL$ 
          QUAL   *
 DTS      EQU    /COMPDTS/DTS 
 QUAL$    ENDIF 
          ENDX
